Got rid of the --no-ir kluge in this test.

[rsync/rsync.git] / configure.in

diff --git a/configure.in b/configure.in
index fb7b7cd..fba5556 100644 (file)
--- a/configure.in
+++ b/configure.in
@@ -346,6 +346,7 @@ AC_CHECK_SIZEOF(uint32_t)
 AC_CHECK_SIZEOF(int64_t)
 AC_CHECK_SIZEOF(off_t)
 AC_CHECK_SIZEOF(off64_t)
+AC_CHECK_SIZEOF(time_t)
 
 AC_C_INLINE
 AC_C_LONG_DOUBLE
@@ -567,6 +568,22 @@ if test $ac_cv_func_getpgrp = yes; then
     AC_FUNC_GETPGRP
 fi
 
+AC_ARG_ENABLE(iconv,
+    AC_HELP_STRING([--disable-iconv],
+           [disable rsync's --iconv option]),
+    [], [enable_iconv=$ac_cv_func_iconv_open])
+AH_TEMPLATE([ICONV_OPTION],
+[Define if you want the --iconv option.  Specifing a value will set the
+default iconv setting (a NULL means no --iconv processing by default).])
+if test x"$enable_iconv" != x"no"; then
+       if test x"$enable_iconv" = x"yes"; then
+               AC_DEFINE(ICONV_OPTION, NULL)
+       else
+               AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
+       fi
+       AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
+fi
+
 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
   AC_TRY_RUN([
 #if HAVE_UNISTD_H
@@ -856,7 +873,7 @@ else
        AC_DEFINE(SUPPORT_ACLS, 1)
        LIBS="$LIBS -lpacl"
        ;;
-    *darwin*)
+    darwin*)
        AC_MSG_RESULT(MacOS ACLs not yet supported)
        ;;
     *)
@@ -891,6 +908,46 @@ samba_cv_HAVE_ACL_GET_PERM_NP=yes,samba_cv_HAVE_ACL_GET_PERM_NP=no)])
     esac
 fi
 
+AC_CHECK_HEADERS(attr/xattr.h)
+AC_CHECK_HEADERS(sys/xattr.h)
+AC_CHECK_HEADERS(sys/extattr.h)
+
+#################################################
+# check for extended attribute support
+AC_MSG_CHECKING(whether to support extended attributes)
+AC_ARG_ENABLE(xattr-support,
+       AC_HELP_STRING([--disable-xattr-support],
+                      [Turn off extended attribute support]))
+
+if test x"$enable_xattr_support" = x"no"; then
+    AC_MSG_RESULT(no)
+else
+    case "$host_os" in
+    *linux*)
+       AC_MSG_RESULT(Using Linux xattrs)
+       AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs])
+       AC_DEFINE(SUPPORT_XATTRS, 1, [Define to 1 to add support for extended attributes])
+       ;;
+    darwin*)
+       AC_MSG_RESULT(Using OS X xattrs)
+       AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
+       AC_DEFINE(SUPPORT_XATTRS, 1)
+       ;;
+    freebsd*)
+       AC_MSG_RESULT(Using FreeBSD extattrs)
+       AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
+       AC_DEFINE(SUPPORT_XATTRS, 1)
+       ;;
+    *)
+       if test x"$enable_xattr_support" = x"yes"; then
+           AC_MSG_ERROR(Failed to find extended attribute support)
+       else
+           AC_MSG_RESULT(No extended attribute support found)
+       fi
+       ;;
+    esac
+fi
+
 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
 AC_OUTPUT