support/patch-update

   1 #!/usr/bin/perl -w
   2 # This script is used to turn one or more of the "patch/*" branches
   3 # into one or more diffs in the "patches" directory.  Pass the option
   4 # --gen if you want generated files in the diffs.  Pass the name of
   5 # one or more diffs if you want to just update a subset of all the
   6 # diffs.
   7
   8 use strict;
   9
  10 die "No 'patches' directory present in the current dir.\n" unless -d 'patches';
  11 die "No '.git' directory present in the current dir.\n" unless -d '.git';
  12
  13 my @extra_files;
  14 open(IN, '<', 'Makefile.in') or die "Couldn't open Makefile.in: $!\n";
  15 while (<IN>) {
  16     if (s/^GENFILES=//) {
  17         while (s/\\$//) {
  18             $_ .= <IN>;
  19         }
  20         @extra_files = split(' ', $_);
  21         last;
  22     }
  23 }
  24 close IN;
  25
  26 my $incl_generated_files = shift if @ARGV && $ARGV[0] eq '--gen';
  27
  28 system "git checkout master" and exit 1;
  29 if ($incl_generated_files) {
  30     die "'a' must not exist in the current directory.\n" if -e 'a';
  31     die "'b' must not exist in the current directory.\n" if -e 'b';
  32     system "make gen && rsync -a @extra_files a/" and exit 1;
  33 }
  34 my $last_touch = time;
  35
  36 my(@patches, %local_patch);
  37 if (@ARGV) {
  38     foreach (@ARGV) {
  39         s{^(patches|patch|origin/patch)/} {};
  40         s{\.diff$} {};
  41         push(@patches, $_);
  42     }
  43     open(PIPE, '-|', 'git', 'branch', '-l') or die $!;
  44 } else {
  45     open(PIPE, '-|', 'git', 'branch', '-a') or die $!;
  46 }
  47 while (<PIPE>) {
  48     if (m# origin/patch/(.*)#) {
  49         push(@patches, $1);
  50     } elsif (m# patch/(.*)#) {
  51         $local_patch{$1} = 1;
  52     }
  53 }
  54 close PIPE;
  55
  56 my(%parent, %description);
  57 foreach my $patch (@patches) {
  58     my $branch = ($local_patch{$patch} ? '' : 'origin/') . "patch/$patch";
  59     my $desc = '';
  60     open(PIPE, '-|', 'git', 'diff', '-U1000', "master...$branch", '--', "PATCH.$patch") or die $!;
  61     while (<PIPE>) {
  62         last if /^@@ /;
  63     }
  64     while (<PIPE>) {
  65         next unless s/^[ +]//;
  66         if (m#patch -p1 <patches/(\S+)\.diff# && $1 ne $patch) {
  67             $parent{$patch} = $1;
  68         }
  69         $desc .= $_;
  70     }
  71     $description{$patch} = $desc;
  72 }
  73
  74 my %completed;
  75 foreach my $patch (@patches) {
  76     next if $completed{$patch}++;
  77     update_patch($patch);
  78 }
  79
  80 if ($incl_generated_files) {
  81     system "rm -rf a b";
  82 }
  83
  84 sleep 1 if $last_touch == time;
  85 system "git checkout master";
  86
  87 exit;
  88
  89
  90 sub update_patch
  91 {
  92     my($patch) = @_;
  93
  94     my $parent = $parent{$patch};
  95     if (defined $parent) {
  96         unless ($completed{$parent}++) {
  97             update_patch($parent);
  98         }
  99         $parent = "patch/$parent";
 100     } else {
 101         $parent = 'master';
 102     }
 103
 104     print "======== $patch ========\n";
 105
 106     sleep 1 if $incl_generated_files && $last_touch == time;
 107     if ($local_patch{$patch}) {
 108         system "git checkout patch/$patch" and exit 1;
 109     } else {
 110         system "git checkout --track -b patch/$patch origin/patch/$patch" and exit 1;
 111     }
 112
 113     open(OUT, '>', "patches/$patch.diff") or die $!;
 114     print OUT $description{$patch}, "\n";
 115
 116     if (system("git rebase -m $parent") != 0) {
 117         print qq|"git rebase -m $parent" incomplete -- please fix.\n|;
 118         $ENV{PS1} = "[$parent] patch/$patch: ";
 119         system $ENV{SHELL} and exit 1;
 120     }
 121
 122     if ($incl_generated_files) {
 123         system "make gen && rsync -a @extra_files b/" and exit 1;
 124     }
 125     $last_touch = time;
 126
 127     open(PIPE, '-|', 'git', 'diff', $parent) or die $!;
 128     DIFF: while (<PIPE>) {
 129         while (m{^diff --git a/PATCH}) {
 130             while (<PIPE>) {
 131                 last if m{^diff --git a/};
 132             }
 133             last DIFF if !defined $_;
 134         }
 135         next if /^index /;
 136         print OUT $_;
 137     }
 138     close PIPE;
 139
 140     if ($incl_generated_files) {
 141         open(PIPE, '-|', 'diff', '-up', 'a', 'b') or die $!;
 142         while (<PIPE>) {
 143             s/^((?:---|\+\+\+) [^\t]+)\t.*/$1/;
 144             print OUT $_;
 145         }
 146         close PIPE;
 147     }
 148
 149     close OUT;
 150 }