configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(byteorder.h)
   3 AC_CONFIG_HEADER(config.h)
   4
   5 # compile with optimisation and without debugging by default
   6 CFLAGS=${CFLAGS-"-O"}
   7
   8 AC_CANONICAL_SYSTEM
   9 AC_VALIDATE_CACHE_SYSTEM_TYPE
  10
  11 dnl Checks for programs.
  12 AC_PROG_CC
  13 AC_PROG_INSTALL
  14 AC_SUBST(SHELL)
  15
  16 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
  17 AC_DEFINE_UNQUOTED(HAVE_REMSH, $HAVE_REMSH)
  18
  19 AC_C_BIGENDIAN
  20 AC_HEADER_DIRENT
  21 AC_HEADER_TIME
  22 AC_HEADER_SYS_WAIT
  23 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h unistd.h utime.h grp.h)
  24 AC_CHECK_HEADERS(compat.h sys/param.h ctype.h sys/wait.h sys/ioctl.h)
  25 AC_CHECK_HEADERS(sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h)
  26 AC_CHECK_HEADERS(glob.h)
  27
  28 AC_CHECK_SIZEOF(int)
  29 AC_CHECK_SIZEOF(long)
  30 AC_CHECK_SIZEOF(short)
  31
  32 AC_C_INLINE
  33
  34 AC_TYPE_SIGNAL
  35 AC_TYPE_UID_T
  36 AC_TYPE_MODE_T
  37 AC_TYPE_OFF_T
  38 AC_TYPE_SIZE_T
  39 AC_TYPE_PID_T
  40 AC_TYPE_GETGROUPS
  41 AC_STRUCT_ST_RDEV
  42 AC_CHECK_TYPE(ino_t,unsigned)
  43
  44 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
  45     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
  46         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
  47 if test x"$rsync_cv_errno" = x"yes"; then
  48    AC_DEFINE(HAVE_ERRNO_DECL)
  49 fi
  50
  51 AC_FUNC_MEMCMP
  52 AC_FUNC_UTIME_NULL
  53 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup strerror chown chmod mknod)
  54 AC_CHECK_FUNCS(fchmod fstat strchr readlink link utime utimes strftime)
  55 AC_CHECK_FUNCS(memmove lchown vsnprintf snprintf setsid glob strpbrk)
  56 AC_CHECK_FUNCS(strlcat strlcpy inet_aton socketpair)
  57
  58 AC_CACHE_CHECK([for working fnmatch],rsync_cv_HAVE_FNMATCH,[
  59 AC_TRY_RUN([#include <fnmatch.h>
  60 main() { exit((fnmatch("*.o", "x.o", FNM_PATHNAME) == 0 &&
  61                fnmatch("a/b/*", "a/b/c/d", FNM_PATHNAME) != 0) ? 0: 1); }],
  62 rsync_cv_HAVE_FNMATCH=yes,rsync_cv_HAVE_FNMATCH=no,rsync_cv_HAVE_FNMATCH=cross)])
  63 if test x"$rsync_cv_HAVE_FNMATCH" = x"yes"; then
  64     AC_DEFINE(HAVE_FNMATCH)
  65 fi
  66
  67 # sometimes getopt_long cannot parse same arguments twice
  68 # e.g. on certain versions of CygWin32
  69 AC_CACHE_CHECK([for working getopt_long],rsync_cv_HAVE_GETOPT_LONG,[
  70 AC_TRY_RUN([#include <getopt.h>
  71 main() {
  72     int i, x = 0; char *argv[] = { "x", "--xx" };
  73     struct option o[] = {{"xx", 0, 0, 1}, {0,0,0,0}};
  74     getopt_long(2, argv, "x", o, &i) == 1 ? x++ : 0; optind = 0;
  75     getopt_long(2, argv, "x", o, &i) == 1 ? x++ : 0;
  76     exit(x == 2 ? 0 : 1);
  77 }], rsync_cv_HAVE_GETOPT_LONG=yes,rsync_cv_HAVE_GETOPT_LONG=no,
  78     rsync_cv_HAVE_GETOPT_LONG=cross)])
  79 if test x"$rsync_cv_HAVE_GETOPT_LONG" = x"yes"; then
  80     AC_DEFINE(HAVE_GETOPT_LONG)
  81 fi
  82
  83 AC_CACHE_CHECK([for long long],rsync_cv_HAVE_LONGLONG,[
  84 AC_TRY_RUN([#include <stdio.h>
  85 main() { long long x = 1000000; x *= x; exit(((x/1000000) == 1000000)? 0: 1); }],
  86 rsync_cv_HAVE_LONGLONG=yes,rsync_cv_HAVE_LONGLONG=no,rsync_cv_HAVE_LONGLONG=cross)])
  87 if test x"$rsync_cv_HAVE_LONGLONG" = x"yes"; then
  88     AC_DEFINE(HAVE_LONGLONG)
  89 fi
  90
  91 AC_CACHE_CHECK([for off64_t],rsync_cv_HAVE_OFF64_T,[
  92 AC_TRY_RUN([#include <stdio.h>
  93 #include <sys/stat.h>
  94 main() { struct stat64 st; off64_t s; if (sizeof(off_t) == sizeof(off64_t)) exit(1); exit((lstat64("/dev/null", &st)==0)?0:1); }],
  95 rsync_cv_HAVE_OFF64_T=yes,rsync_cv_HAVE_OFF64_T=no,rsync_cv_HAVE_OFF64_T=cross)])
  96 if test x"$rsync_cv_HAVE_OFF64_T" = x"yes"; then
  97     AC_DEFINE(HAVE_OFF64_T)
  98 fi
  99
 100 AC_CACHE_CHECK([for short ino_t],rsync_cv_HAVE_SHORT_INO_T,[
 101 AC_TRY_RUN([#include <stdio.h>
 102 #include <sys/types.h>
 103 #include <sys/stat.h>
 104 main() { if (sizeof(ino_t) < sizeof(unsigned int)) return 0; return 1; }],
 105 rsync_cv_HAVE_SHORT_INO_T=yes,rsync_cv_HAVE_SHORT_INO_T=no,rsync_cv_HAVE_SHORT_INO_T=cross)])
 106 if test x"$rsync_cv_HAVE_SHORT_INO_T" = x"yes"; then
 107     AC_DEFINE(HAVE_SHORT_INO_T)
 108 fi
 109
 110 AC_CACHE_CHECK([for unsigned char],rsync_cv_HAVE_UNSIGNED_CHAR,[
 111 AC_TRY_RUN([#include <stdio.h>
 112 main() { char c; c=250; exit((c > 0)?0:1); }],
 113 rsync_cv_HAVE_UNSIGNED_CHAR=yes,rsync_cv_HAVE_UNSIGNED_CHAR=no,rsync_cv_HAVE_UNSIGNED_CHAR=cross)])
 114 if test x"$rsync_cv_HAVE_UNSIGNED_CHAR" = x"yes"; then
 115     AC_DEFINE(HAVE_UNSIGNED_CHAR)
 116 fi
 117
 118 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 119 AC_TRY_RUN([#include <sys/types.h>
 120 #include <dirent.h>
 121 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 122 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 123 di->d_name[0] == 0) exit(0); exit(1);} ],
 124 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 125 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 126     AC_DEFINE(HAVE_BROKEN_READDIR)
 127 fi
 128
 129 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[
 130 AC_TRY_COMPILE([#include <sys/types.h>
 131 #include <utime.h>],
 132 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 133 rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no,rsync_cv_HAVE_UTIMBUF=cross)])
 134 if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then
 135     AC_DEFINE(HAVE_UTIMBUF)
 136 fi
 137
 138 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 139 AC_TRY_RUN([
 140 #include <sys/time.h>
 141 #include <unistd.h>
 142 main() { struct timeval tv; exit(gettimeofday(&tv, NULL));}],
 143            rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no,rsync_cv_HAVE_GETTIMEOFDAY_TZ=cross)])
 144 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" = x"yes"; then
 145     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ)
 146 fi
 147
 148
 149 AC_CACHE_CHECK([for broken inet_ntoa],rsync_cv_REPLACE_INET_NTOA,[
 150 AC_TRY_RUN([
 151 #include <stdio.h>
 152 #include <sys/types.h>
 153 #include <netinet/in.h>
 154 #include <arpa/inet.h>
 155 main() { struct in_addr ip; ip.s_addr = 0x12345678;
 156 if (strcmp(inet_ntoa(ip),"18.52.86.120") &&
 157     strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(0); }
 158 exit(1);}],
 159            rsync_cv_REPLACE_INET_NTOA=yes,rsync_cv_REPLACE_INET_NTOA=no,rsync_cv_REPLACE_INET_NTOA=cross)])
 160 if test x"$rsync_cv_REPLACE_INET_NTOA" = x"yes"; then
 161     AC_DEFINE(REPLACE_INET_NTOA)
 162 fi
 163
 164 # The following test taken from the cvs sources
 165 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 166 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 167 # libsocket.so which has a bad implementation of gethostbyname (it
 168 # only looks in /etc/hosts), so we only look for -lsocket if we need
 169 # it.
 170 AC_CHECK_FUNCS(connect)
 171 if test x"$ac_cv_func_connect" = x"no"; then
 172     case "$LIBS" in
 173     *-lnsl*) ;;
 174     *) AC_CHECK_LIB(nsl_s, printf) ;;
 175     esac
 176     case "$LIBS" in
 177     *-lnsl*) ;;
 178     *) AC_CHECK_LIB(nsl, printf) ;;
 179     esac
 180     case "$LIBS" in
 181     *-lsocket*) ;;
 182     *) AC_CHECK_LIB(socket, connect) ;;
 183     esac
 184     case "$LIBS" in
 185     *-linet*) ;;
 186     *) AC_CHECK_LIB(inet, connect) ;;
 187     esac
 188     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 189     dnl has been cached.
 190     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 191        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 192         # ac_cv_func_connect=yes
 193         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 194         AC_DEFINE(HAVE_CONNECT)
 195     fi
 196 fi
 197
 198 #
 199 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 200 #
 201 AC_CHECK_FUNCS(strcasecmp)
 202 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 203     AC_CHECK_LIB(resolv, strcasecmp)
 204 fi
 205
 206 #
 207 # The following test was mostly taken from the tcl/tk plus patches
 208 #
 209 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 210 rm -rf conftest*
 211 cat > conftest.$ac_ext <<EOF
 212 int main() { return 0; }
 213 EOF
 214 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 215 if test -f conftest..o; then
 216     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 217 else
 218     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 219 fi
 220 rm -rf conftest*
 221 ])
 222 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 223     OBJ_SAVE="#"
 224     OBJ_RESTORE="#"
 225     CC_SHOBJ_FLAG='-o $@'
 226 else
 227     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 228     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 229     CC_SHOBJ_FLAG=""
 230 fi
 231
 232 AC_SUBST(OBJ_SAVE)
 233 AC_SUBST(OBJ_RESTORE)
 234 AC_SUBST(CC_SHOBJ_FLAG)
 235
 236
 237 AC_OUTPUT(Makefile lib/dummy zlib/dummy)