configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(byteorder.h)
   3 AC_CONFIG_HEADER(config.h)
   4
   5 # compile with optimisation and without debugging by default
   6 CFLAGS=${CFLAGS-"-O"}
   7
   8 AC_CANONICAL_SYSTEM
   9 AC_VALIDATE_CACHE_SYSTEM_TYPE
  10
  11 dnl Checks for programs.
  12 AC_PROG_CC
  13 AC_PROG_INSTALL
  14 AC_SUBST(SHELL)
  15
  16 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
  17 AC_DEFINE_UNQUOTED(HAVE_REMSH, $HAVE_REMSH)
  18
  19 AC_C_BIGENDIAN
  20 AC_HEADER_DIRENT
  21 AC_HEADER_TIME
  22 AC_HEADER_SYS_WAIT
  23 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h unistd.h utime.h grp.h)
  24 AC_CHECK_HEADERS(compat.h sys/param.h ctype.h sys/wait.h sys/ioctl.h)
  25 AC_CHECK_HEADERS(sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h)
  26 AC_CHECK_HEADERS(glob.h)
  27
  28 AC_CHECK_SIZEOF(int)
  29 AC_CHECK_SIZEOF(long)
  30 AC_CHECK_SIZEOF(short)
  31
  32 AC_C_INLINE
  33
  34 AC_TYPE_SIGNAL
  35 AC_TYPE_UID_T
  36 AC_TYPE_MODE_T
  37 AC_TYPE_OFF_T
  38 AC_TYPE_SIZE_T
  39 AC_TYPE_PID_T
  40 AC_STRUCT_ST_RDEV
  41 AC_CHECK_TYPE(ino_t,unsigned)
  42
  43 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
  44     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
  45         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
  46 if test x"$rsync_cv_errno" = x"yes"; then
  47    AC_DEFINE(HAVE_ERRNO_DECL)
  48 fi
  49
  50 AC_FUNC_MEMCMP
  51 AC_FUNC_UTIME_NULL
  52 AC_CHECK_FUNCS(mmap munmap waitpid getcwd strdup strerror chown chmod mknod)
  53 AC_CHECK_FUNCS(fchmod fstat strchr readlink link utime utimes strftime)
  54 AC_CHECK_FUNCS(memmove getopt_long lchown vsnprintf snprintf setsid glob strpbrk)
  55 AC_CHECK_FUNCS(strlcat strlcpy)
  56
  57 echo $ac_n "checking for working fnmatch... $ac_c"
  58 AC_TRY_RUN([#include <fnmatch.h>
  59 main() { exit(fnmatch("*.o", "x.o", 0) == 0? 0: 1); }],
  60 echo yes;AC_DEFINE(HAVE_FNMATCH),
  61 echo no)
  62
  63 AC_CACHE_CHECK([for long long],rsync_cv_have_longlong,[
  64 AC_TRY_RUN([#include <stdio.h>
  65 main() { long long x = 1000000; x *= x; exit(((x/1000000) == 1000000)? 0: 1); }],
  66 rsync_cv_have_longlong=yes,rsync_cv_have_longlong=no,rsync_cv_have_longlong=cross)])
  67 if test x"$rsync_cv_have_longlong" = x"yes"; then
  68     AC_DEFINE(HAVE_LONGLONG)
  69 fi
  70
  71 AC_CACHE_CHECK([for off64_t],rsync_cv_HAVE_OFF64_T,[
  72 AC_TRY_RUN([#include <stdio.h>
  73 #include <sys/stat.h>
  74 main() { struct stat64 st; off64_t s; if (sizeof(off_t) == sizeof(off64_t)) exit(1); exit((lstat64("/dev/null", &st)==0)?0:1); }],
  75 rsync_cv_HAVE_OFF64_T=yes,rsync_cv_HAVE_OFF64_T=no,rsync_cv_HAVE_OFF64_T=cross)])
  76 if test x"$rsync_cv_HAVE_OFF64_T" = x"yes"; then
  77     AC_DEFINE(HAVE_OFF64_T)
  78 fi
  79
  80 echo $ac_n "checking for short ino_t ... $ac_c"
  81 AC_TRY_RUN([#include <stdio.h>
  82 #include <sys/types.h>
  83 #include <sys/stat.h>
  84 main() { if (sizeof(ino_t) < sizeof(unsigned int)) return 0; return 1; }],
  85 echo yes;AC_DEFINE(HAVE_SHORT_INO_T),
  86 echo no)
  87
  88 AC_CACHE_CHECK([for unsigned char],rsync_cv_HAVE_UNSIGNED_CHAR,[
  89 AC_TRY_RUN([#include <stdio.h>
  90 main() { char c; c=250; exit((c > 0)?0:1); }],
  91 rsync_cv_HAVE_UNSIGNED_CHAR=yes,rsync_cv_HAVE_UNSIGNED_CHAR=no,rsync_cv_HAVE_UNSIGNED_CHAR=cross)])
  92 if test x"$rsync_cv_HAVE_UNSIGNED_CHAR" = x"yes"; then
  93     AC_DEFINE(HAVE_UNSIGNED_CHAR)
  94 fi
  95
  96 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
  97 AC_TRY_RUN([#include <sys/types.h>
  98 #include <dirent.h>
  99 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 100 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 101 di->d_name[0] == 0) exit(0); exit(1);} ],
 102 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 103 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 104     AC_DEFINE(HAVE_BROKEN_READDIR)
 105 fi
 106
 107 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[
 108 AC_TRY_COMPILE([#include <sys/types.h>
 109 #include <utime.h>],
 110 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 111 rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no,rsync_cv_HAVE_UTIMBUF=cross)])
 112 if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then
 113     AC_DEFINE(HAVE_UTIMBUF)
 114 fi
 115
 116 AC_CACHE_CHECK([for broken inet_ntoa],rsync_cv_REPLACE_INET_NTOA,[
 117 AC_TRY_RUN([
 118 #include <stdio.h>
 119 #include <sys/types.h>
 120 #include <netinet/in.h>
 121 #include <arpa/inet.h>
 122 main() { struct in_addr ip; ip.s_addr = 0x12345678;
 123 if (strcmp(inet_ntoa(ip),"18.52.86.120") &&
 124     strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(0); }
 125 exit(1);}],
 126            rsync_cv_REPLACE_INET_NTOA=yes,rsync_cv_REPLACE_INET_NTOA=no,rsync_cv_REPLACE_INET_NTOA=cross)])
 127 if test x"$rsync_cv_REPLACE_INET_NTOA" = x"yes"; then
 128     AC_DEFINE(REPLACE_INET_NTOA)
 129 fi
 130
 131 # The following test taken from the cvs sources
 132 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 133 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 134 # libsocket.so which has a bad implementation of gethostbyname (it
 135 # only looks in /etc/hosts), so we only look for -lsocket if we need
 136 # it.
 137 AC_CHECK_FUNCS(connect)
 138 if test x"$ac_cv_func_connect" = x"no"; then
 139     case "$LIBS" in
 140     *-lnsl*) ;;
 141     *) AC_CHECK_LIB(nsl_s, printf) ;;
 142     esac
 143     case "$LIBS" in
 144     *-lnsl*) ;;
 145     *) AC_CHECK_LIB(nsl, printf) ;;
 146     esac
 147     case "$LIBS" in
 148     *-lsocket*) ;;
 149     *) AC_CHECK_LIB(socket, connect) ;;
 150     esac
 151     case "$LIBS" in
 152     *-linet*) ;;
 153     *) AC_CHECK_LIB(inet, connect) ;;
 154     esac
 155     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 156     dnl has been cached.
 157     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 158        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 159         # ac_cv_func_connect=yes
 160         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 161         AC_DEFINE(HAVE_CONNECT)
 162     fi
 163 fi
 164
 165 #
 166 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 167 #
 168 AC_CHECK_FUNCS(strcasecmp)
 169 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 170     AC_CHECK_LIB(resolv, strcasecmp)
 171 fi
 172
 173 #
 174 # The following test was mostly taken from the tcl/tk plus patches
 175 #
 176 echo $ac_n "checking whether -c -o works ... $ac_c"
 177 rm -rf conftest*
 178 cat > conftest.$ac_ext <<EOF
 179 int main() { return 0; }
 180 EOF
 181 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 182 if test -f conftest..o; then
 183     OBJ_SAVE="#"
 184     OBJ_RESTORE="#"
 185     CC_SHOBJ_FLAG='-o $@'
 186     echo yes
 187 else
 188     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 189     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 190     CC_SHOBJ_FLAG=""
 191     echo no
 192 fi
 193 rm -rf conftest*
 194 AC_SUBST(OBJ_SAVE)
 195 AC_SUBST(OBJ_RESTORE)
 196 AC_SUBST(CC_SHOBJ_FLAG)
 197
 198
 199 AC_OUTPUT(Makefile lib/dummy zlib/dummy)