| 1 | dnl Process this file with autoconf to produce a configure script. |
| 2 | AC_INIT(byteorder.h) |
| 3 | AC_CONFIG_HEADER(config.h) |
| 4 | AC_PREREQ(2.12) |
| 5 | |
| 6 | LDFLAGS=${LDFLAGS-""} |
| 7 | |
| 8 | AC_CANONICAL_SYSTEM |
| 9 | AC_VALIDATE_CACHE_SYSTEM_TYPE |
| 10 | |
| 11 | # compile with optimisation and without debugging by default, unless |
| 12 | # --debug is given. We must decide this before testing the compiler. |
| 13 | |
| 14 | AC_ARG_ENABLE(debug, |
| 15 | [ --enable-debug including debugging symbols and features]) |
| 16 | |
| 17 | AC_MSG_CHECKING([whether to include debugging symbols]) |
| 18 | if test x"$enable_debug" = x"yes" |
| 19 | then |
| 20 | AC_MSG_RESULT(yes) |
| 21 | # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can |
| 22 | AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation]) |
| 23 | CFLAGS=${CFLAGS-"-g"} |
| 24 | else |
| 25 | AC_MSG_RESULT(no) |
| 26 | CFLAGS=${CFLAGS-"-O"} |
| 27 | fi |
| 28 | |
| 29 | CFLAGS="$CFLAGS -DHAVE_CONFIG_H" |
| 30 | |
| 31 | # look for getconf early as this affects just about everything |
| 32 | AC_CHECK_PROG(HAVE_GETCONF, getconf, "yes", "no") |
| 33 | if test $HAVE_GETCONF = "yes"; then |
| 34 | CFLAGS=$CFLAGS" "`getconf LFS_CFLAGS 2> /dev/null` |
| 35 | LDFLAGS=$LDFLAGS" "`getconf LFS_LDFLAGS 2> /dev/null` |
| 36 | fi |
| 37 | |
| 38 | AC_ARG_WITH(included-popt, |
| 39 | [ --with-included-popt use bundled popt library, not from system]) |
| 40 | |
| 41 | AC_ARG_WITH(rsync-path, |
| 42 | [ --with-rsync-path=PATH set default --rsync-path to PATH (default: \"rsync\")], |
| 43 | [ RSYNC_PATH="$with_rsync_name" ], |
| 44 | [ RSYNC_PATH="rsync" ]) |
| 45 | AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [ ]) |
| 46 | |
| 47 | dnl Checks for programs. |
| 48 | AC_PROG_CC |
| 49 | AC_PROG_INSTALL |
| 50 | AC_SUBST(SHELL) |
| 51 | |
| 52 | AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0) |
| 53 | AC_DEFINE_UNQUOTED(HAVE_REMSH, $HAVE_REMSH, [ ]) |
| 54 | |
| 55 | AC_SYS_LARGEFILE |
| 56 | AC_C_BIGENDIAN |
| 57 | AC_HEADER_DIRENT |
| 58 | AC_HEADER_TIME |
| 59 | AC_HEADER_SYS_WAIT |
| 60 | AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h unistd.h utime.h grp.h) |
| 61 | AC_CHECK_HEADERS(compat.h sys/param.h ctype.h sys/wait.h sys/ioctl.h) |
| 62 | AC_CHECK_HEADERS(sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h) |
| 63 | AC_CHECK_HEADERS(glob.h alloca.h mcheck.h) |
| 64 | |
| 65 | AC_CHECK_SIZEOF(int) |
| 66 | AC_CHECK_SIZEOF(long) |
| 67 | AC_CHECK_SIZEOF(short) |
| 68 | |
| 69 | AC_C_INLINE |
| 70 | |
| 71 | AC_TYPE_SIGNAL |
| 72 | AC_TYPE_UID_T |
| 73 | AC_TYPE_MODE_T |
| 74 | AC_TYPE_OFF_T |
| 75 | AC_TYPE_SIZE_T |
| 76 | AC_TYPE_PID_T |
| 77 | AC_TYPE_GETGROUPS |
| 78 | AC_STRUCT_ST_RDEV |
| 79 | AC_CHECK_TYPE(ino_t,unsigned, [ ]) |
| 80 | |
| 81 | AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [ |
| 82 | AC_TRY_COMPILE([#include <errno.h>],[int i = errno], |
| 83 | rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)]) |
| 84 | if test x"$rsync_cv_errno" = x"yes"; then |
| 85 | AC_DEFINE(HAVE_ERRNO_DECL, 1, [ ]) |
| 86 | fi |
| 87 | |
| 88 | # The following test taken from the cvs sources |
| 89 | # If we can't find connect, try looking in -lsocket, -lnsl, and -linet. |
| 90 | # These need checks to be before checks for any other functions that |
| 91 | # might be in the same libraries. |
| 92 | # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has |
| 93 | # libsocket.so which has a bad implementation of gethostbyname (it |
| 94 | # only looks in /etc/hosts), so we only look for -lsocket if we need |
| 95 | # it. |
| 96 | AC_CHECK_FUNCS(connect) |
| 97 | if test x"$ac_cv_func_connect" = x"no"; then |
| 98 | case "$LIBS" in |
| 99 | *-lnsl*) ;; |
| 100 | *) AC_CHECK_LIB(nsl_s, printf) ;; |
| 101 | esac |
| 102 | case "$LIBS" in |
| 103 | *-lnsl*) ;; |
| 104 | *) AC_CHECK_LIB(nsl, printf) ;; |
| 105 | esac |
| 106 | case "$LIBS" in |
| 107 | *-lsocket*) ;; |
| 108 | *) AC_CHECK_LIB(socket, connect) ;; |
| 109 | esac |
| 110 | case "$LIBS" in |
| 111 | *-linet*) ;; |
| 112 | *) AC_CHECK_LIB(inet, connect) ;; |
| 113 | esac |
| 114 | dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value |
| 115 | dnl has been cached. |
| 116 | if test x"$ac_cv_lib_socket_connect" = x"yes" || |
| 117 | test x"$ac_cv_lib_inet_connect" = x"yes"; then |
| 118 | # ac_cv_func_connect=yes |
| 119 | # don't! it would cause AC_CHECK_FUNC to succeed next time configure is run |
| 120 | AC_DEFINE(HAVE_CONNECT, 1, [ ]) |
| 121 | fi |
| 122 | fi |
| 123 | |
| 124 | # |
| 125 | # if we can't find strcasecmp, look in -lresolv (for Unixware at least) |
| 126 | # |
| 127 | AC_CHECK_FUNCS(strcasecmp) |
| 128 | if test x"$ac_cv_func_strcasecmp" = x"no"; then |
| 129 | AC_CHECK_LIB(resolv, strcasecmp) |
| 130 | fi |
| 131 | |
| 132 | AC_FUNC_MEMCMP |
| 133 | AC_FUNC_UTIME_NULL |
| 134 | AC_CHECK_FUNCS(waitpid wait4 getcwd strdup strerror chown chmod mknod) |
| 135 | AC_CHECK_FUNCS(fchmod fstat strchr readlink link utime utimes strftime) |
| 136 | AC_CHECK_FUNCS(memmove lchown vsnprintf snprintf asprintf setsid glob strpbrk) |
| 137 | AC_CHECK_FUNCS(strlcat strlcpy mtrace) |
| 138 | |
| 139 | AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[ |
| 140 | AC_TRY_RUN([#include <sys/types.h> |
| 141 | #include <sys/socket.h> |
| 142 | main() { |
| 143 | int fd[2]; |
| 144 | exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1); |
| 145 | }], |
| 146 | rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)]) |
| 147 | if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then |
| 148 | AC_DEFINE(HAVE_SOCKETPAIR, 1, [ ]) |
| 149 | fi |
| 150 | |
| 151 | AC_CACHE_CHECK([for working fnmatch],rsync_cv_HAVE_FNMATCH,[ |
| 152 | AC_TRY_RUN([#include <fnmatch.h> |
| 153 | main() { exit((fnmatch("*.o", "x.o", FNM_PATHNAME) == 0 && |
| 154 | fnmatch("a/b/*", "a/b/c/d", FNM_PATHNAME) != 0) ? 0: 1); }], |
| 155 | rsync_cv_HAVE_FNMATCH=yes,rsync_cv_HAVE_FNMATCH=no,rsync_cv_HAVE_FNMATCH=cross)]) |
| 156 | if test x"$rsync_cv_HAVE_FNMATCH" = x"yes"; then |
| 157 | AC_DEFINE(HAVE_FNMATCH, 1, [ ]) |
| 158 | fi |
| 159 | |
| 160 | if test x"$with_included_popt" != x"yes" |
| 161 | then |
| 162 | AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes]) |
| 163 | fi |
| 164 | |
| 165 | AC_MSG_CHECKING("whether to use included libpopt") |
| 166 | if test x"$with_included_popt" = x"yes" |
| 167 | then |
| 168 | AC_MSG_RESULT("$srcdir/popt") |
| 169 | BUILD_POPT='$(popt_OBJS)' |
| 170 | CFLAGS="$CFLAGS -I$srcdir/popt" |
| 171 | else |
| 172 | AC_MSG_RESULT(no) |
| 173 | fi |
| 174 | |
| 175 | AC_CACHE_CHECK([for long long],rsync_cv_HAVE_LONGLONG,[ |
| 176 | AC_TRY_RUN([#include <stdio.h> |
| 177 | main() { long long x = 1000000; x *= x; exit(((x/1000000) == 1000000)? 0: 1); }], |
| 178 | rsync_cv_HAVE_LONGLONG=yes,rsync_cv_HAVE_LONGLONG=no,rsync_cv_HAVE_LONGLONG=cross)]) |
| 179 | if test x"$rsync_cv_HAVE_LONGLONG" = x"yes"; then |
| 180 | AC_DEFINE(HAVE_LONGLONG, 1, [ ]) |
| 181 | fi |
| 182 | |
| 183 | AC_CACHE_CHECK([for off64_t],rsync_cv_HAVE_OFF64_T,[ |
| 184 | AC_TRY_RUN([#include <stdio.h> |
| 185 | #include <sys/stat.h> |
| 186 | main() { struct stat64 st; off64_t s; if (sizeof(off_t) == sizeof(off64_t)) exit(1); exit((lstat64("/dev/null", &st)==0)?0:1); }], |
| 187 | rsync_cv_HAVE_OFF64_T=yes,rsync_cv_HAVE_OFF64_T=no,rsync_cv_HAVE_OFF64_T=cross)]) |
| 188 | if test x"$rsync_cv_HAVE_OFF64_T" = x"yes"; then |
| 189 | AC_DEFINE(HAVE_OFF64_T, 1, [ ]) |
| 190 | fi |
| 191 | |
| 192 | AC_CACHE_CHECK([for short ino_t],rsync_cv_HAVE_SHORT_INO_T,[ |
| 193 | AC_TRY_RUN([#include <stdio.h> |
| 194 | #include <sys/types.h> |
| 195 | #include <sys/stat.h> |
| 196 | main() { if (sizeof(ino_t) < sizeof(unsigned int)) return 0; return 1; }], |
| 197 | rsync_cv_HAVE_SHORT_INO_T=yes,rsync_cv_HAVE_SHORT_INO_T=no,rsync_cv_HAVE_SHORT_INO_T=cross)]) |
| 198 | if test x"$rsync_cv_HAVE_SHORT_INO_T" = x"yes"; then |
| 199 | AC_DEFINE(HAVE_SHORT_INO_T, 1, [ ]) |
| 200 | fi |
| 201 | |
| 202 | AC_CACHE_CHECK([for unsigned char],rsync_cv_HAVE_UNSIGNED_CHAR,[ |
| 203 | AC_TRY_RUN([#include <stdio.h> |
| 204 | main() { char c; c=250; exit((c > 0)?0:1); }], |
| 205 | rsync_cv_HAVE_UNSIGNED_CHAR=yes,rsync_cv_HAVE_UNSIGNED_CHAR=no,rsync_cv_HAVE_UNSIGNED_CHAR=cross)]) |
| 206 | if test x"$rsync_cv_HAVE_UNSIGNED_CHAR" = x"yes"; then |
| 207 | AC_DEFINE(HAVE_UNSIGNED_CHAR, 1, [ ]) |
| 208 | fi |
| 209 | |
| 210 | AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[ |
| 211 | AC_TRY_RUN([#include <sys/types.h> |
| 212 | #include <dirent.h> |
| 213 | main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d); |
| 214 | if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 && |
| 215 | di->d_name[0] == 0) exit(0); exit(1);} ], |
| 216 | rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)]) |
| 217 | if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then |
| 218 | AC_DEFINE(HAVE_BROKEN_READDIR, 1, [ ]) |
| 219 | fi |
| 220 | |
| 221 | AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[ |
| 222 | AC_TRY_COMPILE([#include <sys/types.h> |
| 223 | #include <utime.h>], |
| 224 | [struct utimbuf tbuf; tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));], |
| 225 | rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no,rsync_cv_HAVE_UTIMBUF=cross)]) |
| 226 | if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then |
| 227 | AC_DEFINE(HAVE_UTIMBUF, 1, [ ]) |
| 228 | fi |
| 229 | |
| 230 | AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[ |
| 231 | AC_TRY_RUN([ |
| 232 | #include <sys/time.h> |
| 233 | #include <unistd.h> |
| 234 | main() { struct timeval tv; exit(gettimeofday(&tv, NULL));}], |
| 235 | rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no,rsync_cv_HAVE_GETTIMEOFDAY_TZ=cross)]) |
| 236 | if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" = x"yes"; then |
| 237 | AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [ ]) |
| 238 | fi |
| 239 | |
| 240 | AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[ |
| 241 | AC_TRY_RUN([ |
| 242 | #include <sys/types.h> |
| 243 | #include <stdarg.h> |
| 244 | void foo(const char *format, ...) { |
| 245 | va_list ap; |
| 246 | int len; |
| 247 | char buf[5]; |
| 248 | |
| 249 | va_start(ap, format); |
| 250 | len = vsnprintf(0, 0, format, ap); |
| 251 | va_end(ap); |
| 252 | if (len != 5) exit(1); |
| 253 | |
| 254 | if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1); |
| 255 | |
| 256 | exit(0); |
| 257 | } |
| 258 | main() { foo("hello"); } |
| 259 | ], |
| 260 | rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)]) |
| 261 | if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then |
| 262 | AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [ ]) |
| 263 | fi |
| 264 | |
| 265 | |
| 266 | AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[ |
| 267 | AC_TRY_RUN([#include <stdlib.h> |
| 268 | #include <sys/types.h> |
| 269 | #include <sys/stat.h> |
| 270 | #include <unistd.h> |
| 271 | main() { |
| 272 | struct stat st; |
| 273 | char tpl[20]="/tmp/test.XXXXXX"; |
| 274 | int fd = mkstemp(tpl); |
| 275 | if (fd == -1) exit(1); |
| 276 | unlink(tpl); |
| 277 | if (fstat(fd, &st) != 0) exit(1); |
| 278 | if ((st.st_mode & 0777) != 0600) exit(1); |
| 279 | exit(0); |
| 280 | }], |
| 281 | rsync_cv_HAVE_SECURE_MKSTEMP=yes, |
| 282 | rsync_cv_HAVE_SECURE_MKSTEMP=no, |
| 283 | rsync_cv_HAVE_SECURE_MKSTEMP=cross)]) |
| 284 | if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then |
| 285 | AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [ ]) |
| 286 | fi |
| 287 | |
| 288 | |
| 289 | AC_CACHE_CHECK([for broken inet_ntoa],rsync_cv_REPLACE_INET_NTOA,[ |
| 290 | AC_TRY_RUN([ |
| 291 | #include <stdio.h> |
| 292 | #include <sys/types.h> |
| 293 | #include <netinet/in.h> |
| 294 | #include <arpa/inet.h> |
| 295 | main() { struct in_addr ip; ip.s_addr = 0x12345678; |
| 296 | if (strcmp(inet_ntoa(ip),"18.52.86.120") && |
| 297 | strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(1); } |
| 298 | exit(0);}], |
| 299 | rsync_cv_REPLACE_INET_NTOA=no,rsync_cv_REPLACE_INET_NTOA=yes,rsync_cv_REPLACE_INET_NTOA=cross)]) |
| 300 | if test x"$rsync_cv_REPLACE_INET_NTOA" = x"yes"; then |
| 301 | AC_DEFINE(REPLACE_INET_NTOA, 1, [ ]) |
| 302 | fi |
| 303 | |
| 304 | |
| 305 | AC_CACHE_CHECK([for broken inet_aton],rsync_cv_REPLACE_INET_ATON,[ |
| 306 | AC_TRY_RUN([ |
| 307 | #include <stdio.h> |
| 308 | #include <sys/types.h> |
| 309 | #include <netinet/in.h> |
| 310 | #include <arpa/inet.h> |
| 311 | main() { struct in_addr ip; |
| 312 | if (inet_aton("example", &ip) == 0) exit(0); exit(1);}], |
| 313 | rsync_cv_REPLACE_INET_ATON=no,rsync_cv_REPLACE_INET_ATON=yes,rsync_cv_REPLACE_INET_ATON=cross)]) |
| 314 | if test x"$rsync_cv_REPLACE_INET_ATON" = x"yes"; then |
| 315 | AC_DEFINE(REPLACE_INET_ATON, 1, [ ]) |
| 316 | fi |
| 317 | |
| 318 | # |
| 319 | # The following test was mostly taken from the tcl/tk plus patches |
| 320 | # |
| 321 | AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[ |
| 322 | rm -rf conftest* |
| 323 | cat > conftest.$ac_ext <<EOF |
| 324 | int main() { return 0; } |
| 325 | EOF |
| 326 | ${CC-cc} -c -o conftest..o conftest.$ac_ext |
| 327 | if test -f conftest..o; then |
| 328 | rsync_cv_DASHC_WORKS_WITH_DASHO=yes |
| 329 | else |
| 330 | rsync_cv_DASHC_WORKS_WITH_DASHO=no |
| 331 | fi |
| 332 | rm -rf conftest* |
| 333 | ]) |
| 334 | if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then |
| 335 | OBJ_SAVE="#" |
| 336 | OBJ_RESTORE="#" |
| 337 | CC_SHOBJ_FLAG='-o $@' |
| 338 | else |
| 339 | OBJ_SAVE=' @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;' |
| 340 | OBJ_RESTORE=' @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi' |
| 341 | CC_SHOBJ_FLAG="" |
| 342 | fi |
| 343 | |
| 344 | AC_SUBST(OBJ_SAVE) |
| 345 | AC_SUBST(OBJ_RESTORE) |
| 346 | AC_SUBST(CC_SHOBJ_FLAG) |
| 347 | AC_SUBST(BUILD_POPT) |
| 348 | |
| 349 | AC_OUTPUT(Makefile lib/dummy zlib/dummy) |