| 1 | dnl Process this file with autoconf to produce a configure script. |
| 2 | |
| 3 | AC_INIT() |
| 4 | AC_CONFIG_SRCDIR([byteorder.h]) |
| 5 | AC_CONFIG_HEADER(config.h) |
| 6 | AC_PREREQ(2.59) |
| 7 | |
| 8 | RSYNC_VERSION=3.0.0cvs |
| 9 | AC_SUBST(RSYNC_VERSION) |
| 10 | AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION]) |
| 11 | |
| 12 | AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version]) |
| 13 | |
| 14 | LDFLAGS=${LDFLAGS-""} |
| 15 | |
| 16 | AC_CANONICAL_TARGET([]) |
| 17 | |
| 18 | dnl Checks for programs. |
| 19 | AC_PROG_CC |
| 20 | AC_PROG_CPP |
| 21 | AC_PROG_EGREP |
| 22 | AC_PROG_INSTALL |
| 23 | AC_PROG_CC_STDC |
| 24 | AC_SUBST(SHELL) |
| 25 | |
| 26 | AC_DEFINE([_GNU_SOURCE], 1, |
| 27 | [Define _GNU_SOURCE so that we get all necessary prototypes]) |
| 28 | |
| 29 | if test x"$ac_cv_prog_cc_stdc" = x"no"; then |
| 30 | AC_MSG_WARN([rsync requires an ANSI C compiler and you don't seem to have one]) |
| 31 | fi |
| 32 | |
| 33 | # We must decide this before testing the compiler. |
| 34 | |
| 35 | # Please allow this to default to yes, so that your users have more |
| 36 | # chance of getting a useful stack trace if problems occur. |
| 37 | |
| 38 | AC_MSG_CHECKING([whether to include debugging symbols]) |
| 39 | AC_ARG_ENABLE(debug, |
| 40 | AC_HELP_STRING([--disable-debug], |
| 41 | [turn off debugging symbols and features])) |
| 42 | |
| 43 | if test x"$enable_debug" = x"no"; then |
| 44 | AC_MSG_RESULT(no) |
| 45 | CFLAGS=${CFLAGS-"-O"} |
| 46 | else |
| 47 | AC_MSG_RESULT([yes]) |
| 48 | # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can |
| 49 | dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation]) |
| 50 | dnl CFLAGS=${CFLAGS-"-g"} |
| 51 | fi |
| 52 | |
| 53 | |
| 54 | AC_ARG_ENABLE(profile, |
| 55 | AC_HELP_STRING([--enable-profile], |
| 56 | [turn on CPU profiling])) |
| 57 | if test x"$enable_profile" = x"yes"; then |
| 58 | CFLAGS="$CFLAGS -pg" |
| 59 | fi |
| 60 | |
| 61 | |
| 62 | # Specifically, this turns on panic_action handling. |
| 63 | AC_ARG_ENABLE(maintainer-mode, |
| 64 | AC_HELP_STRING([--enable-maintainer-mode], |
| 65 | [turn on extra debug features])) |
| 66 | if test x"$enable_maintainer_mode" = x"yes"; then |
| 67 | CFLAGS="$CFLAGS -DMAINTAINER_MODE" |
| 68 | fi |
| 69 | |
| 70 | |
| 71 | # This is needed for our included version of popt. Kind of silly, but |
| 72 | # I don't want our version too far out of sync. |
| 73 | CFLAGS="$CFLAGS -DHAVE_CONFIG_H" |
| 74 | |
| 75 | # If GCC, turn on warnings. |
| 76 | if test x"$GCC" = x"yes"; then |
| 77 | CFLAGS="$CFLAGS -Wall -W" |
| 78 | fi |
| 79 | |
| 80 | AC_ARG_WITH(included-popt, |
| 81 | AC_HELP_STRING([--with-included-popt], [use bundled popt library, not from system])) |
| 82 | |
| 83 | AC_ARG_WITH(rsync-path, |
| 84 | AC_HELP_STRING([--with-rsync-path=PATH], [set default --rsync-path to PATH (default: rsync)]), |
| 85 | [ RSYNC_PATH="$with_rsync_path" ], |
| 86 | [ RSYNC_PATH="rsync" ]) |
| 87 | |
| 88 | AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine]) |
| 89 | |
| 90 | AC_ARG_WITH(rsyncd-conf, |
| 91 | AC_HELP_STRING([--with-rsyncd-conf=PATH], [set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]), |
| 92 | [ if test ! -z "$with_rsyncd_conf" ; then |
| 93 | case $with_rsyncd_conf in |
| 94 | yes|no) |
| 95 | RSYNCD_SYSCONF="/etc/rsyncd.conf" |
| 96 | ;; |
| 97 | /*) |
| 98 | RSYNCD_SYSCONF="$with_rsyncd_conf" |
| 99 | ;; |
| 100 | *) |
| 101 | AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH) |
| 102 | ;; |
| 103 | esac |
| 104 | else |
| 105 | RSYNCD_SYSCONF="/etc/rsyncd.conf" |
| 106 | fi ], |
| 107 | [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ]) |
| 108 | |
| 109 | AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server]) |
| 110 | |
| 111 | AC_ARG_WITH(rsh, |
| 112 | AC_HELP_STRING([--with-rsh=CMD], [set remote shell command to CMD (default: ssh)])) |
| 113 | |
| 114 | AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0) |
| 115 | if test x$HAVE_REMSH = x1; then |
| 116 | AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh]) |
| 117 | fi |
| 118 | |
| 119 | if test x"$with_rsh" != x; then |
| 120 | RSYNC_RSH="$with_rsh" |
| 121 | else |
| 122 | RSYNC_RSH="ssh" |
| 123 | fi |
| 124 | AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command]) |
| 125 | |
| 126 | AC_ARG_WITH(nobody-group, |
| 127 | AC_HELP_STRING([--with-nobody-group=GROUP], |
| 128 | [set the default unprivileged group (default nobody or nogroup)]), |
| 129 | [ NOBODY_GROUP="$with_nobody_group" ]) |
| 130 | |
| 131 | if test x"$with_nobody_group" = x; then |
| 132 | AC_MSG_CHECKING([the group for user "nobody"]) |
| 133 | if grep '^nobody:' /etc/group >/dev/null 2>&1; then |
| 134 | NOBODY_GROUP=nobody |
| 135 | elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then |
| 136 | NOBODY_GROUP=nogroup |
| 137 | else |
| 138 | NOBODY_GROUP=nobody # test for others? |
| 139 | fi |
| 140 | AC_MSG_RESULT($NOBODY_GROUP) |
| 141 | fi |
| 142 | |
| 143 | AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody]) |
| 144 | AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user]) |
| 145 | |
| 146 | # arrgh. libc in some old debian version screwed up the largefile |
| 147 | # stuff, getting byte range locking wrong |
| 148 | AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[ |
| 149 | AC_TRY_RUN([ |
| 150 | #define _FILE_OFFSET_BITS 64 |
| 151 | #include <stdio.h> |
| 152 | #include <fcntl.h> |
| 153 | #include <sys/types.h> |
| 154 | #include <sys/wait.h> |
| 155 | |
| 156 | int main(void) |
| 157 | { |
| 158 | struct flock lock; |
| 159 | int status; |
| 160 | char tpl[32] = "/tmp/locktest.XXXXXX"; |
| 161 | int fd = mkstemp(tpl); |
| 162 | if (fd < 0) { |
| 163 | strcpy(tpl, "conftest.dat"); |
| 164 | fd = open(tpl, O_CREAT|O_RDWR, 0600); |
| 165 | } |
| 166 | |
| 167 | lock.l_type = F_WRLCK; |
| 168 | lock.l_whence = SEEK_SET; |
| 169 | lock.l_start = 0; |
| 170 | lock.l_len = 1; |
| 171 | lock.l_pid = 0; |
| 172 | fcntl(fd,F_SETLK,&lock); |
| 173 | if (fork() == 0) { |
| 174 | lock.l_start = 1; |
| 175 | _exit(fcntl(fd,F_SETLK,&lock) == 0); |
| 176 | } |
| 177 | wait(&status); |
| 178 | unlink(tpl); |
| 179 | exit(WEXITSTATUS(status)); |
| 180 | } |
| 181 | ], |
| 182 | rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)]) |
| 183 | if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then |
| 184 | AC_SYS_LARGEFILE |
| 185 | fi |
| 186 | |
| 187 | ipv6type=unknown |
| 188 | ipv6lib=none |
| 189 | ipv6trylibc=yes |
| 190 | |
| 191 | AC_ARG_ENABLE(ipv6, |
| 192 | AC_HELP_STRING([--disable-ipv6], |
| 193 | [don't even try to use IPv6])) |
| 194 | if test x"$enable_ipv6" != x"no"; then |
| 195 | AC_MSG_CHECKING([ipv6 stack type]) |
| 196 | for i in inria kame linux-glibc linux-inet6 toshiba v6d zeta; do |
| 197 | case $i in |
| 198 | inria) |
| 199 | # http://www.kame.net/ |
| 200 | AC_EGREP_CPP(yes, [ |
| 201 | #include <netinet/in.h> |
| 202 | #ifdef IPV6_INRIA_VERSION |
| 203 | yes |
| 204 | #endif], |
| 205 | [ipv6type=$i; |
| 206 | AC_DEFINE(INET6, 1, [true if you have IPv6]) |
| 207 | ]) |
| 208 | ;; |
| 209 | kame) |
| 210 | # http://www.kame.net/ |
| 211 | AC_EGREP_CPP(yes, [ |
| 212 | #include <netinet/in.h> |
| 213 | #ifdef __KAME__ |
| 214 | yes |
| 215 | #endif], |
| 216 | [ipv6type=$i; |
| 217 | AC_DEFINE(INET6, 1, [true if you have IPv6])]) |
| 218 | ;; |
| 219 | linux-glibc) |
| 220 | # http://www.v6.linux.or.jp/ |
| 221 | AC_EGREP_CPP(yes, [ |
| 222 | #include <features.h> |
| 223 | #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1 |
| 224 | yes |
| 225 | #endif], |
| 226 | [ipv6type=$i; |
| 227 | AC_DEFINE(INET6, 1, [true if you have IPv6])]) |
| 228 | ;; |
| 229 | linux-inet6) |
| 230 | # http://www.v6.linux.or.jp/ |
| 231 | if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then |
| 232 | ipv6type=$i |
| 233 | ipv6lib=inet6 |
| 234 | ipv6libdir=/usr/inet6/lib |
| 235 | ipv6trylibc=yes; |
| 236 | AC_DEFINE(INET6, 1, [true if you have IPv6]) |
| 237 | CFLAGS="-I/usr/inet6/include $CFLAGS" |
| 238 | fi |
| 239 | ;; |
| 240 | toshiba) |
| 241 | AC_EGREP_CPP(yes, [ |
| 242 | #include <sys/param.h> |
| 243 | #ifdef _TOSHIBA_INET6 |
| 244 | yes |
| 245 | #endif], |
| 246 | [ipv6type=$i; |
| 247 | ipv6lib=inet6; |
| 248 | ipv6libdir=/usr/local/v6/lib; |
| 249 | AC_DEFINE(INET6, 1, [true if you have IPv6])]) |
| 250 | ;; |
| 251 | v6d) |
| 252 | AC_EGREP_CPP(yes, [ |
| 253 | #include </usr/local/v6/include/sys/v6config.h> |
| 254 | #ifdef __V6D__ |
| 255 | yes |
| 256 | #endif], |
| 257 | [ipv6type=$i; |
| 258 | ipv6lib=v6; |
| 259 | ipv6libdir=/usr/local/v6/lib; |
| 260 | AC_DEFINE(INET6, 1, [true if you have IPv6])]) |
| 261 | ;; |
| 262 | zeta) |
| 263 | AC_EGREP_CPP(yes, [ |
| 264 | #include <sys/param.h> |
| 265 | #ifdef _ZETA_MINAMI_INET6 |
| 266 | yes |
| 267 | #endif], |
| 268 | [ipv6type=$i; |
| 269 | ipv6lib=inet6; |
| 270 | ipv6libdir=/usr/local/v6/lib; |
| 271 | AC_DEFINE(INET6, 1, [true if you have IPv6])]) |
| 272 | ;; |
| 273 | esac |
| 274 | if test "$ipv6type" != "unknown"; then |
| 275 | break |
| 276 | fi |
| 277 | done |
| 278 | AC_MSG_RESULT($ipv6type) |
| 279 | |
| 280 | AC_SEARCH_LIBS(getaddrinfo, inet6) |
| 281 | fi |
| 282 | |
| 283 | dnl Do you want to disable use of locale functions |
| 284 | AC_ARG_ENABLE([locale], |
| 285 | AC_HELP_STRING([--disable-locale], |
| 286 | [turn off locale features])) |
| 287 | AH_TEMPLATE([CONFIG_LOCALE], |
| 288 | [Undefine if you don't want locale features. By default this is defined.]) |
| 289 | if test x"$enable_locale" != x"no"; then |
| 290 | AC_DEFINE(CONFIG_LOCALE) |
| 291 | fi |
| 292 | |
| 293 | AC_MSG_CHECKING([whether to call shutdown on all sockets]) |
| 294 | case $host_os in |
| 295 | *cygwin* ) AC_MSG_RESULT(yes) |
| 296 | AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1, |
| 297 | [Define to 1 if sockets need to be shutdown]) |
| 298 | ;; |
| 299 | * ) AC_MSG_RESULT(no);; |
| 300 | esac |
| 301 | |
| 302 | AC_C_BIGENDIAN |
| 303 | AC_HEADER_DIRENT |
| 304 | AC_HEADER_TIME |
| 305 | AC_HEADER_SYS_WAIT |
| 306 | AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \ |
| 307 | unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \ |
| 308 | sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \ |
| 309 | sys/un.h glob.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \ |
| 310 | netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h) |
| 311 | AC_HEADER_MAJOR |
| 312 | |
| 313 | AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[ |
| 314 | AC_TRY_RUN([ |
| 315 | #include <sys/types.h> |
| 316 | #ifdef MAJOR_IN_MKDEV |
| 317 | #include <sys/mkdev.h> |
| 318 | # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__) |
| 319 | # define makedev mkdev |
| 320 | # endif |
| 321 | #elif defined MAJOR_IN_SYSMACROS |
| 322 | #include <sys/sysmacros.h> |
| 323 | #endif |
| 324 | |
| 325 | int main(void) |
| 326 | { |
| 327 | dev_t dev = makedev(0, 5, 7); |
| 328 | if (major(dev) != 5 || minor(dev) != 7) |
| 329 | exit(1); |
| 330 | return 0; |
| 331 | } |
| 332 | ], |
| 333 | rsync_cv_MAKEDEV_TAKES_3_ARGS=yes,rsync_cv_MAKEDEV_TAKES_3_ARGS=no,rsync_cv_MAKEDEV_TAKES_3_ARGS=no)]) |
| 334 | if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then |
| 335 | AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args]) |
| 336 | fi |
| 337 | |
| 338 | AC_CHECK_SIZEOF(int) |
| 339 | AC_CHECK_SIZEOF(long) |
| 340 | AC_CHECK_SIZEOF(long long) |
| 341 | AC_CHECK_SIZEOF(short) |
| 342 | AC_CHECK_SIZEOF(int16_t) |
| 343 | AC_CHECK_SIZEOF(uint16_t) |
| 344 | AC_CHECK_SIZEOF(int32_t) |
| 345 | AC_CHECK_SIZEOF(uint32_t) |
| 346 | AC_CHECK_SIZEOF(int64_t) |
| 347 | AC_CHECK_SIZEOF(off_t) |
| 348 | AC_CHECK_SIZEOF(off64_t) |
| 349 | AC_CHECK_SIZEOF(time_t) |
| 350 | |
| 351 | AC_C_INLINE |
| 352 | AC_C_LONG_DOUBLE |
| 353 | |
| 354 | AC_TYPE_SIGNAL |
| 355 | AC_TYPE_UID_T |
| 356 | AC_TYPE_MODE_T |
| 357 | AC_TYPE_OFF_T |
| 358 | AC_TYPE_SIZE_T |
| 359 | AC_TYPE_PID_T |
| 360 | AC_TYPE_GETGROUPS |
| 361 | AC_CHECK_MEMBERS([struct stat.st_rdev]) |
| 362 | |
| 363 | TYPE_SOCKLEN_T |
| 364 | |
| 365 | AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [ |
| 366 | AC_TRY_COMPILE([#include <errno.h>],[int i = errno], |
| 367 | rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)]) |
| 368 | if test x"$rsync_cv_errno" = x"yes"; then |
| 369 | AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h]) |
| 370 | fi |
| 371 | |
| 372 | # The following test taken from the cvs sources |
| 373 | # If we can't find connect, try looking in -lsocket, -lnsl, and -linet. |
| 374 | # These need checks to be before checks for any other functions that |
| 375 | # might be in the same libraries. |
| 376 | # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has |
| 377 | # libsocket.so which has a bad implementation of gethostbyname (it |
| 378 | # only looks in /etc/hosts), so we only look for -lsocket if we need |
| 379 | # it. |
| 380 | AC_CHECK_FUNCS(connect) |
| 381 | if test x"$ac_cv_func_connect" = x"no"; then |
| 382 | case "$LIBS" in |
| 383 | *-lnsl*) ;; |
| 384 | *) AC_CHECK_LIB(nsl_s, printf) ;; |
| 385 | esac |
| 386 | case "$LIBS" in |
| 387 | *-lnsl*) ;; |
| 388 | *) AC_CHECK_LIB(nsl, printf) ;; |
| 389 | esac |
| 390 | case "$LIBS" in |
| 391 | *-lsocket*) ;; |
| 392 | *) AC_CHECK_LIB(socket, connect) ;; |
| 393 | esac |
| 394 | case "$LIBS" in |
| 395 | *-linet*) ;; |
| 396 | *) AC_CHECK_LIB(inet, connect) ;; |
| 397 | esac |
| 398 | dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value |
| 399 | dnl has been cached. |
| 400 | if test x"$ac_cv_lib_socket_connect" = x"yes" || |
| 401 | test x"$ac_cv_lib_inet_connect" = x"yes"; then |
| 402 | # ac_cv_func_connect=yes |
| 403 | # don't! it would cause AC_CHECK_FUNC to succeed next time configure is run |
| 404 | AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function]) |
| 405 | fi |
| 406 | fi |
| 407 | |
| 408 | AC_SEARCH_LIBS(inet_ntop, resolv) |
| 409 | |
| 410 | # Solaris and HP-UX weirdness: |
| 411 | # Search for libiconv_open (not iconv_open) to discover if -liconv is needed! |
| 412 | AC_SEARCH_LIBS(libiconv_open, iconv) |
| 413 | |
| 414 | AC_MSG_CHECKING([for iconv declaration]) |
| 415 | AC_CACHE_VAL(am_cv_proto_iconv, [ |
| 416 | AC_TRY_COMPILE([ |
| 417 | #include <stdlib.h> |
| 418 | #include <iconv.h> |
| 419 | extern |
| 420 | #ifdef __cplusplus |
| 421 | "C" |
| 422 | #endif |
| 423 | #if defined(__STDC__) || defined(__cplusplus) |
| 424 | size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft); |
| 425 | #else |
| 426 | size_t iconv(); |
| 427 | #endif |
| 428 | ], [], am_cv_proto_iconv_arg1="", am_cv_proto_iconv_arg1="const") |
| 429 | am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"]) |
| 430 | am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'` |
| 431 | AC_MSG_RESULT([$]{ac_t:- |
| 432 | }[$]am_cv_proto_iconv) |
| 433 | AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1, |
| 434 | [Define as const if the declaration of iconv() needs const.]) |
| 435 | |
| 436 | dnl AC_MSG_NOTICE([Looking in libraries: $LIBS]) |
| 437 | |
| 438 | AC_CHECK_FUNCS(inet_ntop, , [AC_LIBOBJ(lib/inet_ntop)]) |
| 439 | AC_CHECK_FUNCS(inet_pton, , [AC_LIBOBJ(lib/inet_pton)]) |
| 440 | |
| 441 | # Irix 6.5 has getaddrinfo but not the corresponding defines, so use |
| 442 | # builtin getaddrinfo if one of the defines don't exist |
| 443 | AC_CACHE_CHECK([whether defines needed by getaddrinfo exist], |
| 444 | rsync_cv_HAVE_GETADDR_DEFINES,[ |
| 445 | AC_EGREP_CPP(yes, [ |
| 446 | #include <sys/types.h> |
| 447 | #include <sys/socket.h> |
| 448 | #include <netdb.h> |
| 449 | #ifdef AI_PASSIVE |
| 450 | yes |
| 451 | #endif], |
| 452 | rsync_cv_HAVE_GETADDR_DEFINES=yes, |
| 453 | rsync_cv_HAVE_GETADDR_DEFINES=no)]) |
| 454 | if test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes"; then |
| 455 | # Tru64 UNIX has getaddrinfo() but has it renamed in libc as |
| 456 | # something else so we must include <netdb.h> to get the |
| 457 | # redefinition. |
| 458 | AC_CHECK_FUNCS(getaddrinfo, , |
| 459 | [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>]) |
| 460 | AC_TRY_LINK([#include <sys/types.h> |
| 461 | #include <sys/socket.h> |
| 462 | #include <netdb.h>],[getaddrinfo(NULL, NULL, NULL, NULL);], |
| 463 | [AC_MSG_RESULT([yes]) |
| 464 | AC_DEFINE(HAVE_GETADDRINFO, 1, |
| 465 | [Define to 1 if you have the "getaddrinfo" function.])], |
| 466 | [AC_MSG_RESULT([no]) |
| 467 | AC_LIBOBJ(lib/getaddrinfo)])]) |
| 468 | AC_CHECK_FUNCS(getnameinfo, , [AC_LIBOBJ(lib/getnameinfo)]) |
| 469 | else |
| 470 | AC_LIBOBJ(lib/getaddrinfo) |
| 471 | AC_LIBOBJ(lib/getnameinfo) |
| 472 | fi |
| 473 | |
| 474 | AC_CHECK_MEMBER([struct sockaddr.sa_len], |
| 475 | [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ], |
| 476 | [], |
| 477 | [ |
| 478 | #include <sys/types.h> |
| 479 | #include <sys/socket.h> |
| 480 | ]) |
| 481 | |
| 482 | AC_CHECK_MEMBER([struct sockaddr_in.sin_len], |
| 483 | [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ], |
| 484 | [], |
| 485 | [ |
| 486 | #include <sys/types.h> |
| 487 | #include <sys/socket.h> |
| 488 | #include <netinet/in.h> |
| 489 | ]) |
| 490 | |
| 491 | AC_CHECK_MEMBER([struct sockaddr_un.sun_len], |
| 492 | [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ], |
| 493 | [], |
| 494 | [ |
| 495 | #include <sys/types.h> |
| 496 | #include <sys/socket.h> |
| 497 | #include <netinet/in.h> |
| 498 | ]) |
| 499 | |
| 500 | AC_MSG_CHECKING(struct sockaddr_storage) |
| 501 | AC_TRY_COMPILE([#include <sys/types.h> |
| 502 | #include <sys/socket.h>], |
| 503 | [struct sockaddr_storage x;], |
| 504 | AC_MSG_RESULT(yes) |
| 505 | AC_DEFINE(HAVE_SOCKADDR_STORAGE, 1, |
| 506 | [Define to 1 if you have struct sockaddr_storage.] ), |
| 507 | AC_MSG_RESULT(no)) |
| 508 | |
| 509 | AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id], |
| 510 | [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ], |
| 511 | [], |
| 512 | [ |
| 513 | #include <sys/types.h> |
| 514 | #include <sys/socket.h> |
| 515 | #include <netinet/in.h> |
| 516 | ]) |
| 517 | |
| 518 | AC_MSG_CHECKING(struct stat64) |
| 519 | AC_TRY_COMPILE([#include <stdio.h> |
| 520 | #if HAVE_SYS_TYPES_H |
| 521 | # include <sys/types.h> |
| 522 | #endif |
| 523 | #if HAVE_SYS_STAT_H |
| 524 | # include <sys/stat.h> |
| 525 | #endif |
| 526 | #if STDC_HEADERS |
| 527 | # include <stdlib.h> |
| 528 | # include <stddef.h> |
| 529 | #else |
| 530 | # if HAVE_STDLIB_H |
| 531 | # include <stdlib.h> |
| 532 | # endif |
| 533 | #endif |
| 534 | ],[struct stat64 st;], |
| 535 | AC_MSG_RESULT(yes) |
| 536 | AC_DEFINE(HAVE_STRUCT_STAT64,1,[Define to 1 if you have struct stat64.]), |
| 537 | AC_MSG_RESULT(no)) |
| 538 | |
| 539 | # if we can't find strcasecmp, look in -lresolv (for Unixware at least) |
| 540 | # |
| 541 | AC_CHECK_FUNCS(strcasecmp) |
| 542 | if test x"$ac_cv_func_strcasecmp" = x"no"; then |
| 543 | AC_CHECK_LIB(resolv, strcasecmp) |
| 544 | fi |
| 545 | |
| 546 | AC_CHECK_FUNCS(aclsort) |
| 547 | if test x"$ac_cv_func_aclsort" = x"no"; then |
| 548 | AC_CHECK_LIB(sec, aclsort) |
| 549 | fi |
| 550 | |
| 551 | dnl At the moment we don't test for a broken memcmp(), because all we |
| 552 | dnl need to do is test for equality, not comparison, and it seems that |
| 553 | dnl every platform has a memcmp that can do at least that. |
| 554 | dnl AC_FUNC_MEMCMP |
| 555 | |
| 556 | AC_FUNC_UTIME_NULL |
| 557 | AC_FUNC_ALLOCA |
| 558 | AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \ |
| 559 | fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \ |
| 560 | memmove lchown vsnprintf snprintf vasprintf asprintf setsid glob strpbrk \ |
| 561 | strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \ |
| 562 | setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \ |
| 563 | strerror putenv iconv_open locale_charset nl_langinfo \ |
| 564 | sigaction sigprocmask) |
| 565 | |
| 566 | AC_CHECK_FUNCS(getpgrp tcgetpgrp) |
| 567 | if test $ac_cv_func_getpgrp = yes; then |
| 568 | AC_FUNC_GETPGRP |
| 569 | fi |
| 570 | |
| 571 | AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[ |
| 572 | AC_TRY_RUN([ |
| 573 | #if HAVE_UNISTD_H |
| 574 | # include <unistd.h> |
| 575 | #endif |
| 576 | #include <stdlib.h> |
| 577 | #include <errno.h> |
| 578 | main() { |
| 579 | char const *dangling_symlink = "conftest.dangle"; |
| 580 | unlink(dangling_symlink); |
| 581 | if (symlink("conftest.no-such", dangling_symlink) < 0) abort(); |
| 582 | if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) exit(1); |
| 583 | exit(0); |
| 584 | }], |
| 585 | rsync_cv_chown_modifies_symlink=yes,rsync_cv_chown_modifies_symlink=no,rsync_cv_chown_modifies_symlink=no)]) |
| 586 | if test $rsync_cv_chown_modifies_symlink = yes; then |
| 587 | AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.]) |
| 588 | fi |
| 589 | |
| 590 | AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[ |
| 591 | AC_TRY_RUN([ |
| 592 | #if HAVE_UNISTD_H |
| 593 | # include <unistd.h> |
| 594 | #endif |
| 595 | #include <stdlib.h> |
| 596 | #include <errno.h> |
| 597 | #define FILENAME "conftest.dangle" |
| 598 | main() { |
| 599 | unlink(FILENAME); |
| 600 | if (symlink("conftest.no-such", FILENAME) < 0) abort(); |
| 601 | if (link(FILENAME, FILENAME "2") < 0) exit(1); |
| 602 | exit(0); |
| 603 | }], |
| 604 | rsync_cv_can_hardlink_symlink=yes,rsync_cv_can_hardlink_symlink=no,rsync_cv_can_hardlink_symlink=no)]) |
| 605 | if test $rsync_cv_can_hardlink_symlink = yes; then |
| 606 | AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.]) |
| 607 | fi |
| 608 | |
| 609 | AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[ |
| 610 | AC_TRY_RUN([ |
| 611 | #if HAVE_UNISTD_H |
| 612 | # include <unistd.h> |
| 613 | #endif |
| 614 | #include <stdlib.h> |
| 615 | #include <errno.h> |
| 616 | #define FILENAME "conftest.fifi" |
| 617 | main() { |
| 618 | unlink(FILENAME); |
| 619 | if (mkfifo(FILENAME, 0777) < 0) abort(); |
| 620 | if (link(FILENAME, FILENAME "2") < 0) exit(1); |
| 621 | exit(0); |
| 622 | }], |
| 623 | rsync_cv_can_hardlink_special=yes,rsync_cv_can_hardlink_special=no,rsync_cv_can_hardlink_special=no)]) |
| 624 | if test $rsync_cv_can_hardlink_special = yes; then |
| 625 | AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.]) |
| 626 | fi |
| 627 | |
| 628 | AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[ |
| 629 | AC_TRY_RUN([ |
| 630 | #include <sys/types.h> |
| 631 | #include <sys/socket.h> |
| 632 | |
| 633 | main() { |
| 634 | int fd[2]; |
| 635 | exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1); |
| 636 | }], |
| 637 | rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)]) |
| 638 | if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then |
| 639 | AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function]) |
| 640 | fi |
| 641 | |
| 642 | if test x"$with_included_popt" != x"yes"; then |
| 643 | AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes]) |
| 644 | fi |
| 645 | |
| 646 | AC_MSG_CHECKING([whether to use included libpopt]) |
| 647 | if test x"$with_included_popt" = x"yes"; then |
| 648 | AC_MSG_RESULT($srcdir/popt) |
| 649 | BUILD_POPT='$(popt_OBJS)' |
| 650 | CFLAGS="$CFLAGS -I$srcdir/popt" |
| 651 | if test x"$ALLOCA" != x |
| 652 | then |
| 653 | # this can be removed when/if we add an included alloca.c; |
| 654 | # see autoconf documentation on AC_FUNC_ALLOCA |
| 655 | AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)]) |
| 656 | fi |
| 657 | else |
| 658 | AC_MSG_RESULT(no) |
| 659 | fi |
| 660 | |
| 661 | AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[ |
| 662 | AC_TRY_COMPILE([],[signed char *s = ""], |
| 663 | rsync_cv_SIGNED_CHAR_OK=yes,rsync_cv_SIGNED_CHAR_OK=no)]) |
| 664 | if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then |
| 665 | AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type]) |
| 666 | fi |
| 667 | |
| 668 | AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[ |
| 669 | AC_TRY_RUN([#include <sys/types.h> |
| 670 | #include <dirent.h> |
| 671 | main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d); |
| 672 | if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 && |
| 673 | di->d_name[0] == 0) exit(0); exit(1);} ], |
| 674 | rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)]) |
| 675 | if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then |
| 676 | AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken]) |
| 677 | fi |
| 678 | |
| 679 | AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[ |
| 680 | AC_TRY_COMPILE([#include <sys/types.h> |
| 681 | #include <utime.h>], |
| 682 | [struct utimbuf tbuf; tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));], |
| 683 | rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no)]) |
| 684 | if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then |
| 685 | AC_DEFINE(HAVE_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type]) |
| 686 | fi |
| 687 | |
| 688 | AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[ |
| 689 | AC_TRY_COMPILE([#include <sys/time.h> |
| 690 | #include <unistd.h>], |
| 691 | [struct timeval tv; exit(gettimeofday(&tv, NULL));], |
| 692 | rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no)]) |
| 693 | if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then |
| 694 | AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg]) |
| 695 | fi |
| 696 | |
| 697 | AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[ |
| 698 | AC_TRY_RUN([ |
| 699 | #include <sys/types.h> |
| 700 | #include <stdarg.h> |
| 701 | void foo(const char *format, ...) { |
| 702 | va_list ap; |
| 703 | int len; |
| 704 | char buf[5]; |
| 705 | |
| 706 | va_start(ap, format); |
| 707 | len = vsnprintf(0, 0, format, ap); |
| 708 | va_end(ap); |
| 709 | if (len != 5) exit(1); |
| 710 | |
| 711 | if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1); |
| 712 | |
| 713 | exit(0); |
| 714 | } |
| 715 | main() { foo("hello"); } |
| 716 | ], |
| 717 | rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)]) |
| 718 | if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then |
| 719 | AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value]) |
| 720 | fi |
| 721 | |
| 722 | |
| 723 | AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[ |
| 724 | AC_TRY_RUN([#include <stdlib.h> |
| 725 | #include <sys/types.h> |
| 726 | #include <sys/stat.h> |
| 727 | #include <unistd.h> |
| 728 | main() { |
| 729 | struct stat st; |
| 730 | char tpl[20]="/tmp/test.XXXXXX"; |
| 731 | int fd = mkstemp(tpl); |
| 732 | if (fd == -1) exit(1); |
| 733 | unlink(tpl); |
| 734 | if (fstat(fd, &st) != 0) exit(1); |
| 735 | if ((st.st_mode & 0777) != 0600) exit(1); |
| 736 | exit(0); |
| 737 | }], |
| 738 | rsync_cv_HAVE_SECURE_MKSTEMP=yes, |
| 739 | rsync_cv_HAVE_SECURE_MKSTEMP=no, |
| 740 | rsync_cv_HAVE_SECURE_MKSTEMP=cross)]) |
| 741 | if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then |
| 742 | case $target_os in |
| 743 | hpux*) |
| 744 | dnl HP-UX has a broken mkstemp() implementation they refuse to fix, |
| 745 | dnl so we noisily skip using it. See HP change request JAGaf34426 |
| 746 | dnl for details. (sbonds) |
| 747 | AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead) |
| 748 | ;; |
| 749 | *) |
| 750 | AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right]) |
| 751 | ;; |
| 752 | esac |
| 753 | fi |
| 754 | |
| 755 | |
| 756 | AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[ |
| 757 | AC_TRY_RUN([ |
| 758 | #include <stdio.h> |
| 759 | #include <sys/stat.h> |
| 760 | #include <errno.h> |
| 761 | main() { int rc, ec; char *fn = "fifo-test"; |
| 762 | unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn); |
| 763 | if (rc) {printf("(%d %d) ",rc,ec); return ec;} |
| 764 | return 0;}], |
| 765 | rsync_cv_MKNOD_CREATES_FIFOS=yes,rsync_cv_MKNOD_CREATES_FIFOS=no,rsync_cv_MKNOD_CREATES_FIFOS=cross)]) |
| 766 | if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then |
| 767 | AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.]) |
| 768 | fi |
| 769 | |
| 770 | AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[ |
| 771 | AC_TRY_RUN([ |
| 772 | #include <stdio.h> |
| 773 | #include <sys/stat.h> |
| 774 | #include <errno.h> |
| 775 | main() { int rc, ec; char *fn = "sock-test"; |
| 776 | unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn); |
| 777 | if (rc) {printf("(%d %d) ",rc,ec); return ec;} |
| 778 | return 0;}], |
| 779 | rsync_cv_MKNOD_CREATES_SOCKETS=yes,rsync_cv_MKNOD_CREATES_SOCKETS=no,rsync_cv_MKNOD_CREATES_SOCKETS=cross)]) |
| 780 | if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then |
| 781 | AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.]) |
| 782 | fi |
| 783 | |
| 784 | # |
| 785 | # The following test was mostly taken from the tcl/tk plus patches |
| 786 | # |
| 787 | AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[ |
| 788 | rm -rf conftest* |
| 789 | cat > conftest.$ac_ext <<EOF |
| 790 | int main() { return 0; } |
| 791 | EOF |
| 792 | ${CC-cc} -c -o conftest..o conftest.$ac_ext |
| 793 | if test -f conftest..o; then |
| 794 | rsync_cv_DASHC_WORKS_WITH_DASHO=yes |
| 795 | else |
| 796 | rsync_cv_DASHC_WORKS_WITH_DASHO=no |
| 797 | fi |
| 798 | rm -rf conftest* |
| 799 | ]) |
| 800 | if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then |
| 801 | OBJ_SAVE="#" |
| 802 | OBJ_RESTORE="#" |
| 803 | CC_SHOBJ_FLAG='-o $@' |
| 804 | else |
| 805 | OBJ_SAVE=' @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;' |
| 806 | OBJ_RESTORE=' @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi' |
| 807 | CC_SHOBJ_FLAG="" |
| 808 | fi |
| 809 | |
| 810 | AC_SUBST(OBJ_SAVE) |
| 811 | AC_SUBST(OBJ_RESTORE) |
| 812 | AC_SUBST(CC_SHOBJ_FLAG) |
| 813 | AC_SUBST(BUILD_POPT) |
| 814 | |
| 815 | AC_CHECK_HEADERS(sys/acl.h acl/libacl.h) |
| 816 | AC_CHECK_FUNCS(_acl __acl _facl __facl) |
| 817 | ################################################# |
| 818 | # check for ACL support |
| 819 | |
| 820 | AC_MSG_CHECKING([whether to support ACLs]) |
| 821 | AC_ARG_ENABLE(acl-support, |
| 822 | AC_HELP_STRING([--disable-acl-support], |
| 823 | [Turn off ACL support])) |
| 824 | |
| 825 | if test x"$enable_acl_support" = x"no"; then |
| 826 | AC_MSG_RESULT(no) |
| 827 | else |
| 828 | case "$host_os" in |
| 829 | *sysv5*) |
| 830 | AC_MSG_RESULT(Using UnixWare ACLs) |
| 831 | AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs]) |
| 832 | AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs]) |
| 833 | ;; |
| 834 | *solaris*|*cygwin*) |
| 835 | AC_MSG_RESULT(Using solaris ACLs) |
| 836 | AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs]) |
| 837 | AC_DEFINE(SUPPORT_ACLS, 1) |
| 838 | ;; |
| 839 | *hpux*) |
| 840 | AC_MSG_RESULT(Using HPUX ACLs) |
| 841 | AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs]) |
| 842 | AC_DEFINE(SUPPORT_ACLS, 1) |
| 843 | ;; |
| 844 | *irix*) |
| 845 | AC_MSG_RESULT(Using IRIX ACLs) |
| 846 | AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs]) |
| 847 | AC_DEFINE(SUPPORT_ACLS, 1) |
| 848 | ;; |
| 849 | *aix*) |
| 850 | AC_MSG_RESULT(Using AIX ACLs) |
| 851 | AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs]) |
| 852 | AC_DEFINE(SUPPORT_ACLS, 1) |
| 853 | ;; |
| 854 | *osf*) |
| 855 | AC_MSG_RESULT(Using Tru64 ACLs) |
| 856 | AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs]) |
| 857 | AC_DEFINE(SUPPORT_ACLS, 1) |
| 858 | LIBS="$LIBS -lpacl" |
| 859 | ;; |
| 860 | darwin*) |
| 861 | AC_MSG_RESULT(MacOS ACLs not yet supported) |
| 862 | ;; |
| 863 | *) |
| 864 | AC_MSG_RESULT(running tests:) |
| 865 | AC_CHECK_LIB(acl,acl_get_file) |
| 866 | AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[ |
| 867 | AC_TRY_LINK([#include <sys/types.h> |
| 868 | #include <sys/acl.h>], |
| 869 | [ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);], |
| 870 | samba_cv_HAVE_POSIX_ACLS=yes,samba_cv_HAVE_POSIX_ACLS=no)]) |
| 871 | AC_MSG_CHECKING(ACL test results) |
| 872 | if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then |
| 873 | AC_MSG_RESULT(Using posix ACLs) |
| 874 | AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs]) |
| 875 | AC_DEFINE(SUPPORT_ACLS, 1) |
| 876 | AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[ |
| 877 | AC_TRY_LINK([#include <sys/types.h> |
| 878 | #include <sys/acl.h>], |
| 879 | [ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);], |
| 880 | samba_cv_HAVE_ACL_GET_PERM_NP=yes,samba_cv_HAVE_ACL_GET_PERM_NP=no)]) |
| 881 | if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then |
| 882 | AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np]) |
| 883 | fi |
| 884 | else |
| 885 | if test x"$enable_acl_support" = x"yes"; then |
| 886 | AC_MSG_ERROR(Failed to find ACL support) |
| 887 | else |
| 888 | AC_MSG_RESULT(No ACL support found) |
| 889 | fi |
| 890 | fi |
| 891 | ;; |
| 892 | esac |
| 893 | fi |
| 894 | |
| 895 | AC_CHECK_HEADERS(attr/xattr.h) |
| 896 | AC_CHECK_HEADERS(sys/xattr.h) |
| 897 | AC_CHECK_HEADERS(sys/extattr.h) |
| 898 | |
| 899 | ################################################# |
| 900 | # check for extended attribute support |
| 901 | AC_MSG_CHECKING(whether to support extended attributes) |
| 902 | AC_ARG_ENABLE(xattr-support, |
| 903 | AC_HELP_STRING([--disable-xattr-support], |
| 904 | [Turn off extended attribute support])) |
| 905 | |
| 906 | if test x"$enable_xattr_support" = x"no"; then |
| 907 | AC_MSG_RESULT(no) |
| 908 | else |
| 909 | case "$host_os" in |
| 910 | *linux*) |
| 911 | AC_MSG_RESULT(Using Linux xattrs) |
| 912 | AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs]) |
| 913 | AC_DEFINE(SUPPORT_XATTRS, 1, [Define to 1 to add support for extended attributes]) |
| 914 | ;; |
| 915 | darwin*) |
| 916 | AC_MSG_RESULT(Using OS X xattrs) |
| 917 | AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs]) |
| 918 | AC_DEFINE(SUPPORT_XATTRS, 1) |
| 919 | ;; |
| 920 | freebsd*) |
| 921 | AC_MSG_RESULT(Using FreeBSD extattrs) |
| 922 | AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs]) |
| 923 | AC_DEFINE(SUPPORT_XATTRS, 1) |
| 924 | ;; |
| 925 | *) |
| 926 | if test x"$enable_xattr_support" = x"yes"; then |
| 927 | AC_MSG_ERROR(Failed to find extended attribute support) |
| 928 | else |
| 929 | AC_MSG_RESULT(No extended attribute support found) |
| 930 | fi |
| 931 | ;; |
| 932 | esac |
| 933 | fi |
| 934 | |
| 935 | AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig]) |
| 936 | AC_OUTPUT |
| 937 | |
| 938 | AC_MSG_RESULT() |
| 939 | AC_MSG_RESULT([ rsync ${RSYNC_VERSION} configuration successful]) |
| 940 | AC_MSG_RESULT() |