packaging/release-rsync

   1 #!/usr/bin/perl
   2 use strict;
   3 use warnings;
   4
   5 # This script expects the directory ~/samba-rsync-ftp to exist and to be a
   6 # copy of the /home/ftp/pub/rsync dir on samba.org.  When the script is done,
   7 # the git repository in the current directory will be updated, and the local
   8 # ~/samba-rsync-ftp dir will be ready to be rsynced to samba.org.
   9
  10 use Cwd;
  11 use Getopt::Long;
  12 use Term::ReadKey;
  13 use Date::Format;
  14
  15 my $dest = $ENV{HOME} . '/samba-rsync-ftp';
  16 my $passfile = $ENV{HOME} . '/.rsyncpass';
  17 my $path = $ENV{PATH};
  18
  19 &Getopt::Long::Configure('bundling');
  20 &usage if !&GetOptions(
  21     'branch|b=s' => \( my $master_branch = 'master' ),
  22     'help|h' => \( my $help_opt ),
  23 );
  24 &usage if $help_opt;
  25
  26 my $now = time;
  27 my $cl_today = time2str('* %a %b %d %Y', $now);
  28 my $year = time2str('%Y', $now);
  29 my $ztoday = time2str('%d %b %Y', $now);
  30 (my $today = $ztoday) =~ s/^0//;
  31
  32 my $curdir = Cwd::cwd;
  33
  34 END {
  35     unlink($passfile);
  36 }
  37
  38 my @extra_files;
  39 open(IN, '<', 'Makefile.in') or die "Couldn't open Makefile.in: $!\n";
  40 while (<IN>) {
  41     if (s/^GENFILES=//) {
  42         while (s/\\$//) {
  43             $_ .= <IN>;
  44         }
  45         @extra_files = split(' ', $_);
  46         last;
  47     }
  48 }
  49 close IN;
  50
  51 my $break = <<EOT;
  52 ==========================================================================
  53 EOT
  54
  55 print $break, <<EOT, $break, "\n";
  56 == This will release a new version of rsync onto an unsuspecting world. ==
  57 EOT
  58
  59 die "$dest does not exist\n" unless -d $dest;
  60 die "There is no .git dir in the current directory.\n" unless -d '.git';
  61 die "'a' must not exist in the current directory.\n" if -e 'a';
  62 die "'b' must not exist in the current directory.\n" if -e 'b';
  63
  64 open(IN, '-|', 'git status') or die $!;
  65 my $status = join('', <IN>);
  66 close IN;
  67 die "The checkout is not clean:\n", $status unless $status =~ /\nnothing to commit \(working directory clean\)/;
  68 my($cur_branch) = $status =~ /^# On branch (.+)\n/;
  69 if ($cur_branch ne $master_branch) {
  70     print "The checkout is not on the $master_branch branch.\n";
  71     exit 1 if $master_branch ne 'master';
  72     print "Do you want to release branch $cur_branch? [n] ";
  73     $_ = <STDIN>;
  74     exit 1 unless /^y/i;
  75     $master_branch = $cur_branch;
  76 }
  77
  78 my $confversion;
  79 open(IN, '<', 'configure.in') or die $!;
  80 while (<IN>) {
  81     if (/^RSYNC_VERSION=(.*)/) {
  82         $confversion = $1;
  83         last;
  84     }
  85 }
  86 close IN;
  87 die "Unable to find RSYNC_VERSION in configure.in\n" unless defined $confversion;
  88
  89 open(IN, '<', 'OLDNEWS') or die $!;
  90 $_ = <IN>;
  91 my($lastversion) = /(\d+\.\d+\.\d+)/;
  92 my($last_protocol_version, %pdate);
  93 while (<IN>) {
  94     if (my($ver,$pdate,$pver) = /^\s+\S\S\s\S\S\S\s\d\d\d\d\s+(\d+\.\d+\.\d+)\s+(\d\d \w\w\w \d\d\d\d\s+)?(\d+)$/) {
  95         $pdate{$ver} = $pdate if defined $pdate;
  96         $last_protocol_version = $pver if $ver eq $lastversion;
  97     }
  98 }
  99 close IN;
 100 die "Unable to determine protocol_version for $lastversion.\n" unless defined $last_protocol_version;
 101
 102 my $protocol_version;
 103 open(IN, '<', 'rsync.h') or die $!;
 104 while (<IN>) {
 105     if (/^#define\s+PROTOCOL_VERSION\s+(\d+)/) {
 106         $protocol_version = $1;
 107         last;
 108     }
 109 }
 110 close IN;
 111 die "Unable to determine the current PROTOCOL_VERSION.\n" unless defined $protocol_version;
 112
 113 my $version = $confversion;
 114 $version =~ s/dev/pre1/ || $version =~ s/pre(\d+)/ 'pre' . ($1 + 1) /e;
 115
 116 print "Please enter the version number of this release: [$version] ";
 117 chomp($_ = <STDIN>);
 118 if ($_ eq '.') {
 119     $version =~ s/pre\d+//;
 120 } elsif ($_ ne '') {
 121     $version = $_;
 122 }
 123 die "Invalid version: `$version'\n" unless $version =~ /^[\d.]+(pre\d+)?$/;
 124
 125 if (`git tag -l v$version` ne '') {
 126     print "Tag v$version already exists.\n\nDelete tag or quit? [q/del] ";
 127     $_ = <STDIN>;
 128     exit 1 unless /^del/i;
 129     system "git tag -d v$version";
 130 }
 131
 132 if ($version =~ s/[-.]*pre[-.]*/pre/ && $confversion !~ /dev$/) {
 133     $lastversion = $confversion;
 134 }
 135
 136 print "Enter the previous version to produce a patch against: [$lastversion] ";
 137 chomp($_ = <STDIN>);
 138 $lastversion = $_ if $_ ne '';
 139 $lastversion =~ s/[-.]*pre[-.]*/pre/;
 140
 141 my $pre = $version =~ /(pre\d+)/ ? $1 : '';
 142
 143 my $release = $pre ? '0.1' : '1';
 144 print "Please enter the RPM release number of this release: [$release] ";
 145 chomp($_ = <STDIN>);
 146 $release = $_ if $_ ne '';
 147 $release .= ".$pre" if $pre;
 148
 149 (my $finalversion = $version) =~ s/pre\d+//;
 150 my($proto_changed,$proto_change_date);
 151 if ($protocol_version eq $last_protocol_version) {
 152     $proto_changed = 'unchanged';
 153     $proto_change_date = "\t\t";
 154 } else {
 155     $proto_changed = 'changed';
 156     if (!defined($proto_change_date = $pdate{$finalversion})) {
 157         while (1) {
 158             print "On what date did the protocol change to $protocol_version get checked in? (dd Mmm yyyy) ";
 159             chomp($_ = <STDIN>);
 160             last if /^\d\d \w\w\w \d\d\d\d$/;
 161         }
 162         $proto_change_date = "$_\t";
 163     }
 164 }
 165
 166 my($srcdir,$srcdiffdir,$lastsrcdir,$skipping);
 167 if ($lastversion =~ /pre/) {
 168     if (!$pre) {
 169         die "You should not diff a release version against a pre-release version.\n";
 170     }
 171     $srcdir = $srcdiffdir = $lastsrcdir = 'src-previews';
 172     $skipping = ' ** SKIPPING **';
 173 } elsif ($pre) {
 174     $srcdir = $srcdiffdir = 'src-previews';
 175     $lastsrcdir = 'src';
 176     $skipping = ' ** SKIPPING **';
 177 } else {
 178     $srcdir = $lastsrcdir = 'src';
 179     $srcdiffdir = 'src-diffs';
 180     $skipping = '';
 181 }
 182
 183 print "\n", $break, <<EOT;
 184 \$version is "$version"
 185 \$lastversion is "$lastversion"
 186 \$dest is "$dest"
 187 \$curdir is "$curdir"
 188 \$srcdir is "$srcdir"
 189 \$srcdiffdir is "$srcdiffdir"
 190 \$lastsrcdir is "$lastsrcdir"
 191 \$release is "$release"
 192
 193 About to:
 194     - tweak SUBPROTOCOL_VERSION in rsync.h, if needed
 195     - tweak the version in configure.in and the spec files
 196     - tweak NEWS and OLDNEWS to ensure header values are correct
 197     - tweak the date in the *.yo files and generate the manpages
 198     - generate configure.sh, config.h.in, and proto.h
 199     - page through the differences
 200
 201 EOT
 202 print "<Press Enter to continue> ";
 203 $_ = <STDIN>;
 204
 205 my %specvars = ( 'Version:' => $finalversion, 'Release:' => $release,
 206                  '%define fullversion' => "\%{version}$pre", 'Released' => "$version.",
 207                  '%define srcdir' => $srcdir );
 208 my @tweak_files = ( glob('packaging/*.spec'), glob('packaging/*/*.spec'), glob('*.yo'),
 209                     qw( configure.in rsync.h NEWS OLDNEWS options.c ) );
 210
 211 foreach my $fn (@tweak_files) {
 212     open(IN, '<', $fn) or die $!;
 213     undef $/; $_ = <IN>; $/ = "\n";
 214     close IN;
 215     if ($fn =~ /configure/) {
 216         s/^RSYNC_VERSION=.*/RSYNC_VERSION=$version/m
 217             or die "Unable to update RSYNC_VERSION in $fn\n";
 218     } elsif ($fn =~ /\.spec/) {
 219         while (my($str, $val) = each %specvars) {
 220             s/^\Q$str\E .*/$str $val/m
 221                 or die "Unable to update $str in $fn\n";
 222         }
 223         s/^\* \w\w\w \w\w\w \d\d \d\d\d\d (.*)/$cl_today $1/m
 224             or die "Unable to update ChangeLog header in $fn\n";
 225     } elsif ($fn =~ /\.yo/) {
 226         s/^(manpage\([^)]+\)\(\d+\)\()[^)]+(\).*)/$1$today$2/m
 227             or die "Unable to update date in manpage() header in $fn\n";
 228         s/^(This man ?page is current for version) \S+ (of rsync)/$1 $version $2/m
 229             or die "Unable to update current version info in $fn\n";
 230     } elsif ($fn eq 'rsync.h') {
 231         s{(#define\s+SUBPROTOCOL_VERSION)\s+(\d+)}
 232          { $1 . ' ' . get_subprotocol_version($2) }e
 233             or die "Unable to find SUBPROTOCOL_VERSION define in $fn\n";
 234     } elsif ($fn eq 'NEWS') {
 235         s{^(NEWS for rsync \Q$finalversion\E )(\(UNRELEASED\))\s*(\nProtocol: )(\d+) (\([^)]+\))\n}
 236          { $1 . ($pre ? $2 : "($today)") . "$3$protocol_version ($proto_changed)\n" }ei
 237             or die "The first 2 lines of $fn are not in the right format.  They must be:\n"
 238                  . "NEWS for rsync $finalversion (UNRELEASED)\n"
 239                  . "Protocol: $protocol_version ($proto_changed)\n";
 240     } elsif ($fn eq 'OLDNEWS') {
 241         s{^(\t\S\S\s\S\S\S\s\d\d\d\d)(\t\Q$finalversion\E\t).*}
 242          { ($pre ? $1 : "\t$ztoday") . $2 . $proto_change_date . $protocol_version }em
 243             or die "Unable to find \"?? ??? $year\t$finalversion\" line in $fn\n";
 244     } elsif ($fn eq 'options.c') {
 245         if (s/(Copyright \(C\) 2002-)(\d+)( Wayne Davison)/$1$year$3/
 246          && $2 ne $year) {
 247             die "Copyright comments need to be updated to $year in all files!\n";
 248         }
 249         # Adjust the year in the --version output.
 250         s/(rprintf\(f, "Copyright \(C\) 1996-)(\d+)/$1$year/
 251             or die "Unable to find Copyright string in --version output of $fn\n";
 252         next if $2 eq $year;
 253     } else {
 254         die "Unrecognized file in \@tweak_files: $fn\n";
 255     }
 256     open(OUT, '>', $fn) or die $!;
 257     print OUT $_;
 258     close OUT;
 259 }
 260
 261 print $break;
 262 system "git diff --color | less -p '^diff .*'";
 263
 264 my $srctar_name = "rsync-$version.tar.gz";
 265 my $pattar_name = "rsync-patches-$version.tar.gz";
 266 my $diff_name = "rsync-$lastversion-$version.diffs.gz";
 267 my $srctar_file = "$dest/$srcdir/$srctar_name";
 268 my $pattar_file = "$dest/$srcdir/$pattar_name";
 269 my $diff_file = "$dest/$srcdiffdir/$diff_name";
 270 my $news_file = "$dest/$srcdir/rsync-$version-NEWS";
 271 my $lasttar_file = "$dest/$lastsrcdir/rsync-$lastversion.tar.gz";
 272
 273 print $break, <<EOT;
 274
 275 About to:
 276     - commit all version changes
 277     - merge the $master_branch branch into the patch/* branches
 278     - update the files in the "patches" dir and OPTIONALLY
 279       (if you type 'y') to launch a shell for each patch
 280
 281 EOT
 282 print "<Press Enter OR 'y' to continue> ";
 283 my $ans = <STDIN>;
 284
 285 system "git commit -a -m 'Preparing for release of $version'" and exit 1;
 286
 287 print "Updating files in \"patches\" dir ...\n";
 288 system "packaging/patch-update --branch=$master_branch";
 289
 290 if ($ans =~ /^y/i) {
 291     print "\nVisiting all \"patch/*\" branches ...\n";
 292     system "packaging/patch-update --branch=$master_branch --shell";
 293 }
 294
 295 print $break, <<EOT;
 296
 297 About to:
 298     - create signed tag for this release: v$version
 299     - create release diffs, "$diff_name"
 300     - create release tar, "$srctar_name"
 301     - generate rsync-$version/patches/* files
 302     - create patches tar, "$pattar_name"
 303     - update top-level README, *NEWS, TODO, and ChangeLog
 304     - update top-level rsync*.html manpages
 305     - gpg-sign the release files
 306     - update hard-linked top-level release files$skipping
 307
 308 EOT
 309 print "<Press Enter to continue> ";
 310 $_ = <STDIN>;
 311
 312 my $passphrase;
 313 while (1) {
 314     ReadMode('noecho');
 315     print "\nEnter your GPG pass-phrase: ";
 316     chomp($passphrase = <STDIN>);
 317     ReadMode(0);
 318     print "\n";
 319
 320     # Briefly create a temp file with the passphrase for git's tagging use.
 321     my $oldmask = umask 077;
 322     unlink($passfile);
 323     open(OUT, '>', $passfile) or die $!;
 324     print OUT $passphrase, "\n";
 325     close OUT;
 326     umask $oldmask;
 327     $ENV{'GPG_PASSFILE'} = $passfile;
 328
 329     # We want to use our passphrase-providing "gpg" script, so modify the PATH.
 330     $ENV{PATH} = "packaging/bin:$path";
 331     $_ = `git tag -s -m 'Version $version.' v$version 2>&1`;
 332     $ENV{PATH} = $path;
 333     unlink($passfile);
 334     print $_;
 335     next if /bad passphrase/;
 336     last unless /failed/;
 337     exit 1;
 338 }
 339
 340 # Extract the generated files from the old tar.
 341 @_ = @extra_files;
 342 map { s#^#rsync-$lastversion/# } @_;
 343 system "tar xzf $lasttar_file @_";
 344 rename("rsync-$lastversion", 'a');
 345
 346 print "Creating $diff_file ...\n";
 347 system "./config.status Makefile; make gen; rsync -a @extra_files b/";
 348 my $sed_script = 's:^((---|\+\+\+) [ab]/[^\t]+)\t.*:\1:';
 349 system "(git diff v$lastversion v$version; diff -upN a b | sed -r '$sed_script') | gzip -9 >$diff_file";
 350 system "rm -rf a";
 351 rename('b', "rsync-$version");
 352
 353 print "Creating $srctar_file ...\n";
 354 system "git archive --format=tar --prefix=rsync-$version/ v$version | tar xf -";
 355 system "support/git-set-file-times --prefix=rsync-$version/";
 356 system "fakeroot tar czf $srctar_file rsync-$version; rm -rf rsync-$version";
 357
 358 print "Updating files in \"rsync-$version/patches\" dir ...\n";
 359 mkdir("rsync-$version", 0755);
 360 mkdir("rsync-$version/patches", 0755);
 361 system "packaging/patch-update --skip-check --branch=$master_branch --gen=rsync-$version/patches";
 362
 363 print "Creating $pattar_file ...\n";
 364 system "fakeroot tar chzf $pattar_file rsync-$version/patches; rm -rf rsync-$version";
 365
 366 print "Updating the other files in $dest ...\n";
 367 system "rsync -a README NEWS OLDNEWS TODO $dest";
 368 unlink($news_file);
 369 link("$dest/NEWS", $news_file);
 370 system "git log --name-status | gzip -9 >$dest/ChangeLog.gz";
 371
 372 system "yodl2html -o $dest/rsync.html rsync.yo";
 373 system "yodl2html -o $dest/rsyncd.conf.html rsyncd.conf.yo";
 374
 375 foreach my $fn ($srctar_file, $pattar_file, $diff_file) {
 376     unlink("$fn.asc");
 377     open(GPG, '|-', "gpg --batch --passphrase-fd=0 -ba $fn") or die $!;
 378     print GPG $passphrase, "\n";
 379     close GPG;
 380 }
 381
 382 if (!$pre) {
 383     system "rm $dest/rsync-*.gz $dest/rsync-*.asc $dest/rsync-*-NEWS $dest/src-previews/rsync-*diffs.gz*";
 384
 385     foreach my $fn ($srctar_file, "$srctar_file.asc",
 386                     $pattar_file, "$pattar_file.asc",
 387                     $diff_file, "$diff_file.asc", $news_file) {
 388         (my $top_fn = $fn) =~ s#/src(-\w+)?/#/#;
 389         link($fn, $top_fn);
 390     }
 391 }
 392
 393 print $break, <<'EOT';
 394
 395 Local changes are done.  When you're satisfied, push the git repository
 396 and rsync the release files.  Remember to announce the release on *BOTH*
 397 rsync-announce@lists.samba.org and rsync@lists.samba.org (and the web)!
 398 EOT
 399
 400 exit;
 401
 402 sub get_subprotocol_version
 403 {
 404     my($subver) = @_;
 405     if ($pre && $proto_changed eq 'changed') {
 406         return $subver == 0 ? 1 : $subver;
 407     }
 408     0;
 409 }
 410
 411 sub usage
 412 {
 413     die <<EOT;
 414 Usage: release-rsync [OPTIONS]
 415
 416 -b, --branch=BRANCH   The branch to release (default: master)
 417 -h, --help            Display this help message
 418 EOT
 419 }