configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(byteorder.h)
   3 AC_CONFIG_HEADER(config.h)
   4
   5 LDFLAGS=${LDFLAGS-""}
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_VALIDATE_CACHE_SYSTEM_TYPE
   9
  10 # compile with optimisation and without debugging by default, unless
  11 # --debug is given.  We must decide this before testing the compiler.
  12
  13 AC_ARG_ENABLE(debug,
  14         [  --enable-debug          including debugging symbols and features])
  15
  16 AC_MSG_CHECKING([whether to include debugging symbols])
  17 if test x"$enable_debug" = x"yes"
  18 then
  19     AC_MSG_RESULT(yes)
  20     # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can
  21     AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  22     CFLAGS=${CFLAGS-"-g"}
  23 else
  24     AC_MSG_RESULT(no)
  25     CFLAGS=${CFLAGS-"-O"}
  26 fi
  27
  28 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  29
  30 # look for getconf early as this affects just about everything
  31 AC_CHECK_PROG(HAVE_GETCONF, getconf, "yes", "no")
  32 if test $HAVE_GETCONF = "yes"; then
  33         CFLAGS=$CFLAGS" "`getconf LFS_CFLAGS 2> /dev/null`
  34         LDFLAGS=$LDFLAGS" "`getconf LFS_LDFLAGS 2> /dev/null`
  35 fi
  36
  37 AC_ARG_WITH(included-popt,
  38         [  --with-included-popt    use bundled popt library, not from system])
  39
  40 dnl Checks for programs.
  41 AC_PROG_CC
  42 AC_PROG_INSTALL
  43 AC_SUBST(SHELL)
  44
  45 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
  46 AC_DEFINE_UNQUOTED(HAVE_REMSH, $HAVE_REMSH)
  47
  48 AC_SYS_LARGEFILE
  49 AC_C_BIGENDIAN
  50 AC_HEADER_DIRENT
  51 AC_HEADER_TIME
  52 AC_HEADER_SYS_WAIT
  53 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h unistd.h utime.h grp.h)
  54 AC_CHECK_HEADERS(compat.h sys/param.h ctype.h sys/wait.h sys/ioctl.h)
  55 AC_CHECK_HEADERS(sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h)
  56 AC_CHECK_HEADERS(glob.h)
  57
  58 AC_CHECK_SIZEOF(int)
  59 AC_CHECK_SIZEOF(long)
  60 AC_CHECK_SIZEOF(short)
  61
  62 AC_C_INLINE
  63
  64 AC_TYPE_SIGNAL
  65 AC_TYPE_UID_T
  66 AC_TYPE_MODE_T
  67 AC_TYPE_OFF_T
  68 AC_TYPE_SIZE_T
  69 AC_TYPE_PID_T
  70 AC_TYPE_GETGROUPS
  71 AC_STRUCT_ST_RDEV
  72 AC_CHECK_TYPE(ino_t,unsigned)
  73
  74 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
  75     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
  76         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
  77 if test x"$rsync_cv_errno" = x"yes"; then
  78    AC_DEFINE(HAVE_ERRNO_DECL)
  79 fi
  80
  81 # The following test taken from the cvs sources
  82 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
  83 # These need checks to be before checks for any other functions that
  84 #    might be in the same libraries.
  85 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
  86 # libsocket.so which has a bad implementation of gethostbyname (it
  87 # only looks in /etc/hosts), so we only look for -lsocket if we need
  88 # it.
  89 AC_CHECK_FUNCS(connect)
  90 if test x"$ac_cv_func_connect" = x"no"; then
  91     case "$LIBS" in
  92     *-lnsl*) ;;
  93     *) AC_CHECK_LIB(nsl_s, printf) ;;
  94     esac
  95     case "$LIBS" in
  96     *-lnsl*) ;;
  97     *) AC_CHECK_LIB(nsl, printf) ;;
  98     esac
  99     case "$LIBS" in
 100     *-lsocket*) ;;
 101     *) AC_CHECK_LIB(socket, connect) ;;
 102     esac
 103     case "$LIBS" in
 104     *-linet*) ;;
 105     *) AC_CHECK_LIB(inet, connect) ;;
 106     esac
 107     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 108     dnl has been cached.
 109     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 110        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 111         # ac_cv_func_connect=yes
 112         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 113         AC_DEFINE(HAVE_CONNECT)
 114     fi
 115 fi
 116
 117 #
 118 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 119 #
 120 AC_CHECK_FUNCS(strcasecmp)
 121 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 122     AC_CHECK_LIB(resolv, strcasecmp)
 123 fi
 124
 125 AC_FUNC_MEMCMP
 126 AC_FUNC_UTIME_NULL
 127 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup strerror chown chmod mknod)
 128 AC_CHECK_FUNCS(fchmod fstat strchr readlink link utime utimes strftime)
 129 AC_CHECK_FUNCS(memmove lchown vsnprintf snprintf setsid glob strpbrk)
 130 AC_CHECK_FUNCS(strlcat strlcpy)
 131
 132 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 133 AC_TRY_RUN([#include <sys/types.h>
 134             #include <sys/socket.h>
 135             main() {
 136                 int fd[2];
 137                 exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 138             }],
 139 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
 140 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 141     AC_DEFINE(HAVE_SOCKETPAIR)
 142 fi
 143
 144 AC_CACHE_CHECK([for working fnmatch],rsync_cv_HAVE_FNMATCH,[
 145 AC_TRY_RUN([#include <fnmatch.h>
 146 main() { exit((fnmatch("*.o", "x.o", FNM_PATHNAME) == 0 &&
 147                fnmatch("a/b/*", "a/b/c/d", FNM_PATHNAME) != 0) ? 0: 1); }],
 148 rsync_cv_HAVE_FNMATCH=yes,rsync_cv_HAVE_FNMATCH=no,rsync_cv_HAVE_FNMATCH=cross)])
 149 if test x"$rsync_cv_HAVE_FNMATCH" = x"yes"; then
 150     AC_DEFINE(HAVE_FNMATCH)
 151 fi
 152
 153 if test x"$with_included_popt" != x"yes"
 154 then
 155     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 156 fi
 157
 158 AC_MSG_CHECKING("whether to use included libpopt")
 159 if test x"$with_included_popt" = x"yes"
 160 then
 161     AC_MSG_RESULT("$srcdir/popt")
 162     BUILD_POPT='$(popt_OBJS)'
 163     CFLAGS="$CFLAGS -I $srcdir/popt"
 164 else
 165     AC_MSG_RESULT(no)
 166 fi
 167
 168 AC_CACHE_CHECK([for long long],rsync_cv_HAVE_LONGLONG,[
 169 AC_TRY_RUN([#include <stdio.h>
 170 main() { long long x = 1000000; x *= x; exit(((x/1000000) == 1000000)? 0: 1); }],
 171 rsync_cv_HAVE_LONGLONG=yes,rsync_cv_HAVE_LONGLONG=no,rsync_cv_HAVE_LONGLONG=cross)])
 172 if test x"$rsync_cv_HAVE_LONGLONG" = x"yes"; then
 173     AC_DEFINE(HAVE_LONGLONG)
 174 fi
 175
 176 AC_CACHE_CHECK([for off64_t],rsync_cv_HAVE_OFF64_T,[
 177 AC_TRY_RUN([#include <stdio.h>
 178 #include <sys/stat.h>
 179 main() { struct stat64 st; off64_t s; if (sizeof(off_t) == sizeof(off64_t)) exit(1); exit((lstat64("/dev/null", &st)==0)?0:1); }],
 180 rsync_cv_HAVE_OFF64_T=yes,rsync_cv_HAVE_OFF64_T=no,rsync_cv_HAVE_OFF64_T=cross)])
 181 if test x"$rsync_cv_HAVE_OFF64_T" = x"yes"; then
 182     AC_DEFINE(HAVE_OFF64_T)
 183 fi
 184
 185 AC_CACHE_CHECK([for short ino_t],rsync_cv_HAVE_SHORT_INO_T,[
 186 AC_TRY_RUN([#include <stdio.h>
 187 #include <sys/types.h>
 188 #include <sys/stat.h>
 189 main() { if (sizeof(ino_t) < sizeof(unsigned int)) return 0; return 1; }],
 190 rsync_cv_HAVE_SHORT_INO_T=yes,rsync_cv_HAVE_SHORT_INO_T=no,rsync_cv_HAVE_SHORT_INO_T=cross)])
 191 if test x"$rsync_cv_HAVE_SHORT_INO_T" = x"yes"; then
 192     AC_DEFINE(HAVE_SHORT_INO_T)
 193 fi
 194
 195 AC_CACHE_CHECK([for unsigned char],rsync_cv_HAVE_UNSIGNED_CHAR,[
 196 AC_TRY_RUN([#include <stdio.h>
 197 main() { char c; c=250; exit((c > 0)?0:1); }],
 198 rsync_cv_HAVE_UNSIGNED_CHAR=yes,rsync_cv_HAVE_UNSIGNED_CHAR=no,rsync_cv_HAVE_UNSIGNED_CHAR=cross)])
 199 if test x"$rsync_cv_HAVE_UNSIGNED_CHAR" = x"yes"; then
 200     AC_DEFINE(HAVE_UNSIGNED_CHAR)
 201 fi
 202
 203 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 204 AC_TRY_RUN([#include <sys/types.h>
 205 #include <dirent.h>
 206 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 207 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 208 di->d_name[0] == 0) exit(0); exit(1);} ],
 209 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 210 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 211     AC_DEFINE(HAVE_BROKEN_READDIR)
 212 fi
 213
 214 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[
 215 AC_TRY_COMPILE([#include <sys/types.h>
 216 #include <utime.h>],
 217 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 218 rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no,rsync_cv_HAVE_UTIMBUF=cross)])
 219 if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then
 220     AC_DEFINE(HAVE_UTIMBUF)
 221 fi
 222
 223 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 224 AC_TRY_RUN([
 225 #include <sys/time.h>
 226 #include <unistd.h>
 227 main() { struct timeval tv; exit(gettimeofday(&tv, NULL));}],
 228            rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no,rsync_cv_HAVE_GETTIMEOFDAY_TZ=cross)])
 229 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" = x"yes"; then
 230     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ)
 231 fi
 232
 233
 234 AC_CACHE_CHECK([for broken inet_ntoa],rsync_cv_REPLACE_INET_NTOA,[
 235 AC_TRY_RUN([
 236 #include <stdio.h>
 237 #include <sys/types.h>
 238 #include <netinet/in.h>
 239 #include <arpa/inet.h>
 240 main() { struct in_addr ip; ip.s_addr = 0x12345678;
 241 if (strcmp(inet_ntoa(ip),"18.52.86.120") &&
 242     strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(1); }
 243 exit(0);}],
 244            rsync_cv_REPLACE_INET_NTOA=no,rsync_cv_REPLACE_INET_NTOA=yes,rsync_cv_REPLACE_INET_NTOA=cross)])
 245 if test x"$rsync_cv_REPLACE_INET_NTOA" = x"yes"; then
 246     AC_DEFINE(REPLACE_INET_NTOA)
 247 fi
 248
 249
 250 AC_CACHE_CHECK([for broken inet_aton],rsync_cv_REPLACE_INET_ATON,[
 251 AC_TRY_RUN([
 252 #include <stdio.h>
 253 #include <sys/types.h>
 254 #include <netinet/in.h>
 255 #include <arpa/inet.h>
 256 main() { struct in_addr ip;
 257 if (inet_aton("example", &ip) == 0) exit(0); exit(1);}],
 258            rsync_cv_REPLACE_INET_ATON=no,rsync_cv_REPLACE_INET_ATON=yes,rsync_cv_REPLACE_INET_ATON=cross)])
 259 if test x"$rsync_cv_REPLACE_INET_ATON" = x"yes"; then
 260     AC_DEFINE(REPLACE_INET_ATON)
 261 fi
 262
 263 #
 264 # The following test was mostly taken from the tcl/tk plus patches
 265 #
 266 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 267 rm -rf conftest*
 268 cat > conftest.$ac_ext <<EOF
 269 int main() { return 0; }
 270 EOF
 271 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 272 if test -f conftest..o; then
 273     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 274 else
 275     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 276 fi
 277 rm -rf conftest*
 278 ])
 279 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 280     OBJ_SAVE="#"
 281     OBJ_RESTORE="#"
 282     CC_SHOBJ_FLAG='-o $@'
 283 else
 284     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 285     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 286     CC_SHOBJ_FLAG=""
 287 fi
 288
 289 AC_SUBST(OBJ_SAVE)
 290 AC_SUBST(OBJ_RESTORE)
 291 AC_SUBST(CC_SHOBJ_FLAG)
 292 AC_SUBST(BUILD_POPT)
 293
 294 AC_OUTPUT(Makefile lib/dummy zlib/dummy)