support/rrsync

   1 #!/usr/bin/perl
   2 # Name: /usr/local/bin/rrsync (should also have a symlink in /usr/bin)
   3 # Purpose: Restricts rsync to subdirectory declared in .ssh/authorized_keys
   4 # Author: Joe Smith <js-cgi@inwap.com> 30-Sep-2004
   5 # Modified by: Wayne Davison <wayned@samba.org>
   6 use strict;
   7
   8 use Socket;
   9 use Cwd 'abs_path';
  10 use File::Glob ':glob';
  11 use constant RSYNC => 'rsync'; # Optionally set the path of rsync here.
  12 use constant LOGFILE => 'rrsync.log';
  13 my $Usage = <<EOM;
  14 Use 'command="$0 [-ro] SUBDIR"'
  15         in front of lines in $ENV{HOME}/.ssh/authorized_keys
  16 EOM
  17
  18 our $ro = (@ARGV && $ARGV[0] eq '-ro') ? shift : '';    # -ro = Read-Only
  19 our $subdir = shift;
  20 die "$0: No subdirectory specified\n$Usage" unless defined $subdir;
  21 $subdir = abs_path($subdir);
  22 die "$0: Restricted directory does not exist!\n" if $subdir ne '/' && !-d $subdir;
  23
  24 # The client uses "rsync -av -e ssh src/ server:dir/", and sshd on the server
  25 # executes this program when .ssh/authorized_keys has 'command="..."'.
  26 # For example:
  27 # command="rrsync logs/client" ssh-rsa AAAAB3NzaC1yc2EAAAABIwAAAIEAzGhEeNlPr...
  28 # command="rrsync -ro results" ssh-rsa AAAAB3NzaC1yc2EAAAABIwAAAIEAmkHG1WCjC...
  29 #
  30 # Format of the envrionment variables set by sshd:
  31 # SSH_ORIGINAL_COMMAND=rsync --server          -vlogDtpr --partial . ARG # push
  32 # SSH_ORIGINAL_COMMAND=rsync --server --sender -vlogDtpr --partial . ARGS # pull
  33 # SSH_CONNECTION=client_addr client_port server_port
  34
  35 my $command = $ENV{SSH_ORIGINAL_COMMAND};
  36 die "$0: Not invoked via sshd\n$Usage"  unless defined $command;
  37 die "$0: SSH_ORIGINAL_COMMAND='$command' is not rsync\n" unless $command =~ s/^rsync\s+//;
  38 our $am_sender = $command =~ /^--server\s+--sender\s/; # Restrictive on purpose!
  39 die "$0 -ro: sending to read-only server not allowed\n" if $ro && !$am_sender;
  40
  41 ### START of options data produced by the cull-options script. ###
  42
  43 # These options are the only options that rsync might send to the
  44 # server, and only in the arg styles that the stock rsync produces.
  45 our $short_no_arg = 'CDHIKLORSWbcdglnoprtuvxz';
  46 our $short_with_num = 'B';
  47 # To disable a short-named option, add its letter to this string:
  48 our $short_disabled = '';
  49 # To disable a long-named option, change its value to a 0.  A value of -1
  50 # means the arg doesn't need checking, a 2 means only check when receiving.
  51 our %long_no_arg = (
  52   'copy-unsafe-links' => -1,
  53   'daemon' => -1,
  54   'delay-updates' => -1,
  55   'delete' => -1,
  56   'delete-after' => -1,
  57   'delete-before' => -1,
  58   'delete-during' => -1,
  59   'delete-excluded' => -1,
  60   'existing' => -1,
  61   'force' => -1,
  62   'from0' => -1,
  63   'fuzzy' => -1,
  64   'ignore-errors' => -1,
  65   'ignore-existing' => -1,
  66   'inplace' => -1,
  67   'list-only' => -1,
  68   'no-implied-dirs' => -1,
  69   'no-relative' => -1,
  70   'numeric-ids' => -1,
  71   'partial' => -1,
  72   'remove-sent-files' => $ro ? 0 : -1,
  73   'safe-links' => -1,
  74   'sender' => -1,
  75   'server' => -1,
  76   'size-only' => -1,
  77 );
  78 our %long_with_arg = (
  79   'bwlimit' => -1,
  80   'checksum-seed' => -1,
  81   'files-from' => 1,
  82   'log-format' => -1,
  83   'max-delete' => -1,
  84   'modify-window' => -1,
  85   'only-write-batch' => -1,
  86   'suffix' => -1,
  87   'timeout' => -1,
  88 );
  89 our %long_before_arg = (
  90   'backup-dir' => 2,
  91   'files-from' => 1,
  92   'max-size' => -1,
  93   'partial-dir' => 2,
  94   'temp-dir' => 2,
  95 );
  96
  97 ### END of options data produced by the cull-options script. ###
  98
  99 if ($short_disabled ne '') {
 100     $short_no_arg =~ s/[$short_disabled]//go;
 101     $short_with_num =~ s/[$short_disabled]//go;
 102 }
 103
 104 my $write_log = -f LOGFILE && open(LOG, '>>', LOGFILE);
 105
 106 chdir($subdir) or die "$0: Unable to chdir to restricted dir: $!\n";
 107
 108 my(@opts, @args);
 109 my $in_options = 1;
 110 my $last_opt = '';
 111 my $check_type;
 112 foreach (split(/(?<!\\)\s+/, $command)) {
 113   if ($check_type) {
 114     s/\\(.)/$1/g;
 115     push(@opts, check_arg($last_opt, $_, $check_type));
 116     $check_type = 0;
 117   } elsif ($in_options) {
 118     s/\\(.)/$1/g;
 119     push(@opts, $_);
 120     if ($_ eq '.') {
 121       $in_options = 0;
 122     } else {
 123       next if /^-[$short_no_arg]+$/o || /^-[$short_with_num]\d+$/o;
 124
 125       my($opt,$arg) = /^--([^=]+)(?:=(.*))?$/;
 126       my $disabled;
 127       if (defined $arg) {
 128         my $ct = $long_with_arg{$opt};
 129         if ($ct) {
 130           $arg = check_arg($opt, $arg, $ct);
 131           $opts[-1] =~ s/=.*/=$arg/;
 132           next;
 133         }
 134         $disabled = defined $long_with_arg{$opt};
 135         $opt = "--$opt";
 136       } elsif (defined $opt) {
 137         if (defined $long_no_arg{$opt}) {
 138           next if $long_no_arg{$opt};
 139           $disabled = 1;
 140         } else {
 141           $check_type = $long_before_arg{$opt};
 142           if ($check_type) {
 143             $last_opt = $opt;
 144             next;
 145           }
 146           $disabled = defined $check_type;
 147         }
 148         $opt = "--$opt";
 149       } elsif ($short_disabled ne '') {
 150         $disabled = /^-[$short_no_arg]*([$short_disabled])/o;
 151         $opt = "-$1" if $disabled;
 152       }
 153
 154       die "$0: option $opt has been disabled on this server.\n" if $disabled;
 155       last;
 156     }
 157   } else {
 158     if ($subdir ne '/') {
 159       # Validate args to ensure they don't try to leave our restricted dir.
 160       s#//+#/#g;
 161       s#^/##;
 162       s#^$#.#;
 163       die "Do not use .. in any path!\n" if m#(^|/)\\?\.\\?\.(\\?/|$)#;
 164     }
 165     push(@args, bsd_glob($_, GLOB_LIMIT|GLOB_NOCHECK|GLOB_BRACE|GLOB_QUOTE));
 166   }
 167 }
 168 die "$0: invalid rsync-command syntax or options\n" if $in_options;
 169
 170 @args = ( '.' ) if !@args;
 171
 172 if ($write_log) {
 173   my ($mm,$hh) = (localtime)[1,2];
 174   my $host = $ENV{SSH_CONNECTION} || 'unknown';
 175   $host =~ s/ .*//; # Keep only the client's IP addr
 176   $host =~ s/^::ffff://;
 177   $host = gethostbyaddr(inet_aton($host),AF_INET) || $host;
 178   printf LOG "%02d:%02d %-13s [%s]\n", $hh, $mm, $host, "@opts @args";
 179   close LOG;
 180 }
 181
 182 # Note: This assumes that the rsync protocol will not be maliciously hijacked.
 183 exec(RSYNC, @opts, @args) or die "exec(rsync @opts @args) failed: $? $!";
 184
 185 sub check_arg
 186 {
 187   my($opt, $arg, $type) = @_;
 188   if ($subdir ne '/' && $type > 0 && ($type < 2 || !$am_sender)) {
 189     $arg =~ s#//#/#g;
 190     die "Do not use .. in --$opt; anchor the path at the root of your restricted dir.\n"
 191       if $arg =~ m#(^|/)\.\.(/|$)#;
 192     $arg =~ s#^/#$subdir/#;
 193   }
 194   $arg;
 195 }