packaging/release-rsync

   1 #!/usr/bin/perl
   2 use strict;
   3
   4 # This script expects the directory ~/samba-rsync-ftp to exist and to be a
   5 # copy of the /home/ftp/pub/rsync dir on samba.org.  When the script is done,
   6 # the git repository in the current directory will be updated, and the local
   7 # ~/samba-rsync-ftp dir will be ready to be rsynced to samba.org.
   8
   9 use Cwd;
  10 use Date::Format;
  11
  12 my $dest = $ENV{HOME} . '/samba-rsync-ftp';
  13
  14 my $now = time;
  15 my $cl_today = time2str('* %a %b %d %Y', $now);
  16 my $year = time2str('%Y', $now);
  17 my $ztoday = time2str('%d %b %Y', $now);
  18 (my $today = $ztoday) =~ s/^0//;
  19
  20 my $curdir = Cwd::cwd;
  21
  22 my @extra_files;
  23 open(IN, '<', 'Makefile.in') or die "Couldn't open Makefile.in: $!\n";
  24 while (<IN>) {
  25     if (s/^GENFILES=//) {
  26         while (s/\\$//) {
  27             $_ .= <IN>;
  28         }
  29         @extra_files = split(' ', $_);
  30         last;
  31     }
  32 }
  33 close IN;
  34
  35 my $break = <<EOT;
  36 ==========================================================================
  37 EOT
  38
  39 print $break, <<EOT, $break, "\n";
  40 == This will release a new version of rsync onto an unsuspecting world. ==
  41 EOT
  42
  43 die "$dest does not exist\n" unless -d $dest;
  44 die "There is no .git dir in the current directory.\n" unless -d '.git';
  45 die "'a' must not exist in the current directory.\n" if -e 'a';
  46 die "'b' must not exist in the current directory.\n" if -e 'b';
  47
  48 open(IN, '-|', 'git status') or die $!;
  49 my $status = join('', <IN>);
  50 close IN;
  51 die "The checkout is not clean:\n", $status unless $status =~ /\nnothing to commit \(working directory clean\)/;
  52 die "The checkout is not on the master branch.\n" unless $status =~ /^# On branch master\n/;
  53
  54 my $confversion;
  55 open(IN, '<', 'configure.in') or die $!;
  56 while (<IN>) {
  57     if (/^RSYNC_VERSION=(.*)/) {
  58         $confversion = $1;
  59         last;
  60     }
  61 }
  62 close IN;
  63 die "Unable to find RSYNC_VERSION in configure.in\n" unless defined $confversion;
  64
  65 open(IN, '<', 'OLDNEWS') or die $!;
  66 $_ = <IN>;
  67 close IN;
  68 my($lastversion) = /(\d+\.\d+\.\d+)/;
  69
  70 my $version = $confversion;
  71 $version =~ s/dev/pre1/ || $version =~ s/pre(\d+)/ 'pre' . ($1 + 1) /e;
  72
  73 print "Please enter the version number of this release: [$version] ";
  74 chomp($_ = <STDIN>);
  75 if ($_ eq '.') {
  76     $version =~ s/pre\d+//;
  77 } elsif ($_ ne '') {
  78     $version = $_;
  79 }
  80
  81 if ($version =~ s/[-.]*pre[-.]*/pre/ && $confversion !~ /dev$/) {
  82     $lastversion = $confversion;
  83 }
  84
  85 print "Enter the previous version to produce a patch against: [$lastversion] ";
  86 chomp($_ = <STDIN>);
  87 $lastversion = $_ if $_ ne '';
  88 $lastversion =~ s/[-.]*pre[-.]*/pre/;
  89
  90 my $release = 1;
  91 print "Please enter the RPM release number of this release: [$release] ";
  92 chomp($_ = <STDIN>);
  93 $release = $_ if $_ ne '';
  94
  95 my($srcdir,$srcdiffdir,$lastsrcdir,$skipping);
  96 if ($lastversion =~ /pre/) {
  97     if ($version !~ /pre/) {
  98         die "You should not diff a release version against a pre-release version.\n";
  99     }
 100     $srcdir = $srcdiffdir = $lastsrcdir = 'src-previews';
 101     $skipping = ' ** SKIPPING **';
 102 } elsif ($version =~ /pre/) {
 103     $srcdir = $srcdiffdir = 'src-previews';
 104     $lastsrcdir = 'src';
 105     $skipping = ' ** SKIPPING **';
 106 } else {
 107     $srcdir = $lastsrcdir = 'src';
 108     $srcdiffdir = 'src-diffs';
 109     $skipping = '';
 110 }
 111
 112 print "\n", $break, <<EOT;
 113 \$version is "$version"
 114 \$lastversion is "$lastversion"
 115 \$dest is "$dest"
 116 \$curdir is "$curdir"
 117 \$srcdir is "$srcdir"
 118 \$srcdiffdir is "$srcdiffdir"
 119 \$lastsrcdir is "$lastsrcdir"
 120 \$release is "$release"
 121
 122 About to:
 123     - make sure that SUBPROTOCOL_VERSION is 0$skipping
 124     - tweak the version in configure.in and the spec files
 125     - tweak NEWS and OLDNEWS to update the release date$skipping
 126     - tweak the date in the *.yo files and generate the man pages
 127     - generate configure.sh, config.h.in, and proto.h
 128     - page through the differences
 129
 130 EOT
 131 print "<Press Enter to continue> ";
 132 $_ = <STDIN>;
 133
 134 (my $finalversion = $version) =~ s/pre\d+//;
 135 my %specvars = ( 'Version:' => $version, 'Release:' => $release,
 136                  'Released' => "$version." );
 137 my @tweak_files = ( glob('packaging/*.spec'), glob('packaging/*/*.spec'), glob('*.yo'),
 138                     qw( configure.in rsync.h NEWS OLDNEWS options.c ) );
 139
 140 foreach my $fn (@tweak_files) {
 141     open(IN, '<', $fn) or die $!;
 142     undef $/; $_ = <IN>; $/ = "\n";
 143     close IN;
 144     if ($fn =~ /configure/) {
 145         s/^RSYNC_VERSION=.*/RSYNC_VERSION=$version/m
 146             or die "Unable to update RSYNC_VERSION in $fn\n";
 147     } elsif ($fn =~ /\.spec/) {
 148         while (my($str, $val) = each %specvars) {
 149             s/^\Q$str\E .*/$str $val/m
 150                 or die "Unable to update $str in $fn\n";
 151         }
 152         s/^\* \w\w\w \w\w\w \d\d \d\d\d\d (.*)/$cl_today $1/m
 153             or die "Unable to update ChangeLog header in $fn\n";
 154     } elsif ($fn =~ /\.yo/) {
 155         s/^(manpage\([^)]+\)\(\d+\)\()[^)]+(\).*)/$1$today$2/m
 156             or die "Unable to update date in manpage() header in $fn\n";
 157         s/^(This man ?page is current for version) \S+ (of rsync)/$1 $version $2/m
 158             or die "Unable to update current version info in $fn\n";
 159     } elsif ($fn eq 'rsync.h') {
 160         s/(#define\s+SUBPROTOCOL_VERSION)\s+\d+/$1 0/
 161             or die "Unable to find SUBPROTOCOL_VERSION define in $fn\n";
 162         next if $version =~ /pre/;
 163     } elsif ($fn eq 'NEWS') {
 164         s/^(NEWS for rsync \Q$finalversion\E) \(UNRELEASED\)\s*\n/$1 ($today)\n/mi
 165             or die "The first line of $fn is not in the right format.  It must be:\n"
 166                  . "NEWS for rsync $finalversion (UNRELEASED)\n";
 167         next if $version =~ /pre/;
 168     } elsif ($fn eq 'OLDNEWS') {
 169         s/^\t\S\S\s\S\S\S\s\d\d\d\d(\t\Q$finalversion\E)/\t$ztoday$1/m
 170             or die "Unable to find \"?? ??? $year\t$finalversion\" line in $fn\n";
 171         next if $version =~ /pre/;
 172     } elsif ($fn eq 'options.c') {
 173         if (s/(Copyright \(C\) 2002-)(\d+)( Wayne Davison)/$1$year$3/
 174          && $2 ne $year) {
 175             die "Copyright comments need to be updated to $year in all files!\n";
 176         }
 177         # Adjust the year in the --version output.
 178         s/(rprintf\(f, "Copyright \(C\) 1996-)(\d+)/$1$year/
 179             or die "Unable to find Copyright string in --version output of $fn\n";
 180         next if $2 eq $year;
 181     } else {
 182         die "Unrecognized file in \@tweak_files: $fn\n";
 183     }
 184     open(OUT, '>', $fn) or die $!;
 185     print OUT $_;
 186     close OUT;
 187 }
 188
 189 print $break;
 190 system "git diff --color | less -p '^diff .*'";
 191
 192 my $srctar_name = "rsync-$version.tar.gz";
 193 my $pattar_name = "rsync-patches-$version.tar.gz";
 194 my $diff_name = "rsync-$lastversion-$version.diffs.gz";
 195 my $srctar_file = "$dest/$srcdir/$srctar_name";
 196 my $pattar_file = "$dest/$srcdir/$pattar_name";
 197 my $diff_file = "$dest/$srcdiffdir/$diff_name";
 198 my $news_file = "$dest/$srcdir/rsync-$version-NEWS";
 199 my $lasttar_file = "$dest/$lastsrcdir/rsync-$lastversion.tar.gz";
 200
 201 print $break, <<EOT;
 202
 203 About to:
 204     - commit all changes
 205     - tag this release as v$version
 206     - update hard-linked top-level files for new version$skipping
 207     - create release tar, "$srctar_name"
 208     - create patches tar, "$pattar_name"
 209     - create release diffs, "$diff_name"
 210     - update patch branches and generate patch/* files
 211     - update README, *NEWS, TODO, and ChangeLog
 212     - update rsync*.html man pages
 213     - gpg-sign the release files
 214
 215 EOT
 216 print "<Press Enter to continue> ";
 217 $_ = <STDIN>;
 218
 219 system "git commit -a -m 'Preparing for release of $version'" and exit 1;
 220 print "\nSign the tag:";
 221 system "git tag -s -m 'Version $version.' v$version" and exit 1;
 222
 223 # Extract the generated files from the old tar.
 224 @_ = @extra_files;
 225 map { s#^#rsync-$lastversion/# } @_;
 226 system "tar xzf $lasttar_file @_";
 227 rename("rsync-$lastversion", 'a');
 228
 229 print "Creating $diff_file ...\n";
 230 system "./config.status Makefile; make gen; rsync -a @extra_files b/";
 231 my $sed_script = 's:^((---|\+\+\+) [ab]/[^\t]+)\t.*:\1:';
 232 system "(git diff v$lastversion v$version; diff -upN a b | sed -r '$sed_script') | gzip -9 >$diff_file";
 233 system "rm -rf a";
 234 rename('b', "rsync-$version");
 235
 236 print "Creating $srctar_file ...\n";
 237 system "git archive --format=tar --prefix=rsync-$version/ v$version | tar xf -";
 238 system "support/git-set-file-times --prefix=rsync-$version/";
 239 system "fakeroot tar czf $srctar_file rsync-$version; rm -rf rsync-$version";
 240
 241 mkdir("rsync-$version", 0755);
 242 mkdir("rsync-$version/patches", 0755);
 243 system "support/patch-update --skip-check --gen=rsync-$version/patches";
 244 system "fakeroot tar chzf $pattar_file rsync-$version/patches; rm -rf rsync-$version";
 245
 246 print "Updating the other files in $dest ...\n";
 247 system "rsync -a README NEWS OLDNEWS TODO $dest";
 248 unlink($news_file);
 249 link("$dest/NEWS", $news_file);
 250 system "git log --name-status | gzip -9 >$dest/ChangeLog.gz";
 251
 252 system "yodl2html -o $dest/rsync.html rsync.yo";
 253 system "yodl2html -o $dest/rsyncd.conf.html rsyncd.conf.yo";
 254
 255 my $cnt = 0;
 256 print "\n";
 257 foreach my $fn ($srctar_file, $pattar_file, $diff_file) {
 258     print ++$cnt, ". Sign file \"$fn\":";
 259     system "gpg -ba $fn";
 260 }
 261
 262 if ($version !~ /pre/) {
 263     system "rm $dest/rsync-*{.tar.gz,.asc,-NEWS} $dest/src-preview/rsync-*diffs.gz";
 264
 265     foreach my $fn ($srctar_file, "$srctar_file.asc",
 266                     $pattar_file, "$pattar_file.asc",
 267                     $diff_file, "$diff_file.asc", $news_file) {
 268         (my $top_fn = $fn) =~ s#/src(-\w+)?/#/#;
 269         link($fn, $top_fn);
 270     }
 271 }
 272
 273 print $break, <<'EOT';
 274
 275 Local changes are done.  When you're satisfied, push the git repository
 276 and rsync the release files.  Remember to announce the release on *BOTH*
 277 rsync-announce@lists.samba.org and rsync@lists.samba.org (and the web)!
 278 EOT