configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(byteorder.h)
   3 AC_CONFIG_HEADER(config.h)
   4 AC_PREREQ(2.12)
   5
   6 LDFLAGS=${LDFLAGS-""}
   7
   8 AC_CANONICAL_SYSTEM
   9 AC_VALIDATE_CACHE_SYSTEM_TYPE
  10
  11 # compile with optimisation and without debugging by default, unless
  12 # --debug is given.  We must decide this before testing the compiler.
  13
  14 AC_ARG_ENABLE(debug,
  15         [  --enable-debug          including debugging symbols and features])
  16
  17 AC_MSG_CHECKING([whether to include debugging symbols])
  18 if test x"$enable_debug" = x"yes"
  19 then
  20     AC_MSG_RESULT(yes)
  21     # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can
  22     AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  23     CFLAGS=${CFLAGS-"-g"}
  24 else
  25     AC_MSG_RESULT(no)
  26     CFLAGS=${CFLAGS-"-O"}
  27 fi
  28
  29 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  30
  31 # look for getconf early as this affects just about everything
  32 AC_CHECK_PROG(HAVE_GETCONF, getconf, "yes", "no")
  33 if test $HAVE_GETCONF = "yes"; then
  34         CFLAGS=$CFLAGS" "`getconf LFS_CFLAGS 2> /dev/null`
  35         LDFLAGS=$LDFLAGS" "`getconf LFS_LDFLAGS 2> /dev/null`
  36 fi
  37
  38 AC_ARG_WITH(included-popt,
  39         [  --with-included-popt    use bundled popt library, not from system])
  40
  41 AC_ARG_WITH(rsync-path,
  42         [  --with-rsync-path=PATH  set rsync path used on server to PATH (default: "rsync")],
  43         [ RSYNC_PATH="$with_rsync_name" ],
  44         [ RSYNC_PATH="rsync" ])
  45 RSYNC_PATH="\"$RSYNC_PATH\""
  46 AC_DEFINE_UNQUOTED(RSYNC_PATH, $RSYNC_PATH)
  47
  48 dnl Checks for programs.
  49 AC_PROG_CC
  50 AC_PROG_INSTALL
  51 AC_SUBST(SHELL)
  52
  53 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
  54 AC_DEFINE_UNQUOTED(HAVE_REMSH, $HAVE_REMSH)
  55
  56 AC_SYS_LARGEFILE
  57 AC_C_BIGENDIAN
  58 AC_HEADER_DIRENT
  59 AC_HEADER_TIME
  60 AC_HEADER_SYS_WAIT
  61 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h unistd.h utime.h grp.h)
  62 AC_CHECK_HEADERS(compat.h sys/param.h ctype.h sys/wait.h sys/ioctl.h)
  63 AC_CHECK_HEADERS(sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h)
  64 AC_CHECK_HEADERS(glob.h alloca.h mcheck.h)
  65
  66 AC_CHECK_SIZEOF(int)
  67 AC_CHECK_SIZEOF(long)
  68 AC_CHECK_SIZEOF(short)
  69
  70 AC_C_INLINE
  71
  72 AC_TYPE_SIGNAL
  73 AC_TYPE_UID_T
  74 AC_TYPE_MODE_T
  75 AC_TYPE_OFF_T
  76 AC_TYPE_SIZE_T
  77 AC_TYPE_PID_T
  78 AC_TYPE_GETGROUPS
  79 AC_STRUCT_ST_RDEV
  80 AC_CHECK_TYPE(ino_t,unsigned)
  81
  82 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
  83     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
  84         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
  85 if test x"$rsync_cv_errno" = x"yes"; then
  86    AC_DEFINE(HAVE_ERRNO_DECL)
  87 fi
  88
  89 # The following test taken from the cvs sources
  90 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
  91 # These need checks to be before checks for any other functions that
  92 #    might be in the same libraries.
  93 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
  94 # libsocket.so which has a bad implementation of gethostbyname (it
  95 # only looks in /etc/hosts), so we only look for -lsocket if we need
  96 # it.
  97 AC_CHECK_FUNCS(connect)
  98 if test x"$ac_cv_func_connect" = x"no"; then
  99     case "$LIBS" in
 100     *-lnsl*) ;;
 101     *) AC_CHECK_LIB(nsl_s, printf) ;;
 102     esac
 103     case "$LIBS" in
 104     *-lnsl*) ;;
 105     *) AC_CHECK_LIB(nsl, printf) ;;
 106     esac
 107     case "$LIBS" in
 108     *-lsocket*) ;;
 109     *) AC_CHECK_LIB(socket, connect) ;;
 110     esac
 111     case "$LIBS" in
 112     *-linet*) ;;
 113     *) AC_CHECK_LIB(inet, connect) ;;
 114     esac
 115     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 116     dnl has been cached.
 117     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 118        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 119         # ac_cv_func_connect=yes
 120         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 121         AC_DEFINE(HAVE_CONNECT)
 122     fi
 123 fi
 124
 125 #
 126 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 127 #
 128 AC_CHECK_FUNCS(strcasecmp)
 129 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 130     AC_CHECK_LIB(resolv, strcasecmp)
 131 fi
 132
 133 AC_FUNC_MEMCMP
 134 AC_FUNC_UTIME_NULL
 135 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup strerror chown chmod mknod)
 136 AC_CHECK_FUNCS(fchmod fstat strchr readlink link utime utimes strftime)
 137 AC_CHECK_FUNCS(memmove lchown vsnprintf snprintf asprintf setsid glob strpbrk)
 138 AC_CHECK_FUNCS(strlcat strlcpy mtrace)
 139
 140 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 141 AC_TRY_RUN([#include <sys/types.h>
 142             #include <sys/socket.h>
 143             main() {
 144                 int fd[2];
 145                 exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 146             }],
 147 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
 148 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 149     AC_DEFINE(HAVE_SOCKETPAIR)
 150 fi
 151
 152 AC_CACHE_CHECK([for working fnmatch],rsync_cv_HAVE_FNMATCH,[
 153 AC_TRY_RUN([#include <fnmatch.h>
 154 main() { exit((fnmatch("*.o", "x.o", FNM_PATHNAME) == 0 &&
 155                fnmatch("a/b/*", "a/b/c/d", FNM_PATHNAME) != 0) ? 0: 1); }],
 156 rsync_cv_HAVE_FNMATCH=yes,rsync_cv_HAVE_FNMATCH=no,rsync_cv_HAVE_FNMATCH=cross)])
 157 if test x"$rsync_cv_HAVE_FNMATCH" = x"yes"; then
 158     AC_DEFINE(HAVE_FNMATCH)
 159 fi
 160
 161 if test x"$with_included_popt" != x"yes"
 162 then
 163     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 164 fi
 165
 166 AC_MSG_CHECKING("whether to use included libpopt")
 167 if test x"$with_included_popt" = x"yes"
 168 then
 169     AC_MSG_RESULT("$srcdir/popt")
 170     BUILD_POPT='$(popt_OBJS)'
 171     CFLAGS="$CFLAGS -I$srcdir/popt"
 172 else
 173     AC_MSG_RESULT(no)
 174 fi
 175
 176 AC_CACHE_CHECK([for long long],rsync_cv_HAVE_LONGLONG,[
 177 AC_TRY_RUN([#include <stdio.h>
 178 main() { long long x = 1000000; x *= x; exit(((x/1000000) == 1000000)? 0: 1); }],
 179 rsync_cv_HAVE_LONGLONG=yes,rsync_cv_HAVE_LONGLONG=no,rsync_cv_HAVE_LONGLONG=cross)])
 180 if test x"$rsync_cv_HAVE_LONGLONG" = x"yes"; then
 181     AC_DEFINE(HAVE_LONGLONG)
 182 fi
 183
 184 AC_CACHE_CHECK([for off64_t],rsync_cv_HAVE_OFF64_T,[
 185 AC_TRY_RUN([#include <stdio.h>
 186 #include <sys/stat.h>
 187 main() { struct stat64 st; off64_t s; if (sizeof(off_t) == sizeof(off64_t)) exit(1); exit((lstat64("/dev/null", &st)==0)?0:1); }],
 188 rsync_cv_HAVE_OFF64_T=yes,rsync_cv_HAVE_OFF64_T=no,rsync_cv_HAVE_OFF64_T=cross)])
 189 if test x"$rsync_cv_HAVE_OFF64_T" = x"yes"; then
 190     AC_DEFINE(HAVE_OFF64_T)
 191 fi
 192
 193 AC_CACHE_CHECK([for short ino_t],rsync_cv_HAVE_SHORT_INO_T,[
 194 AC_TRY_RUN([#include <stdio.h>
 195 #include <sys/types.h>
 196 #include <sys/stat.h>
 197 main() { if (sizeof(ino_t) < sizeof(unsigned int)) return 0; return 1; }],
 198 rsync_cv_HAVE_SHORT_INO_T=yes,rsync_cv_HAVE_SHORT_INO_T=no,rsync_cv_HAVE_SHORT_INO_T=cross)])
 199 if test x"$rsync_cv_HAVE_SHORT_INO_T" = x"yes"; then
 200     AC_DEFINE(HAVE_SHORT_INO_T)
 201 fi
 202
 203 AC_CACHE_CHECK([for unsigned char],rsync_cv_HAVE_UNSIGNED_CHAR,[
 204 AC_TRY_RUN([#include <stdio.h>
 205 main() { char c; c=250; exit((c > 0)?0:1); }],
 206 rsync_cv_HAVE_UNSIGNED_CHAR=yes,rsync_cv_HAVE_UNSIGNED_CHAR=no,rsync_cv_HAVE_UNSIGNED_CHAR=cross)])
 207 if test x"$rsync_cv_HAVE_UNSIGNED_CHAR" = x"yes"; then
 208     AC_DEFINE(HAVE_UNSIGNED_CHAR)
 209 fi
 210
 211 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 212 AC_TRY_RUN([#include <sys/types.h>
 213 #include <dirent.h>
 214 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 215 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 216 di->d_name[0] == 0) exit(0); exit(1);} ],
 217 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 218 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 219     AC_DEFINE(HAVE_BROKEN_READDIR)
 220 fi
 221
 222 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[
 223 AC_TRY_COMPILE([#include <sys/types.h>
 224 #include <utime.h>],
 225 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 226 rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no,rsync_cv_HAVE_UTIMBUF=cross)])
 227 if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then
 228     AC_DEFINE(HAVE_UTIMBUF)
 229 fi
 230
 231 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 232 AC_TRY_RUN([
 233 #include <sys/time.h>
 234 #include <unistd.h>
 235 main() { struct timeval tv; exit(gettimeofday(&tv, NULL));}],
 236            rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no,rsync_cv_HAVE_GETTIMEOFDAY_TZ=cross)])
 237 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" = x"yes"; then
 238     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ)
 239 fi
 240
 241 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 242 AC_TRY_RUN([
 243 #include <sys/types.h>
 244 #include <stdarg.h>
 245 void foo(const char *format, ...) {
 246        va_list ap;
 247        int len;
 248        char buf[5];
 249
 250        va_start(ap, format);
 251        len = vsnprintf(0, 0, format, ap);
 252        va_end(ap);
 253        if (len != 5) exit(1);
 254
 255        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 256
 257        exit(0);
 258 }
 259 main() { foo("hello"); }
 260 ],
 261 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
 262 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 263     AC_DEFINE(HAVE_C99_VSNPRINTF)
 264 fi
 265
 266
 267 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 268 AC_TRY_RUN([#include <stdlib.h>
 269 #include <sys/types.h>
 270 #include <sys/stat.h>
 271 #include <unistd.h>
 272 main() {
 273   struct stat st;
 274   char tpl[20]="/tmp/test.XXXXXX";
 275   int fd = mkstemp(tpl);
 276   if (fd == -1) exit(1);
 277   unlink(tpl);
 278   if (fstat(fd, &st) != 0) exit(1);
 279   if ((st.st_mode & 0777) != 0600) exit(1);
 280   exit(0);
 281 }],
 282 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
 283 rsync_cv_HAVE_SECURE_MKSTEMP=no,
 284 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
 285 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 286     AC_DEFINE(HAVE_SECURE_MKSTEMP)
 287 fi
 288
 289
 290 AC_CACHE_CHECK([for broken inet_ntoa],rsync_cv_REPLACE_INET_NTOA,[
 291 AC_TRY_RUN([
 292 #include <stdio.h>
 293 #include <sys/types.h>
 294 #include <netinet/in.h>
 295 #include <arpa/inet.h>
 296 main() { struct in_addr ip; ip.s_addr = 0x12345678;
 297 if (strcmp(inet_ntoa(ip),"18.52.86.120") &&
 298     strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(1); }
 299 exit(0);}],
 300            rsync_cv_REPLACE_INET_NTOA=no,rsync_cv_REPLACE_INET_NTOA=yes,rsync_cv_REPLACE_INET_NTOA=cross)])
 301 if test x"$rsync_cv_REPLACE_INET_NTOA" = x"yes"; then
 302     AC_DEFINE(REPLACE_INET_NTOA)
 303 fi
 304
 305
 306 AC_CACHE_CHECK([for broken inet_aton],rsync_cv_REPLACE_INET_ATON,[
 307 AC_TRY_RUN([
 308 #include <stdio.h>
 309 #include <sys/types.h>
 310 #include <netinet/in.h>
 311 #include <arpa/inet.h>
 312 main() { struct in_addr ip;
 313 if (inet_aton("example", &ip) == 0) exit(0); exit(1);}],
 314            rsync_cv_REPLACE_INET_ATON=no,rsync_cv_REPLACE_INET_ATON=yes,rsync_cv_REPLACE_INET_ATON=cross)])
 315 if test x"$rsync_cv_REPLACE_INET_ATON" = x"yes"; then
 316     AC_DEFINE(REPLACE_INET_ATON)
 317 fi
 318
 319 #
 320 # The following test was mostly taken from the tcl/tk plus patches
 321 #
 322 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 323 rm -rf conftest*
 324 cat > conftest.$ac_ext <<EOF
 325 int main() { return 0; }
 326 EOF
 327 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 328 if test -f conftest..o; then
 329     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 330 else
 331     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 332 fi
 333 rm -rf conftest*
 334 ])
 335 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 336     OBJ_SAVE="#"
 337     OBJ_RESTORE="#"
 338     CC_SHOBJ_FLAG='-o $@'
 339 else
 340     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 341     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 342     CC_SHOBJ_FLAG=""
 343 fi
 344
 345 AC_SUBST(OBJ_SAVE)
 346 AC_SUBST(OBJ_RESTORE)
 347 AC_SUBST(CC_SHOBJ_FLAG)
 348 AC_SUBST(BUILD_POPT)
 349
 350 AC_OUTPUT(Makefile lib/dummy zlib/dummy)