configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(byteorder.h)
   3 AC_CONFIG_HEADER(config.h)
   4
   5 LDFLAGS=${LDFLAGS-""}
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_VALIDATE_CACHE_SYSTEM_TYPE
   9
  10 # compile with optimisation and without debugging by default, unless
  11 # --debug is given.  We must decide this before testing the compiler.
  12
  13 AC_ARG_ENABLE(debug,
  14         [  --enable-debug          including debugging symbols and features])
  15
  16 AC_MSG_CHECKING([whether to include debugging symbols])
  17 if test x"$enable_debug" = x"yes"
  18 then
  19     AC_MSG_RESULT(yes)
  20     # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can
  21     AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  22     CFLAGS=${CFLAGS-"-g"}
  23 else
  24     AC_MSG_RESULT(no)
  25     CFLAGS=${CFLAGS-"-O"}
  26 fi
  27
  28 # look for getconf early as this affects just about everything
  29 AC_CHECK_PROG(HAVE_GETCONF, getconf, "yes", "no")
  30 if test $HAVE_GETCONF = "yes"; then
  31         CFLAGS=$CFLAGS" "`getconf LFS_CFLAGS 2> /dev/null`
  32         LDFLAGS=$LDFLAGS" "`getconf LFS_LDFLAGS 2> /dev/null`
  33 fi
  34
  35 AC_ARG_WITH(included-popt,
  36         [  --with-included-popt    use bundled popt library, not from system])
  37
  38 dnl Checks for programs.
  39 AC_PROG_CC
  40 AC_PROG_INSTALL
  41 AC_SUBST(SHELL)
  42
  43
  44 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
  45 AC_DEFINE_UNQUOTED(HAVE_REMSH, $HAVE_REMSH)
  46
  47 AC_C_BIGENDIAN
  48 AC_HEADER_DIRENT
  49 AC_HEADER_TIME
  50 AC_HEADER_SYS_WAIT
  51 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h unistd.h utime.h grp.h)
  52 AC_CHECK_HEADERS(compat.h sys/param.h ctype.h sys/wait.h sys/ioctl.h)
  53 AC_CHECK_HEADERS(sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h)
  54 AC_CHECK_HEADERS(glob.h)
  55
  56 AC_CHECK_SIZEOF(int)
  57 AC_CHECK_SIZEOF(long)
  58 AC_CHECK_SIZEOF(short)
  59
  60 AC_C_INLINE
  61
  62 AC_TYPE_SIGNAL
  63 AC_TYPE_UID_T
  64 AC_TYPE_MODE_T
  65 AC_TYPE_OFF_T
  66 AC_TYPE_SIZE_T
  67 AC_TYPE_PID_T
  68 AC_TYPE_GETGROUPS
  69 AC_STRUCT_ST_RDEV
  70 AC_CHECK_TYPE(ino_t,unsigned)
  71
  72 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
  73     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
  74         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
  75 if test x"$rsync_cv_errno" = x"yes"; then
  76    AC_DEFINE(HAVE_ERRNO_DECL)
  77 fi
  78
  79 # The following test taken from the cvs sources
  80 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
  81 # These need checks to be before checks for any other functions that
  82 #    might be in the same libraries.
  83 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
  84 # libsocket.so which has a bad implementation of gethostbyname (it
  85 # only looks in /etc/hosts), so we only look for -lsocket if we need
  86 # it.
  87 AC_CHECK_FUNCS(connect)
  88 if test x"$ac_cv_func_connect" = x"no"; then
  89     case "$LIBS" in
  90     *-lnsl*) ;;
  91     *) AC_CHECK_LIB(nsl_s, printf) ;;
  92     esac
  93     case "$LIBS" in
  94     *-lnsl*) ;;
  95     *) AC_CHECK_LIB(nsl, printf) ;;
  96     esac
  97     case "$LIBS" in
  98     *-lsocket*) ;;
  99     *) AC_CHECK_LIB(socket, connect) ;;
 100     esac
 101     case "$LIBS" in
 102     *-linet*) ;;
 103     *) AC_CHECK_LIB(inet, connect) ;;
 104     esac
 105     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 106     dnl has been cached.
 107     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 108        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 109         # ac_cv_func_connect=yes
 110         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 111         AC_DEFINE(HAVE_CONNECT)
 112     fi
 113 fi
 114
 115 #
 116 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 117 #
 118 AC_CHECK_FUNCS(strcasecmp)
 119 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 120     AC_CHECK_LIB(resolv, strcasecmp)
 121 fi
 122
 123 AC_FUNC_MEMCMP
 124 AC_FUNC_UTIME_NULL
 125 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup strerror chown chmod mknod)
 126 AC_CHECK_FUNCS(fchmod fstat strchr readlink link utime utimes strftime)
 127 AC_CHECK_FUNCS(memmove lchown vsnprintf snprintf setsid glob strpbrk)
 128 AC_CHECK_FUNCS(strlcat strlcpy)
 129
 130 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 131 AC_TRY_RUN([#include <sys/types.h>
 132             #include <sys/socket.h>
 133             main() {
 134                 int fd[2];
 135                 exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 136             }],
 137 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
 138 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 139     AC_DEFINE(HAVE_SOCKETPAIR)
 140 fi
 141
 142 AC_CACHE_CHECK([for working fnmatch],rsync_cv_HAVE_FNMATCH,[
 143 AC_TRY_RUN([#include <fnmatch.h>
 144 main() { exit((fnmatch("*.o", "x.o", FNM_PATHNAME) == 0 &&
 145                fnmatch("a/b/*", "a/b/c/d", FNM_PATHNAME) != 0) ? 0: 1); }],
 146 rsync_cv_HAVE_FNMATCH=yes,rsync_cv_HAVE_FNMATCH=no,rsync_cv_HAVE_FNMATCH=cross)])
 147 if test x"$rsync_cv_HAVE_FNMATCH" = x"yes"; then
 148     AC_DEFINE(HAVE_FNMATCH)
 149 fi
 150
 151 AC_CONFIG_SUBDIRS(popt-1.2)
 152 AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 153
 154 AC_MSG_CHECKING("whether to use included libpopt...")
 155 if test x"$with_included_popt" = x"yes"
 156 then
 157     AC_MSG_RESULT("$srcdir/popt-1.2")
 158     BUILD_LIBPOPT=popt-1.2/libpopt.a
 159     LDFLAGS="$CFLAGS -L popt-1.2"
 160     CFLAGS="$CFLAGS -I $srcdir/popt-1.2"
 161 else
 162     AC_MSG_RESULT(no)
 163 fi
 164
 165 AC_CACHE_CHECK([for long long],rsync_cv_HAVE_LONGLONG,[
 166 AC_TRY_RUN([#include <stdio.h>
 167 main() { long long x = 1000000; x *= x; exit(((x/1000000) == 1000000)? 0: 1); }],
 168 rsync_cv_HAVE_LONGLONG=yes,rsync_cv_HAVE_LONGLONG=no,rsync_cv_HAVE_LONGLONG=cross)])
 169 if test x"$rsync_cv_HAVE_LONGLONG" = x"yes"; then
 170     AC_DEFINE(HAVE_LONGLONG)
 171 fi
 172
 173 AC_CACHE_CHECK([for off64_t],rsync_cv_HAVE_OFF64_T,[
 174 AC_TRY_RUN([#include <stdio.h>
 175 #include <sys/stat.h>
 176 main() { struct stat64 st; off64_t s; if (sizeof(off_t) == sizeof(off64_t)) exit(1); exit((lstat64("/dev/null", &st)==0)?0:1); }],
 177 rsync_cv_HAVE_OFF64_T=yes,rsync_cv_HAVE_OFF64_T=no,rsync_cv_HAVE_OFF64_T=cross)])
 178 if test x"$rsync_cv_HAVE_OFF64_T" = x"yes"; then
 179     AC_DEFINE(HAVE_OFF64_T)
 180 fi
 181
 182 AC_CACHE_CHECK([for short ino_t],rsync_cv_HAVE_SHORT_INO_T,[
 183 AC_TRY_RUN([#include <stdio.h>
 184 #include <sys/types.h>
 185 #include <sys/stat.h>
 186 main() { if (sizeof(ino_t) < sizeof(unsigned int)) return 0; return 1; }],
 187 rsync_cv_HAVE_SHORT_INO_T=yes,rsync_cv_HAVE_SHORT_INO_T=no,rsync_cv_HAVE_SHORT_INO_T=cross)])
 188 if test x"$rsync_cv_HAVE_SHORT_INO_T" = x"yes"; then
 189     AC_DEFINE(HAVE_SHORT_INO_T)
 190 fi
 191
 192 AC_CACHE_CHECK([for unsigned char],rsync_cv_HAVE_UNSIGNED_CHAR,[
 193 AC_TRY_RUN([#include <stdio.h>
 194 main() { char c; c=250; exit((c > 0)?0:1); }],
 195 rsync_cv_HAVE_UNSIGNED_CHAR=yes,rsync_cv_HAVE_UNSIGNED_CHAR=no,rsync_cv_HAVE_UNSIGNED_CHAR=cross)])
 196 if test x"$rsync_cv_HAVE_UNSIGNED_CHAR" = x"yes"; then
 197     AC_DEFINE(HAVE_UNSIGNED_CHAR)
 198 fi
 199
 200 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 201 AC_TRY_RUN([#include <sys/types.h>
 202 #include <dirent.h>
 203 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 204 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 205 di->d_name[0] == 0) exit(0); exit(1);} ],
 206 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 207 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 208     AC_DEFINE(HAVE_BROKEN_READDIR)
 209 fi
 210
 211 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[
 212 AC_TRY_COMPILE([#include <sys/types.h>
 213 #include <utime.h>],
 214 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 215 rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no,rsync_cv_HAVE_UTIMBUF=cross)])
 216 if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then
 217     AC_DEFINE(HAVE_UTIMBUF)
 218 fi
 219
 220 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 221 AC_TRY_RUN([
 222 #include <sys/time.h>
 223 #include <unistd.h>
 224 main() { struct timeval tv; exit(gettimeofday(&tv, NULL));}],
 225            rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no,rsync_cv_HAVE_GETTIMEOFDAY_TZ=cross)])
 226 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" = x"yes"; then
 227     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ)
 228 fi
 229
 230
 231 AC_CACHE_CHECK([for broken inet_ntoa],rsync_cv_REPLACE_INET_NTOA,[
 232 AC_TRY_RUN([
 233 #include <stdio.h>
 234 #include <sys/types.h>
 235 #include <netinet/in.h>
 236 #include <arpa/inet.h>
 237 main() { struct in_addr ip; ip.s_addr = 0x12345678;
 238 if (strcmp(inet_ntoa(ip),"18.52.86.120") &&
 239     strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(1); }
 240 exit(0);}],
 241            rsync_cv_REPLACE_INET_NTOA=no,rsync_cv_REPLACE_INET_NTOA=yes,rsync_cv_REPLACE_INET_NTOA=cross)])
 242 if test x"$rsync_cv_REPLACE_INET_NTOA" = x"yes"; then
 243     AC_DEFINE(REPLACE_INET_NTOA)
 244 fi
 245
 246
 247 AC_CACHE_CHECK([for broken inet_aton],rsync_cv_REPLACE_INET_ATON,[
 248 AC_TRY_RUN([
 249 #include <stdio.h>
 250 #include <sys/types.h>
 251 #include <netinet/in.h>
 252 #include <arpa/inet.h>
 253 main() { struct in_addr ip;
 254 if (inet_aton("example", &ip) == 0) exit(0); exit(1);}],
 255            rsync_cv_REPLACE_INET_ATON=no,rsync_cv_REPLACE_INET_ATON=yes,rsync_cv_REPLACE_INET_ATON=cross)])
 256 if test x"$rsync_cv_REPLACE_INET_ATON" = x"yes"; then
 257     AC_DEFINE(REPLACE_INET_ATON)
 258 fi
 259
 260 #
 261 # The following test was mostly taken from the tcl/tk plus patches
 262 #
 263 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 264 rm -rf conftest*
 265 cat > conftest.$ac_ext <<EOF
 266 int main() { return 0; }
 267 EOF
 268 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 269 if test -f conftest..o; then
 270     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 271 else
 272     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 273 fi
 274 rm -rf conftest*
 275 ])
 276 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 277     OBJ_SAVE="#"
 278     OBJ_RESTORE="#"
 279     CC_SHOBJ_FLAG='-o $@'
 280 else
 281     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 282     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 283     CC_SHOBJ_FLAG=""
 284 fi
 285
 286 AC_SUBST(OBJ_SAVE)
 287 AC_SUBST(OBJ_RESTORE)
 288 AC_SUBST(CC_SHOBJ_FLAG)
 289 AC_SUBST(BUILD_LIBPOPT)
 290
 291 AC_OUTPUT(Makefile lib/dummy zlib/dummy)