configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(byteorder.h)
   3 AC_CONFIG_HEADER(config.h)
   4
   5 # compile with optimisation and without debugging by default
   6 CFLAGS=${CFLAGS-"-O"}
   7
   8 AC_CANONICAL_SYSTEM
   9 AC_VALIDATE_CACHE_SYSTEM_TYPE
  10
  11 dnl Checks for programs.
  12 AC_PROG_CC
  13 AC_PROG_INSTALL
  14 AC_SUBST(SHELL)
  15
  16 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
  17 AC_DEFINE_UNQUOTED(HAVE_REMSH, $HAVE_REMSH)
  18
  19 AC_C_BIGENDIAN
  20 AC_HEADER_DIRENT
  21 AC_HEADER_TIME
  22 AC_HEADER_SYS_WAIT
  23 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h unistd.h utime.h grp.h)
  24 AC_CHECK_HEADERS(compat.h sys/param.h ctype.h sys/wait.h sys/ioctl.h)
  25 AC_CHECK_HEADERS(sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h)
  26 AC_CHECK_HEADERS(glob.h)
  27
  28 AC_CHECK_SIZEOF(int)
  29 AC_CHECK_SIZEOF(long)
  30 AC_CHECK_SIZEOF(short)
  31
  32 AC_C_INLINE
  33
  34 AC_TYPE_SIGNAL
  35 AC_TYPE_UID_T
  36 AC_TYPE_MODE_T
  37 AC_TYPE_OFF_T
  38 AC_TYPE_SIZE_T
  39 AC_TYPE_PID_T
  40 AC_TYPE_GETGROUPS
  41 AC_STRUCT_ST_RDEV
  42 AC_CHECK_TYPE(ino_t,unsigned)
  43
  44 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
  45     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
  46         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
  47 if test x"$rsync_cv_errno" = x"yes"; then
  48    AC_DEFINE(HAVE_ERRNO_DECL)
  49 fi
  50
  51 AC_FUNC_MEMCMP
  52 AC_FUNC_UTIME_NULL
  53 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup strerror chown chmod mknod)
  54 AC_CHECK_FUNCS(fchmod fstat strchr readlink link utime utimes strftime)
  55 AC_CHECK_FUNCS(memmove getopt_long lchown vsnprintf snprintf setsid glob strpbrk)
  56 AC_CHECK_FUNCS(strlcat strlcpy)
  57
  58 echo $ac_n "checking for working fnmatch... $ac_c"
  59 AC_TRY_RUN([#include <fnmatch.h>
  60 main() { exit(fnmatch("*.o", "x.o", FNM_PATHNAME) == 0? 0: 1); }],
  61 echo yes;AC_DEFINE(HAVE_FNMATCH),
  62 echo no)
  63
  64 AC_CACHE_CHECK([for long long],rsync_cv_have_longlong,[
  65 AC_TRY_RUN([#include <stdio.h>
  66 main() { long long x = 1000000; x *= x; exit(((x/1000000) == 1000000)? 0: 1); }],
  67 rsync_cv_have_longlong=yes,rsync_cv_have_longlong=no,rsync_cv_have_longlong=cross)])
  68 if test x"$rsync_cv_have_longlong" = x"yes"; then
  69     AC_DEFINE(HAVE_LONGLONG)
  70 fi
  71
  72 AC_CACHE_CHECK([for off64_t],rsync_cv_HAVE_OFF64_T,[
  73 AC_TRY_RUN([#include <stdio.h>
  74 #include <sys/stat.h>
  75 main() { struct stat64 st; off64_t s; if (sizeof(off_t) == sizeof(off64_t)) exit(1); exit((lstat64("/dev/null", &st)==0)?0:1); }],
  76 rsync_cv_HAVE_OFF64_T=yes,rsync_cv_HAVE_OFF64_T=no,rsync_cv_HAVE_OFF64_T=cross)])
  77 if test x"$rsync_cv_HAVE_OFF64_T" = x"yes"; then
  78     AC_DEFINE(HAVE_OFF64_T)
  79 fi
  80
  81 echo $ac_n "checking for short ino_t ... $ac_c"
  82 AC_TRY_RUN([#include <stdio.h>
  83 #include <sys/types.h>
  84 #include <sys/stat.h>
  85 main() { if (sizeof(ino_t) < sizeof(unsigned int)) return 0; return 1; }],
  86 echo yes;AC_DEFINE(HAVE_SHORT_INO_T),
  87 echo no)
  88
  89 AC_CACHE_CHECK([for unsigned char],rsync_cv_HAVE_UNSIGNED_CHAR,[
  90 AC_TRY_RUN([#include <stdio.h>
  91 main() { char c; c=250; exit((c > 0)?0:1); }],
  92 rsync_cv_HAVE_UNSIGNED_CHAR=yes,rsync_cv_HAVE_UNSIGNED_CHAR=no,rsync_cv_HAVE_UNSIGNED_CHAR=cross)])
  93 if test x"$rsync_cv_HAVE_UNSIGNED_CHAR" = x"yes"; then
  94     AC_DEFINE(HAVE_UNSIGNED_CHAR)
  95 fi
  96
  97 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
  98 AC_TRY_RUN([#include <sys/types.h>
  99 #include <dirent.h>
 100 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 101 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 102 di->d_name[0] == 0) exit(0); exit(1);} ],
 103 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 104 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 105     AC_DEFINE(HAVE_BROKEN_READDIR)
 106 fi
 107
 108 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[
 109 AC_TRY_COMPILE([#include <sys/types.h>
 110 #include <utime.h>],
 111 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 112 rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no,rsync_cv_HAVE_UTIMBUF=cross)])
 113 if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then
 114     AC_DEFINE(HAVE_UTIMBUF)
 115 fi
 116
 117 AC_CACHE_CHECK([for broken inet_ntoa],rsync_cv_REPLACE_INET_NTOA,[
 118 AC_TRY_RUN([
 119 #include <stdio.h>
 120 #include <sys/types.h>
 121 #include <netinet/in.h>
 122 #include <arpa/inet.h>
 123 main() { struct in_addr ip; ip.s_addr = 0x12345678;
 124 if (strcmp(inet_ntoa(ip),"18.52.86.120") &&
 125     strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(0); }
 126 exit(1);}],
 127            rsync_cv_REPLACE_INET_NTOA=yes,rsync_cv_REPLACE_INET_NTOA=no,rsync_cv_REPLACE_INET_NTOA=cross)])
 128 if test x"$rsync_cv_REPLACE_INET_NTOA" = x"yes"; then
 129     AC_DEFINE(REPLACE_INET_NTOA)
 130 fi
 131
 132 # The following test taken from the cvs sources
 133 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 134 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 135 # libsocket.so which has a bad implementation of gethostbyname (it
 136 # only looks in /etc/hosts), so we only look for -lsocket if we need
 137 # it.
 138 AC_CHECK_FUNCS(connect)
 139 if test x"$ac_cv_func_connect" = x"no"; then
 140     case "$LIBS" in
 141     *-lnsl*) ;;
 142     *) AC_CHECK_LIB(nsl_s, printf) ;;
 143     esac
 144     case "$LIBS" in
 145     *-lnsl*) ;;
 146     *) AC_CHECK_LIB(nsl, printf) ;;
 147     esac
 148     case "$LIBS" in
 149     *-lsocket*) ;;
 150     *) AC_CHECK_LIB(socket, connect) ;;
 151     esac
 152     case "$LIBS" in
 153     *-linet*) ;;
 154     *) AC_CHECK_LIB(inet, connect) ;;
 155     esac
 156     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 157     dnl has been cached.
 158     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 159        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 160         # ac_cv_func_connect=yes
 161         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 162         AC_DEFINE(HAVE_CONNECT)
 163     fi
 164 fi
 165
 166 #
 167 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 168 #
 169 AC_CHECK_FUNCS(strcasecmp)
 170 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 171     AC_CHECK_LIB(resolv, strcasecmp)
 172 fi
 173
 174 #
 175 # The following test was mostly taken from the tcl/tk plus patches
 176 #
 177 echo $ac_n "checking whether -c -o works ... $ac_c"
 178 rm -rf conftest*
 179 cat > conftest.$ac_ext <<EOF
 180 int main() { return 0; }
 181 EOF
 182 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 183 if test -f conftest..o; then
 184     OBJ_SAVE="#"
 185     OBJ_RESTORE="#"
 186     CC_SHOBJ_FLAG='-o $@'
 187     echo yes
 188 else
 189     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 190     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 191     CC_SHOBJ_FLAG=""
 192     echo no
 193 fi
 194 rm -rf conftest*
 195 AC_SUBST(OBJ_SAVE)
 196 AC_SUBST(OBJ_RESTORE)
 197 AC_SUBST(CC_SHOBJ_FLAG)
 198
 199
 200 AC_OUTPUT(Makefile lib/dummy zlib/dummy)