support/rrsync

   1 #!/usr/bin/perl
   2 # Name: /usr/local/bin/rrsync (should also have a symlink in /usr/bin)
   3 # Purpose: Restricts rsync to subdirectory declared in .ssh/authorized_keys
   4 # Author: Joe Smith <js-cgi@inwap.com> 30-Sep-2004
   5 # Modified by: Wayne Davison <wayned@samba.org>
   6 use strict;
   7
   8 use Socket;
   9 use Cwd 'abs_path';
  10 use File::Glob ':glob';
  11
  12 # You may configure these values to your liking.  See also the section
  13 # of options if you want to disable any options that rsync accepts.
  14 use constant RSYNC => '/usr/bin/rsync';
  15 use constant LOGFILE => 'rrsync.log';
  16
  17 my $Usage = <<EOM;
  18 Use 'command="$0 [-ro] SUBDIR"'
  19         in front of lines in $ENV{HOME}/.ssh/authorized_keys
  20 EOM
  21
  22 our $ro = (@ARGV && $ARGV[0] eq '-ro') ? shift : '';    # -ro = Read-Only
  23 our $subdir = shift;
  24 die "$0: No subdirectory specified\n$Usage" unless defined $subdir;
  25 $subdir = abs_path($subdir);
  26 die "$0: Restricted directory does not exist!\n" if $subdir ne '/' && !-d $subdir;
  27
  28 # The client uses "rsync -av -e ssh src/ server:dir/", and sshd on the server
  29 # executes this program when .ssh/authorized_keys has 'command="..."'.
  30 # For example:
  31 # command="rrsync logs/client" ssh-rsa AAAAB3NzaC1yc2EAAAABIwAAAIEAzGhEeNlPr...
  32 # command="rrsync -ro results" ssh-rsa AAAAB3NzaC1yc2EAAAABIwAAAIEAmkHG1WCjC...
  33 #
  34 # Format of the envrionment variables set by sshd:
  35 # SSH_ORIGINAL_COMMAND=rsync --server          -vlogDtpr --partial . ARG # push
  36 # SSH_ORIGINAL_COMMAND=rsync --server --sender -vlogDtpr --partial . ARGS # pull
  37 # SSH_CONNECTION=client_addr client_port server_port
  38
  39 my $command = $ENV{SSH_ORIGINAL_COMMAND};
  40 die "$0: Not invoked via sshd\n$Usage"  unless defined $command;
  41 die "$0: SSH_ORIGINAL_COMMAND='$command' is not rsync\n" unless $command =~ s/^rsync\s+//;
  42 our $am_sender = $command =~ /^--server\s+--sender\s/; # Restrictive on purpose!
  43 die "$0 -ro: sending to read-only server not allowed\n" if $ro && !$am_sender;
  44
  45 ### START of options data produced by the cull_options script. ###
  46
  47 # These options are the only options that rsync might send to the server,
  48 # and only in the option format that the stock rsync produces.
  49
  50 # To disable a short-named option, add its letter to this string:
  51 our $short_disabled = '';
  52
  53 our $short_no_arg = 'CDHIKLORSWbcdglnoprtuvxz'; # DO NOT REMOVE ANY
  54 our $short_with_num = 'B'; # DO NOT REMOVE ANY
  55
  56 # To disable a long-named option, change its value to a -1.  The values mean:
  57 # 0 = the option has no arg; 1 = the arg doesn't need any checking; 2 = only
  58 # check the arg when receiving; and 3 = always check the arg.
  59 our %long_opt = (
  60   'backup-dir' => 2,
  61   'bwlimit' => 1,
  62   'checksum-seed' => 1,
  63   'compare-dest' => 2,
  64   'copy-dest' => 2,
  65   'copy-unsafe-links' => 0,
  66   'daemon' => 0,
  67   'delay-updates' => 0,
  68   'delete' => 0,
  69   'delete-after' => 0,
  70   'delete-before' => 0,
  71   'delete-during' => 0,
  72   'delete-excluded' => 0,
  73   'existing' => 0,
  74   'files-from' => 3,
  75   'force' => 0,
  76   'from0' => 0,
  77   'fuzzy' => 0,
  78   'ignore-errors' => 0,
  79   'ignore-existing' => 0,
  80   'inplace' => 0,
  81   'link-dest' => 2,
  82   'list-only' => 0,
  83   'log-format' => 1,
  84   'max-delete' => 1,
  85   'max-size' => 1,
  86   'modify-window' => 1,
  87   'no-implied-dirs' => 0,
  88   'no-relative' => 0,
  89   'numeric-ids' => 0,
  90   'only-write-batch' => 1,
  91   'partial' => 0,
  92   'partial-dir' => 2,
  93   'remove-sent-files' => $ro ? -1 : 0,
  94   'safe-links' => 0,
  95   'sender' => 0,
  96   'server' => 0,
  97   'size-only' => 0,
  98   'suffix' => 1,
  99   'temp-dir' => 2,
 100   'timeout' => 1,
 101 );
 102
 103 ### END of options data produced by the cull_options script. ###
 104
 105 if ($short_disabled ne '') {
 106     $short_no_arg =~ s/[$short_disabled]//go;
 107     $short_with_num =~ s/[$short_disabled]//go;
 108 }
 109 $short_no_arg = "[$short_no_arg]" if length($short_no_arg) > 1;
 110 $short_with_num = "[$short_with_num]" if length($short_with_num) > 1;
 111
 112 my $write_log = -f LOGFILE && open(LOG, '>>', LOGFILE);
 113
 114 chdir($subdir) or die "$0: Unable to chdir to restricted dir: $!\n";
 115
 116 my(@opts, @args);
 117 my $in_options = 1;
 118 my $last_opt = '';
 119 my $check_type;
 120 while ($command =~ /((?:[^\s\\]+|\\.[^\s\\]*)+)/g) {
 121   $_ = $1;
 122   if ($check_type) {
 123     push(@opts, check_arg($last_opt, $_, $check_type));
 124     $check_type = 0;
 125   } elsif ($in_options) {
 126     push(@opts, $_);
 127     if ($_ eq '.') {
 128       $in_options = 0;
 129     } else {
 130       next if /^-$short_no_arg+$/o || /^-$short_with_num\d+$/o;
 131
 132       my($opt,$arg) = /^--([^=]+)(?:=(.*))?$/;
 133       my $disabled;
 134       if (defined $opt) {
 135         my $ct = $long_opt{$opt};
 136         last unless defined $ct;
 137         next if $ct == 0;
 138         if ($ct > 0) {
 139           if (!defined $arg) {
 140             $check_type = $ct;
 141             $last_opt = $opt;
 142             next;
 143           }
 144           $arg = check_arg($opt, $arg, $ct);
 145           $opts[-1] =~ s/=.*/=$arg/;
 146           next;
 147         }
 148         $disabled = 1;
 149         $opt = "--$opt";
 150       } elsif ($short_disabled ne '') {
 151         $disabled = /^-$short_no_arg*([$short_disabled])/o;
 152         $opt = "-$1";
 153       }
 154
 155       last unless $disabled; # Generate generic failure
 156       die "$0: option $opt has been disabled on this server.\n";
 157     }
 158   } else {
 159     if ($subdir ne '/') {
 160       # Validate args to ensure they don't try to leave our restricted dir.
 161       s#//+#/#g;
 162       s#^/##;
 163       s#^$#.#;
 164       die "Do not use .. in any path!\n" if m#(^|/)\\?\.\\?\.(\\?/|$)#;
 165     }
 166     push(@args, bsd_glob($_, GLOB_LIMIT|GLOB_NOCHECK|GLOB_BRACE|GLOB_QUOTE));
 167   }
 168 }
 169 die "$0: invalid rsync-command syntax or options\n" if $in_options;
 170
 171 @args = ( '.' ) if !@args;
 172
 173 if ($write_log) {
 174   my ($mm,$hh) = (localtime)[1,2];
 175   my $host = $ENV{SSH_CONNECTION} || 'unknown';
 176   $host =~ s/ .*//; # Keep only the client's IP addr
 177   $host =~ s/^::ffff://;
 178   $host = gethostbyaddr(inet_aton($host),AF_INET) || $host;
 179   printf LOG "%02d:%02d %-13s [%s]\n", $hh, $mm, $host, "@opts @args";
 180   close LOG;
 181 }
 182
 183 # Note: This assumes that the rsync protocol will not be maliciously hijacked.
 184 exec(RSYNC, @opts, @args) or die "exec(rsync @opts @args) failed: $? $!";
 185
 186 sub check_arg
 187 {
 188   my($opt, $arg, $type) = @_;
 189   $arg =~ s/\\(.)/$1/g;
 190   if ($subdir ne '/' && ($type == 3 || ($type == 2 && !$am_sender))) {
 191     $arg =~ s#//#/#g;
 192     die "Do not use .. in --$opt; anchor the path at the root of your restricted dir.\n"
 193       if $arg =~ m#(^|/)\.\.(/|$)#;
 194     $arg =~ s#^/#$subdir/#;
 195   }
 196   $arg;
 197 }