support/rrsync

   1 #!/usr/bin/perl
   2 # Name: /usr/local/bin/rrsync (should also have a symlink in /usr/bin)
   3 # Purpose: Restricts rsync to subdirectory declared in .ssh/authorized_keys
   4 # Author: Joe Smith <js-cgi@inwap.com> 30-Sep-2004
   5 # Modified by: Wayne Davison <wayned@samba.org>
   6 use strict;
   7
   8 use Socket;
   9 use Cwd 'abs_path';
  10 use File::Glob ':glob';
  11
  12 # You may configure these values to your liking.  See also the section
  13 # of options if you want to disable any options that rsync accepts.
  14 use constant RSYNC => '/usr/bin/rsync';
  15 use constant LOGFILE => 'rrsync.log';
  16
  17 my $Usage = <<EOM;
  18 Use 'command="$0 [-ro] SUBDIR"'
  19         in front of lines in $ENV{HOME}/.ssh/authorized_keys
  20 EOM
  21
  22 our $ro = (@ARGV && $ARGV[0] eq '-ro') ? shift : '';    # -ro = Read-Only
  23 our $subdir = shift;
  24 die "$0: No subdirectory specified\n$Usage" unless defined $subdir;
  25 $subdir = abs_path($subdir);
  26 die "$0: Restricted directory does not exist!\n" if $subdir ne '/' && !-d $subdir;
  27
  28 # The client uses "rsync -av -e ssh src/ server:dir/", and sshd on the server
  29 # executes this program when .ssh/authorized_keys has 'command="..."'.
  30 # For example:
  31 # command="rrsync logs/client" ssh-rsa AAAAB3NzaC1yc2EAAAABIwAAAIEAzGhEeNlPr...
  32 # command="rrsync -ro results" ssh-rsa AAAAB3NzaC1yc2EAAAABIwAAAIEAmkHG1WCjC...
  33 #
  34 # Format of the envrionment variables set by sshd:
  35 # SSH_ORIGINAL_COMMAND=rsync --server          -vlogDtpr --partial . ARG # push
  36 # SSH_ORIGINAL_COMMAND=rsync --server --sender -vlogDtpr --partial . ARGS # pull
  37 # SSH_CONNECTION=client_addr client_port server_port
  38
  39 my $command = $ENV{SSH_ORIGINAL_COMMAND};
  40 die "$0: Not invoked via sshd\n$Usage"  unless defined $command;
  41 die "$0: SSH_ORIGINAL_COMMAND='$command' is not rsync\n" unless $command =~ s/^rsync\s+//;
  42 die "$0: --server option is not first\n" unless $command =~ /^--server\s/;
  43 our $am_sender = $command =~ /^--server\s+--sender\s/; # Restrictive on purpose!
  44 die "$0 -ro: sending to read-only server not allowed\n" if $ro && !$am_sender;
  45
  46 ### START of options data produced by the cull_options script. ###
  47
  48 # These options are the only options that rsync might send to the server,
  49 # and only in the option format that the stock rsync produces.
  50
  51 # To disable a short-named option, add its letter to this string:
  52 our $short_disabled = 's';
  53
  54 our $short_no_arg = 'ACDEHIKLORSWXbcdgklmnoprstuvxz'; # DO NOT REMOVE ANY
  55 our $short_with_num = 'B'; # DO NOT REMOVE ANY
  56
  57 # To disable a long-named option, change its value to a -1.  The values mean:
  58 # 0 = the option has no arg; 1 = the arg doesn't need any checking; 2 = only
  59 # check the arg when receiving; and 3 = always check the arg.
  60 our %long_opt = (
  61   'append' => 0,
  62   'backup-dir' => 2,
  63   'bwlimit' => 1,
  64   'checksum-seed' => 1,
  65   'compare-dest' => 2,
  66   'compress-level' => 1,
  67   'copy-dest' => 2,
  68   'copy-unsafe-links' => 0,
  69   'daemon' => -1,
  70   'delay-updates' => 0,
  71   'delete' => 0,
  72   'delete-after' => 0,
  73   'delete-before' => 0,
  74   'delete-delay' => 0,
  75   'delete-during' => 0,
  76   'delete-excluded' => 0,
  77   'delete-missing-args' => 0,
  78   'existing' => 0,
  79   'fake-super' => 0,
  80   'files-from' => 3,
  81   'force' => 0,
  82   'from0' => 0,
  83   'fuzzy' => 0,
  84   'groupmap' => 1,
  85   'iconv' => 1,
  86   'ignore-errors' => 0,
  87   'ignore-existing' => 0,
  88   'ignore-missing-args' => 0,
  89   'inplace' => 0,
  90   'link-dest' => 2,
  91   'list-only' => 0,
  92   'log-file' => 3,
  93   'log-format' => 1,
  94   'max-delete' => 1,
  95   'max-size' => 1,
  96   'min-size' => 1,
  97   'modify-window' => 1,
  98   'no-implied-dirs' => 0,
  99   'no-r' => 0,
 100   'no-relative' => 0,
 101   'no-specials' => 0,
 102   'numeric-ids' => 0,
 103   'only-write-batch' => 1,
 104   'partial' => 0,
 105   'partial-dir' => 2,
 106   'remove-sent-files' => $ro ? -1 : 0,
 107   'remove-source-files' => $ro ? -1 : 0,
 108   'safe-links' => 0,
 109   'sender' => 0,
 110   'server' => 0,
 111   'size-only' => 0,
 112   'skip-compress' => 1,
 113   'specials' => 0,
 114   'stats' => 0,
 115   'suffix' => 1,
 116   'super' => 0,
 117   'temp-dir' => 2,
 118   'timeout' => 1,
 119   'use-qsort' => 0,
 120   'usermap' => 1,
 121 );
 122
 123 ### END of options data produced by the cull_options script. ###
 124
 125 if ($short_disabled ne '') {
 126     $short_no_arg =~ s/[$short_disabled]//go;
 127     $short_with_num =~ s/[$short_disabled]//go;
 128 }
 129 $short_no_arg = "[$short_no_arg]" if length($short_no_arg) > 1;
 130 $short_with_num = "[$short_with_num]" if length($short_with_num) > 1;
 131
 132 my $write_log = -f LOGFILE && open(LOG, '>>', LOGFILE);
 133
 134 chdir($subdir) or die "$0: Unable to chdir to restricted dir: $!\n";
 135
 136 my(@opts, @args);
 137 my $in_options = 1;
 138 my $last_opt = '';
 139 my $check_type;
 140 while ($command =~ /((?:[^\s\\]+|\\.[^\s\\]*)+)/g) {
 141   $_ = $1;
 142   if ($check_type) {
 143     push(@opts, check_arg($last_opt, $_, $check_type));
 144     $check_type = 0;
 145   } elsif ($in_options) {
 146     push(@opts, $_);
 147     if ($_ eq '.') {
 148       $in_options = 0;
 149     } else {
 150       die "$0: invalid option: '-'\n" if $_ eq '-';
 151       next if /^-$short_no_arg*(e\d*\.\w*)?$/o || /^-$short_with_num\d+$/o;
 152
 153       my($opt,$arg) = /^--([^=]+)(?:=(.*))?$/;
 154       my $disabled;
 155       if (defined $opt) {
 156         my $ct = $long_opt{$opt};
 157         last unless defined $ct;
 158         next if $ct == 0;
 159         if ($ct > 0) {
 160           if (!defined $arg) {
 161             $check_type = $ct;
 162             $last_opt = $opt;
 163             next;
 164           }
 165           $arg = check_arg($opt, $arg, $ct);
 166           $opts[-1] =~ s/=.*/=$arg/;
 167           next;
 168         }
 169         $disabled = 1;
 170         $opt = "--$opt";
 171       } elsif ($short_disabled ne '') {
 172         $disabled = /^-$short_no_arg*([$short_disabled])/o;
 173         $opt = "-$1";
 174       }
 175
 176       last unless $disabled; # Generate generic failure
 177       die "$0: option $opt has been disabled on this server.\n";
 178     }
 179   } else {
 180     if ($subdir ne '/') {
 181       # Validate args to ensure they don't try to leave our restricted dir.
 182       s{//+}{/}g;
 183       s{^/}{};
 184       s{^$}{.};
 185       die "$0: do not use .. in any path!\n" if m{(^|/)\\?\.\\?\.(\\?/|$)};
 186     }
 187     push(@args, bsd_glob($_, GLOB_LIMIT|GLOB_NOCHECK|GLOB_BRACE|GLOB_QUOTE));
 188   }
 189 }
 190 die "$0: invalid rsync-command syntax or options\n" if $in_options;
 191
 192 @args = ( '.' ) if !@args;
 193
 194 if ($write_log) {
 195   my ($mm,$hh) = (localtime)[1,2];
 196   my $host = $ENV{SSH_CONNECTION} || 'unknown';
 197   $host =~ s/ .*//; # Keep only the client's IP addr
 198   $host =~ s/^::ffff://;
 199   $host = gethostbyaddr(inet_aton($host),AF_INET) || $host;
 200   printf LOG "%02d:%02d %-13s [%s]\n", $hh, $mm, $host, "@opts @args";
 201   close LOG;
 202 }
 203
 204 # Note: This assumes that the rsync protocol will not be maliciously hijacked.
 205 exec(RSYNC, @opts, @args) or die "exec(rsync @opts @args) failed: $? $!";
 206
 207 sub check_arg
 208 {
 209   my($opt, $arg, $type) = @_;
 210   $arg =~ s/\\(.)/$1/g;
 211   if ($subdir ne '/' && ($type == 3 || ($type == 2 && !$am_sender))) {
 212     $arg =~ s{//}{/}g;
 213     die "Do not use .. in --$opt; anchor the path at the root of your restricted dir.\n"
 214       if $arg =~ m{(^|/)\.\.(/|$)};
 215     $arg =~ s{^/}{$subdir/};
 216   }
 217   $arg;
 218 }