configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(byteorder.h)
   3 AC_CONFIG_HEADER(config.h)
   4
   5 AC_CANONICAL_SYSTEM
   6 AC_VALIDATE_CACHE_SYSTEM_TYPE
   7
   8 dnl Checks for programs.
   9 AC_PROG_CC
  10 AC_PROG_INSTALL
  11 AC_SUBST(SHELL)
  12
  13 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
  14 AC_DEFINE_UNQUOTED(HAVE_REMSH, $HAVE_REMSH)
  15
  16 AC_C_BIGENDIAN
  17 AC_HEADER_DIRENT
  18 AC_HEADER_TIME
  19 AC_HEADER_SYS_WAIT
  20 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h unistd.h utime.h grp.h)
  21 AC_CHECK_HEADERS(compat.h sys/param.h ctype.h sys/wait.h sys/ioctl.h)
  22 AC_CHECK_HEADERS(sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h)
  23 AC_CHECK_HEADERS(glob.h)
  24
  25 AC_CHECK_SIZEOF(int)
  26 AC_CHECK_SIZEOF(long)
  27 AC_CHECK_SIZEOF(short)
  28
  29 AC_C_INLINE
  30
  31 AC_TYPE_SIGNAL
  32 AC_TYPE_UID_T
  33 AC_TYPE_MODE_T
  34 AC_TYPE_OFF_T
  35 AC_TYPE_SIZE_T
  36 AC_TYPE_PID_T
  37 AC_STRUCT_ST_RDEV
  38 AC_CHECK_TYPE(ino_t,unsigned)
  39
  40 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
  41     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
  42         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
  43 if test x"$rsync_cv_errno" = x"yes"; then
  44    AC_DEFINE(HAVE_ERRNO_DECL)
  45 fi
  46
  47 AC_FUNC_MEMCMP
  48 AC_FUNC_UTIME_NULL
  49 AC_CHECK_FUNCS(mmap munmap waitpid getcwd strdup strerror chown chmod mknod)
  50 AC_CHECK_FUNCS(fchmod fstat strchr readlink link utime utimes strftime)
  51 AC_CHECK_FUNCS(memmove getopt_long lchown vsnprintf snprintf setsid glob strpbrk)
  52
  53 echo $ac_n "checking for working fnmatch... $ac_c"
  54 AC_TRY_RUN([#include <fnmatch.h>
  55 main() { exit(fnmatch("*.o", "x.o", 0) == 0? 0: 1); }],
  56 echo yes;AC_DEFINE(HAVE_FNMATCH),
  57 echo no)
  58
  59 AC_CACHE_CHECK([for long long],rsync_cv_have_longlong,[
  60 AC_TRY_RUN([#include <stdio.h>
  61 main() { long long x = 1000000; x *= x; exit(((x/1000000) == 1000000)? 0: 1); }],
  62 rsync_cv_have_longlong=yes,rsync_cv_have_longlong=no,rsync_cv_have_longlong=cross)])
  63 if test x"$rsync_cv_have_longlong" = x"yes"; then
  64     AC_DEFINE(HAVE_LONGLONG)
  65 fi
  66
  67 AC_CACHE_CHECK([for off64_t],rsync_cv_HAVE_OFF64_T,[
  68 AC_TRY_RUN([#include <stdio.h>
  69 #include <sys/stat.h>
  70 main() { struct stat64 st; off64_t s; if (sizeof(off_t) == sizeof(off64_t)) exit(1); exit((lstat64("/dev/null", &st)==0)?0:1); }],
  71 rsync_cv_HAVE_OFF64_T=yes,rsync_cv_HAVE_OFF64_T=no,rsync_cv_HAVE_OFF64_T=cross)])
  72 if test x"$rsync_cv_HAVE_OFF64_T" = x"yes"; then
  73     AC_DEFINE(HAVE_OFF64_T)
  74 fi
  75
  76 echo $ac_n "checking for short ino_t ... $ac_c"
  77 AC_TRY_RUN([#include <stdio.h>
  78 #include <sys/types.h>
  79 #include <sys/stat.h>
  80 main() { if (sizeof(ino_t) < sizeof(unsigned int)) return 0; return 1; }],
  81 echo yes;AC_DEFINE(HAVE_SHORT_INO_T),
  82 echo no)
  83
  84 AC_CACHE_CHECK([for unsigned char],rsync_cv_HAVE_UNSIGNED_CHAR,[
  85 AC_TRY_RUN([#include <stdio.h>
  86 main() { char c; c=250; exit((c > 0)?0:1); }],
  87 rsync_cv_HAVE_UNSIGNED_CHAR=yes,rsync_cv_HAVE_UNSIGNED_CHAR=no,rsync_cv_HAVE_UNSIGNED_CHAR=cross)])
  88 if test x"$rsync_cv_HAVE_UNSIGNED_CHAR" = x"yes"; then
  89     AC_DEFINE(HAVE_UNSIGNED_CHAR)
  90 fi
  91
  92 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
  93 AC_TRY_RUN([#include <sys/types.h>
  94 #include <dirent.h>
  95 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
  96 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
  97 di->d_name[0] == 0) exit(0); exit(1);} ],
  98 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
  99 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 100     AC_DEFINE(HAVE_BROKEN_READDIR)
 101 fi
 102
 103 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[
 104 AC_TRY_COMPILE([#include <sys/types.h>
 105 #include <utime.h>],
 106 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 107 rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no,rsync_cv_HAVE_UTIMBUF=cross)])
 108 if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then
 109     AC_DEFINE(HAVE_UTIMBUF)
 110 fi
 111
 112 AC_CACHE_CHECK([for broken inet_ntoa],rsync_cv_REPLACE_INET_NTOA,[
 113 AC_TRY_RUN([
 114 #include <stdio.h>
 115 #include <sys/types.h>
 116 #include <netinet/in.h>
 117 #include <arpa/inet.h>
 118 main() { struct in_addr ip; ip.s_addr = 0x12345678;
 119 if (strcmp(inet_ntoa(ip),"18.52.86.120") &&
 120     strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(0); }
 121 exit(1);}],
 122            rsync_cv_REPLACE_INET_NTOA=yes,rsync_cv_REPLACE_INET_NTOA=no,rsync_cv_REPLACE_INET_NTOA=cross)])
 123 if test x"$rsync_cv_REPLACE_INET_NTOA" = x"yes"; then
 124     AC_DEFINE(REPLACE_INET_NTOA)
 125 fi
 126
 127 # The following test taken from the cvs sources
 128 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 129 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 130 # libsocket.so which has a bad implementation of gethostbyname (it
 131 # only looks in /etc/hosts), so we only look for -lsocket if we need
 132 # it.
 133 AC_CHECK_FUNCS(connect)
 134 if test x"$ac_cv_func_connect" = x"no"; then
 135     case "$LIBS" in
 136     *-lnsl*) ;;
 137     *) AC_CHECK_LIB(nsl_s, printf) ;;
 138     esac
 139     case "$LIBS" in
 140     *-lnsl*) ;;
 141     *) AC_CHECK_LIB(nsl, printf) ;;
 142     esac
 143     case "$LIBS" in
 144     *-lsocket*) ;;
 145     *) AC_CHECK_LIB(socket, connect) ;;
 146     esac
 147     case "$LIBS" in
 148     *-linet*) ;;
 149     *) AC_CHECK_LIB(inet, connect) ;;
 150     esac
 151     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 152     dnl has been cached.
 153     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 154        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 155         # ac_cv_func_connect=yes
 156         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 157         AC_DEFINE(HAVE_CONNECT)
 158     fi
 159 fi
 160
 161 #
 162 # The following test was mostly taken from the tcl/tk plus patches
 163 #
 164 echo $ac_n "checking whether -c -o works ... $ac_c"
 165 rm -rf conftest*
 166 cat > conftest.$ac_ext <<EOF
 167 int main() { return 0; }
 168 EOF
 169 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 170 if test -f conftest..o; then
 171     OBJ_SAVE="#"
 172     OBJ_RESTORE="#"
 173     CC_SHOBJ_FLAG='-o $@'
 174     echo yes
 175 else
 176     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 177     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 178     CC_SHOBJ_FLAG=""
 179     echo no
 180 fi
 181 rm -rf conftest*
 182 AC_SUBST(OBJ_SAVE)
 183 AC_SUBST(OBJ_RESTORE)
 184 AC_SUBST(CC_SHOBJ_FLAG)
 185
 186
 187 AC_OUTPUT(Makefile lib/dummy zlib/dummy)