configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT()
   4 AC_CONFIG_SRCDIR([byteorder.h])
   5 AC_CONFIG_HEADER(config.h)
   6 AC_PREREQ(2.52)
   7
   8 RSYNC_VERSION=2.5.1-dev
   9 AC_SUBST(RSYNC_VERSION)
  10 AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION])
  11
  12 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
  13
  14 LDFLAGS=${LDFLAGS-""}
  15
  16 AC_CANONICAL_TARGET([])
  17
  18 dnl Checks for programs.
  19 AC_PROG_CC
  20 AC_PROG_CPP
  21 AC_PROG_INSTALL
  22 AC_PROG_CC_STDC
  23 AC_SUBST(SHELL)
  24
  25 AC_DEFINE([_GNU_SOURCE], 1,
  26           [Define _GNU_SOURCE so that we get all necessary prototypes])
  27
  28 if test "$xac_cv_prog_cc_stdc" = xno
  29 then
  30         AC_MSG_WARN([rsync requires an ANSI C compiler and you don't seem to have one])
  31 fi
  32
  33 # compile with optimisation and without debugging by default, unless
  34 # --debug is given.  We must decide this before testing the compiler.
  35
  36 # Please allow this to default to yes, so that your users have more
  37 # chance of getting a useful stack trace if problems occur.
  38
  39 AC_MSG_CHECKING([whether to include debugging symbols])
  40 AC_ARG_ENABLE(debug,
  41         AC_HELP_STRING([--enable-debug],
  42                 [including debugging symbols and features (default yes)]),
  43                 [], [])
  44
  45 if test x"$enable_debug" = x"no"
  46 then
  47     AC_MSG_RESULT(no)
  48     CFLAGS=${CFLAGS-"-O"}
  49 else
  50     AC_MSG_RESULT([yes])
  51     # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can
  52     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  53     dnl CFLAGS=${CFLAGS-"-g"}
  54 fi
  55
  56
  57
  58
  59 AC_ARG_ENABLE(profile,
  60         AC_HELP_STRING([--enable-profile],
  61                 [turn on CPU profiling (default no)],
  62                 [], []))
  63 if test x"$enable_profile" = xyes
  64 then
  65         CFLAGS="$CFLAGS -pg"
  66 fi
  67
  68
  69 # This is needed for our included version of popt.  Kind of silly, but
  70 # I don't want our version too far out of sync.
  71 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  72
  73 # If GCC, turn on warnings.
  74 if test "x$GCC" = "xyes"
  75 then
  76         CFLAGS="$CFLAGS -Wall -W"
  77 fi
  78
  79 AC_ARG_WITH(included-popt,
  80         [  --with-included-popt    use bundled popt library, not from system])
  81
  82 AC_ARG_WITH(rsync-path,
  83         [  --with-rsync-path=PATH  set default --rsync-path to PATH (default: \"rsync\")],
  84         [ RSYNC_PATH="$with_rsync_path" ],
  85         [ RSYNC_PATH="rsync" ])
  86 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [ ])
  87
  88 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
  89 AC_DEFINE_UNQUOTED(HAVE_REMSH, $HAVE_REMSH, [ ])
  90
  91
  92 # arrgh. libc in the current debian stable screws up the largefile
  93 # stuff, getting byte range locking wrong
  94 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
  95 AC_TRY_RUN([
  96 #define _FILE_OFFSET_BITS 64
  97 #include <stdio.h>
  98 #include <fcntl.h>
  99 #include <sys/types.h>
 100 #include <sys/wait.h>
 101
 102 int main(void)
 103 {
 104         struct flock lock;
 105         int status;
 106         int fd = open("conftest.dat", O_CREAT|O_RDWR, 0600);
 107         lock.l_type = F_WRLCK;
 108         lock.l_whence = SEEK_SET;
 109         lock.l_start = 0;
 110         lock.l_len = 1;
 111         lock.l_pid = 0;
 112
 113         fcntl(fd,F_SETLK,&lock);
 114         if (fork() == 0) {
 115                 lock.l_start = 1;
 116                 exit(fcntl(fd,F_SETLK,&lock) == 0);
 117         }
 118         wait(&status);
 119         unlink("conftest.dat");
 120         exit(WEXITSTATUS(status));
 121 }
 122 ],
 123 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
 124 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 125    AC_SYS_LARGEFILE
 126 fi
 127
 128 ipv6type=unknown
 129 ipv6lib=none
 130 ipv6trylibc=yes
 131
 132 AC_ARG_ENABLE(ipv6,
 133         AC_HELP_STRING([--disable-ipv6], [don't even try to use IPv6]))
 134
 135 if test "x$enable_ipv6" != xno
 136 then
 137         AC_MSG_CHECKING([ipv6 stack type])
 138         for i in inria kame linux-glibc linux-inet6 toshiba v6d zeta; do
 139                 case $i in
 140                 inria)
 141                         # http://www.kame.net/
 142                         AC_EGREP_CPP(yes, [
 143 #include <netinet/in.h>
 144 #ifdef IPV6_INRIA_VERSION
 145 yes
 146 #endif],
 147                                 [ipv6type=$i;
 148                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 149                                 ])
 150                         ;;
 151                 kame)
 152                         # http://www.kame.net/
 153                         AC_EGREP_CPP(yes, [
 154 #include <netinet/in.h>
 155 #ifdef __KAME__
 156 yes
 157 #endif],
 158                                 [ipv6type=$i;
 159                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 160                         ;;
 161                 linux-glibc)
 162                         # http://www.v6.linux.or.jp/
 163                         AC_EGREP_CPP(yes, [
 164 #include <features.h>
 165 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 166 yes
 167 #endif],
 168                                 [ipv6type=$i;
 169 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 170                         ;;
 171                 linux-inet6)
 172                         # http://www.v6.linux.or.jp/
 173                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 174                                 ipv6type=$i
 175                                 ipv6lib=inet6
 176                                 ipv6libdir=/usr/inet6/lib
 177                                 ipv6trylibc=yes;
 178                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 179                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 180                         fi
 181                         ;;
 182                 toshiba)
 183                         AC_EGREP_CPP(yes, [
 184 #include <sys/param.h>
 185 #ifdef _TOSHIBA_INET6
 186 yes
 187 #endif],
 188                                 [ipv6type=$i;
 189                                 ipv6lib=inet6;
 190                                 ipv6libdir=/usr/local/v6/lib;
 191                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 192                         ;;
 193                 v6d)
 194                         AC_EGREP_CPP(yes, [
 195 #include </usr/local/v6/include/sys/v6config.h>
 196 #ifdef __V6D__
 197 yes
 198 #endif],
 199                                 [ipv6type=$i;
 200                                 ipv6lib=v6;
 201                                 ipv6libdir=/usr/local/v6/lib;
 202                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 203                         ;;
 204                 zeta)
 205                         AC_EGREP_CPP(yes, [
 206 #include <sys/param.h>
 207 #ifdef _ZETA_MINAMI_INET6
 208 yes
 209 #endif],
 210                                 [ipv6type=$i;
 211                                 ipv6lib=inet6;
 212                                 ipv6libdir=/usr/local/v6/lib;
 213                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 214                         ;;
 215                 esac
 216                 if test "$ipv6type" != "unknown"; then
 217                         break
 218                 fi
 219         done
 220         AC_MSG_RESULT($ipv6type)
 221
 222         AC_SEARCH_LIBS(getaddrinfo, inet6)
 223 fi
 224
 225 AC_C_BIGENDIAN
 226 AC_HEADER_DIRENT
 227 AC_HEADER_TIME
 228 AC_HEADER_SYS_WAIT
 229 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h unistd.h utime.h grp.h)
 230 AC_CHECK_HEADERS(compat.h sys/param.h ctype.h sys/wait.h sys/ioctl.h)
 231 AC_CHECK_HEADERS(sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h)
 232 AC_CHECK_HEADERS(glob.h alloca.h mcheck.h sys/sysctl.h arpa/inet.h arpa/nameser.h)
 233 AC_CHECK_HEADERS(netdb.h)
 234 AC_CHECK_HEADERS(malloc.h)
 235
 236 AC_CHECK_SIZEOF(int)
 237 AC_CHECK_SIZEOF(long)
 238 AC_CHECK_SIZEOF(short)
 239
 240 AC_C_INLINE
 241
 242 AC_TYPE_SIGNAL
 243 AC_TYPE_UID_T
 244 AC_TYPE_MODE_T
 245 AC_TYPE_OFF_T
 246 AC_TYPE_SIZE_T
 247 AC_TYPE_PID_T
 248 AC_TYPE_GETGROUPS
 249 AC_CHECK_MEMBERS([struct stat.st_rdev])
 250
 251 AC_CHECK_TYPE([ino_t], [unsigned])
 252 TYPE_SOCKLEN_T
 253
 254 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 255     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
 256         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
 257 if test x"$rsync_cv_errno" = x"yes"; then
 258    AC_DEFINE(HAVE_ERRNO_DECL, 1, [ ])
 259 fi
 260
 261 # The following test taken from the cvs sources
 262 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 263 # These need checks to be before checks for any other functions that
 264 #    might be in the same libraries.
 265 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 266 # libsocket.so which has a bad implementation of gethostbyname (it
 267 # only looks in /etc/hosts), so we only look for -lsocket if we need
 268 # it.
 269 AC_CHECK_FUNCS(connect)
 270 if test x"$ac_cv_func_connect" = x"no"; then
 271     case "$LIBS" in
 272     *-lnsl*) ;;
 273     *) AC_CHECK_LIB(nsl_s, printf) ;;
 274     esac
 275     case "$LIBS" in
 276     *-lnsl*) ;;
 277     *) AC_CHECK_LIB(nsl, printf) ;;
 278     esac
 279     case "$LIBS" in
 280     *-lsocket*) ;;
 281     *) AC_CHECK_LIB(socket, connect) ;;
 282     esac
 283     case "$LIBS" in
 284     *-linet*) ;;
 285     *) AC_CHECK_LIB(inet, connect) ;;
 286     esac
 287     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 288     dnl has been cached.
 289     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 290        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 291         # ac_cv_func_connect=yes
 292         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 293         AC_DEFINE(HAVE_CONNECT, 1, [ ])
 294     fi
 295 fi
 296
 297 AC_CHECK_LIB(resolv, inet_ntop)
 298
 299 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 300
 301 AC_CHECK_FUNCS(inet_ntop, , AC_LIBOBJ(lib/inet_ntop))
 302 AC_CHECK_FUNCS(inet_pton, , AC_LIBOBJ(lib/inet_pton))
 303
 304 AC_CHECK_FUNCS(getaddrinfo, , AC_LIBOBJ(lib/getaddrinfo))
 305 AC_CHECK_FUNCS(getnameinfo, , AC_LIBOBJ(lib/getnameinfo))
 306
 307 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 308                 [ AC_DEFINE(HAVE_SOCKADDR_LEN) ],
 309                 [],
 310                 [
 311 #include <sys/types.h>
 312 #include <sys/socket.h>
 313 ])
 314
 315 AC_MSG_CHECKING(struct sockaddr_storage)
 316 AC_TRY_COMPILE([#include <sys/types.h>
 317 #include <sys/socket.h>],
 318 [struct sockaddr_storage x;],
 319         AC_MSG_RESULT(yes)
 320         AC_DEFINE(HAVE_SOCKADDR_STORAGE, 1,
 321                 [Define if you have strct sockaddr_storage.] ),
 322         AC_MSG_RESULT(no))
 323
 324 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 325 #
 326 AC_CHECK_FUNCS(strcasecmp)
 327 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 328     AC_CHECK_LIB(resolv, strcasecmp)
 329 fi
 330
 331 dnl At the moment we don't test for a broken memcmp(), because all we
 332 dnl need to do is test for equality, not comparison, and it seems that
 333 dnl every platform has a memcmp that can do at least that.
 334 dnl AC_FUNC_MEMCMP
 335
 336 AC_FUNC_UTIME_NULL
 337 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup strerror chown chmod mknod)
 338 AC_CHECK_FUNCS(fchmod fstat strchr readlink link utime utimes strftime)
 339 AC_CHECK_FUNCS(memmove lchown vsnprintf snprintf asprintf setsid glob strpbrk)
 340 AC_CHECK_FUNCS(strlcat strlcpy mtrace mallinfo)
 341
 342 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 343 AC_TRY_RUN([
 344 #include <sys/types.h>
 345 #include <sys/socket.h>
 346
 347 main() {
 348        int fd[2];
 349        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 350 }],
 351 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
 352 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 353     AC_DEFINE(HAVE_SOCKETPAIR, 1, [ ])
 354 fi
 355
 356 AC_CACHE_CHECK([for working fnmatch],rsync_cv_HAVE_FNMATCH,[
 357 AC_TRY_RUN([#include <fnmatch.h>
 358 main() { exit((fnmatch("*.o", "x.o", FNM_PATHNAME) == 0 &&
 359                fnmatch("a/b/*", "a/b/c/d", FNM_PATHNAME) != 0) ? 0: 1); }],
 360 rsync_cv_HAVE_FNMATCH=yes,rsync_cv_HAVE_FNMATCH=no,rsync_cv_HAVE_FNMATCH=cross)])
 361 if test x"$rsync_cv_HAVE_FNMATCH" = x"yes"; then
 362     AC_DEFINE(HAVE_FNMATCH, 1, [ ])
 363 fi
 364
 365 if test x"$with_included_popt" != x"yes"
 366 then
 367     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 368 fi
 369
 370 AC_MSG_CHECKING([whether to use included libpopt])
 371 if test x"$with_included_popt" = x"yes"
 372 then
 373     AC_MSG_RESULT($srcdir/popt)
 374     BUILD_POPT='$(popt_OBJS)'
 375     CFLAGS="$CFLAGS -I$srcdir/popt"
 376 else
 377     AC_MSG_RESULT(no)
 378 fi
 379
 380 AC_CACHE_CHECK([for long long],rsync_cv_HAVE_LONGLONG,[
 381 AC_TRY_RUN([#include <stdio.h>
 382 main() { long long x = 1000000; x *= x; exit(((x/1000000) == 1000000)? 0: 1); }],
 383 rsync_cv_HAVE_LONGLONG=yes,rsync_cv_HAVE_LONGLONG=no,rsync_cv_HAVE_LONGLONG=cross)])
 384 if test x"$rsync_cv_HAVE_LONGLONG" = x"yes"; then
 385     AC_DEFINE(HAVE_LONGLONG, 1, [ ])
 386 fi
 387
 388 AC_CACHE_CHECK([for off64_t],rsync_cv_HAVE_OFF64_T,[
 389 AC_TRY_RUN([#include <stdio.h>
 390 #include <sys/stat.h>
 391 main() { struct stat64 st; off64_t s; if (sizeof(off_t) == sizeof(off64_t)) exit(1); exit((lstat64("/dev/null", &st)==0)?0:1); }],
 392 rsync_cv_HAVE_OFF64_T=yes,rsync_cv_HAVE_OFF64_T=no,rsync_cv_HAVE_OFF64_T=cross)])
 393 if test x"$rsync_cv_HAVE_OFF64_T" = x"yes"; then
 394     AC_DEFINE(HAVE_OFF64_T, 1, [ ])
 395 fi
 396
 397 AC_CACHE_CHECK([for short ino_t],rsync_cv_HAVE_SHORT_INO_T,[
 398 AC_TRY_RUN([#include <stdio.h>
 399 #include <sys/types.h>
 400 #include <sys/stat.h>
 401 main() { if (sizeof(ino_t) < sizeof(unsigned int)) return 0; return 1; }],
 402 rsync_cv_HAVE_SHORT_INO_T=yes,rsync_cv_HAVE_SHORT_INO_T=no,rsync_cv_HAVE_SHORT_INO_T=cross)])
 403 if test x"$rsync_cv_HAVE_SHORT_INO_T" = x"yes"; then
 404     AC_DEFINE(HAVE_SHORT_INO_T, 1, [ ])
 405 fi
 406
 407 AC_CACHE_CHECK([for unsigned char],rsync_cv_HAVE_UNSIGNED_CHAR,[
 408 AC_TRY_RUN([#include <stdio.h>
 409 main() { char c; c=250; exit((c > 0)?0:1); }],
 410 rsync_cv_HAVE_UNSIGNED_CHAR=yes,rsync_cv_HAVE_UNSIGNED_CHAR=no,rsync_cv_HAVE_UNSIGNED_CHAR=cross)])
 411 if test x"$rsync_cv_HAVE_UNSIGNED_CHAR" = x"yes"; then
 412     AC_DEFINE(HAVE_UNSIGNED_CHAR, 1, [ ])
 413 fi
 414
 415 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 416 AC_TRY_RUN([#include <sys/types.h>
 417 #include <dirent.h>
 418 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 419 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 420 di->d_name[0] == 0) exit(0); exit(1);} ],
 421 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 422 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 423     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [ ])
 424 fi
 425
 426 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[
 427 AC_TRY_COMPILE([#include <sys/types.h>
 428 #include <utime.h>],
 429 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 430 rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no,rsync_cv_HAVE_UTIMBUF=cross)])
 431 if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then
 432     AC_DEFINE(HAVE_UTIMBUF, 1, [ ])
 433 fi
 434
 435 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 436 AC_TRY_RUN([
 437 #include <sys/time.h>
 438 #include <unistd.h>
 439 main() { struct timeval tv; exit(gettimeofday(&tv, NULL));}],
 440            rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no,rsync_cv_HAVE_GETTIMEOFDAY_TZ=cross)])
 441 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" = x"yes"; then
 442     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [ ])
 443 fi
 444
 445 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 446 AC_TRY_RUN([
 447 #include <sys/types.h>
 448 #include <stdarg.h>
 449 void foo(const char *format, ...) {
 450        va_list ap;
 451        int len;
 452        char buf[5];
 453
 454        va_start(ap, format);
 455        len = vsnprintf(0, 0, format, ap);
 456        va_end(ap);
 457        if (len != 5) exit(1);
 458
 459        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 460
 461        exit(0);
 462 }
 463 main() { foo("hello"); }
 464 ],
 465 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
 466 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 467     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [ ])
 468 fi
 469
 470
 471 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 472 AC_TRY_RUN([#include <stdlib.h>
 473 #include <sys/types.h>
 474 #include <sys/stat.h>
 475 #include <unistd.h>
 476 main() {
 477   struct stat st;
 478   char tpl[20]="/tmp/test.XXXXXX";
 479   int fd = mkstemp(tpl);
 480   if (fd == -1) exit(1);
 481   unlink(tpl);
 482   if (fstat(fd, &st) != 0) exit(1);
 483   if ((st.st_mode & 0777) != 0600) exit(1);
 484   exit(0);
 485 }],
 486 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
 487 rsync_cv_HAVE_SECURE_MKSTEMP=no,
 488 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
 489 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 490     AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [ ])
 491 fi
 492
 493
 494 AC_CACHE_CHECK([for broken inet_ntoa],rsync_cv_REPLACE_INET_NTOA,[
 495 AC_TRY_RUN([
 496 #include <stdio.h>
 497 #include <sys/types.h>
 498 #include <netinet/in.h>
 499 #include <arpa/inet.h>
 500 main() { struct in_addr ip; ip.s_addr = 0x12345678;
 501 if (strcmp(inet_ntoa(ip),"18.52.86.120") &&
 502     strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(1); }
 503 exit(0);}],
 504            rsync_cv_REPLACE_INET_NTOA=no,rsync_cv_REPLACE_INET_NTOA=yes,rsync_cv_REPLACE_INET_NTOA=cross)])
 505 if test x"$rsync_cv_REPLACE_INET_NTOA" = x"yes"; then
 506     AC_DEFINE(REPLACE_INET_NTOA, 1, [ ])
 507 fi
 508
 509
 510 AC_CACHE_CHECK([for broken inet_aton],rsync_cv_REPLACE_INET_ATON,[
 511 AC_TRY_RUN([
 512 #include <stdio.h>
 513 #include <sys/types.h>
 514 #include <netinet/in.h>
 515 #include <arpa/inet.h>
 516 main() { struct in_addr ip;
 517 if (inet_aton("example", &ip) == 0) exit(0); exit(1);}],
 518            rsync_cv_REPLACE_INET_ATON=no,rsync_cv_REPLACE_INET_ATON=yes,rsync_cv_REPLACE_INET_ATON=cross)])
 519 if test x"$rsync_cv_REPLACE_INET_ATON" = x"yes"; then
 520     AC_DEFINE(REPLACE_INET_ATON, 1, [ ])
 521 fi
 522
 523 #
 524 # The following test was mostly taken from the tcl/tk plus patches
 525 #
 526 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 527 rm -rf conftest*
 528 cat > conftest.$ac_ext <<EOF
 529 int main() { return 0; }
 530 EOF
 531 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 532 if test -f conftest..o; then
 533     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 534 else
 535     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 536 fi
 537 rm -rf conftest*
 538 ])
 539 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 540     OBJ_SAVE="#"
 541     OBJ_RESTORE="#"
 542     CC_SHOBJ_FLAG='-o $@'
 543 else
 544     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 545     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 546     CC_SHOBJ_FLAG=""
 547 fi
 548
 549 AC_SUBST(OBJ_SAVE)
 550 AC_SUBST(OBJ_RESTORE)
 551 AC_SUBST(CC_SHOBJ_FLAG)
 552 AC_SUBST(BUILD_POPT)
 553
 554 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
 555 AC_OUTPUT