| 1 | dnl Process this file with autoconf to produce a configure script. |
| 2 | |
| 3 | AC_INIT() |
| 4 | AC_CONFIG_SRCDIR([byteorder.h]) |
| 5 | AC_CONFIG_HEADER(config.h) |
| 6 | AC_PREREQ(2.52) |
| 7 | |
| 8 | RSYNC_VERSION=2.6.3 |
| 9 | AC_SUBST(RSYNC_VERSION) |
| 10 | AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION]) |
| 11 | |
| 12 | AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version]) |
| 13 | |
| 14 | LDFLAGS=${LDFLAGS-""} |
| 15 | |
| 16 | AC_CANONICAL_TARGET([]) |
| 17 | |
| 18 | dnl Checks for programs. |
| 19 | AC_PROG_CC |
| 20 | AC_PROG_CPP |
| 21 | AC_PROG_EGREP |
| 22 | AC_PROG_INSTALL |
| 23 | AC_PROG_CC_STDC |
| 24 | AC_SUBST(SHELL) |
| 25 | |
| 26 | AC_DEFINE([_GNU_SOURCE], 1, |
| 27 | [Define _GNU_SOURCE so that we get all necessary prototypes]) |
| 28 | |
| 29 | if test "x$ac_cv_prog_cc_stdc" = xno |
| 30 | then |
| 31 | AC_MSG_WARN([rsync requires an ANSI C compiler and you don't seem to have one]) |
| 32 | fi |
| 33 | |
| 34 | # We must decide this before testing the compiler. |
| 35 | |
| 36 | # Please allow this to default to yes, so that your users have more |
| 37 | # chance of getting a useful stack trace if problems occur. |
| 38 | |
| 39 | AC_MSG_CHECKING([whether to include debugging symbols]) |
| 40 | AC_ARG_ENABLE(debug, |
| 41 | AC_HELP_STRING([--enable-debug], |
| 42 | [including debugging symbols and features (default yes)]), |
| 43 | [], []) |
| 44 | |
| 45 | if test x"$enable_debug" = x"no" |
| 46 | then |
| 47 | AC_MSG_RESULT(no) |
| 48 | CFLAGS=${CFLAGS-"-O"} |
| 49 | else |
| 50 | AC_MSG_RESULT([yes]) |
| 51 | # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can |
| 52 | dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation]) |
| 53 | dnl CFLAGS=${CFLAGS-"-g"} |
| 54 | fi |
| 55 | |
| 56 | |
| 57 | |
| 58 | |
| 59 | AC_ARG_ENABLE(profile, |
| 60 | AC_HELP_STRING([--enable-profile], |
| 61 | [turn on CPU profiling (default no)], |
| 62 | [], [])) |
| 63 | if test x"$enable_profile" = xyes |
| 64 | then |
| 65 | CFLAGS="$CFLAGS -pg" |
| 66 | fi |
| 67 | |
| 68 | |
| 69 | # Specifically, this turns on panic_action handling. |
| 70 | AC_ARG_ENABLE(maintainer-mode, |
| 71 | AC_HELP_STRING([--enable-maintainer-mode], |
| 72 | [turn on extra debug features], |
| 73 | [], [])) |
| 74 | if test x"$enable_maintainer_mode" = xyes |
| 75 | then |
| 76 | CFLAGS="$CFLAGS -DMAINTAINER_MODE" |
| 77 | fi |
| 78 | |
| 79 | |
| 80 | # This is needed for our included version of popt. Kind of silly, but |
| 81 | # I don't want our version too far out of sync. |
| 82 | CFLAGS="$CFLAGS -DHAVE_CONFIG_H" |
| 83 | |
| 84 | # If GCC, turn on warnings. |
| 85 | if test "x$GCC" = "xyes" |
| 86 | then |
| 87 | CFLAGS="$CFLAGS -Wall -W" |
| 88 | fi |
| 89 | |
| 90 | AC_ARG_WITH(included-popt, |
| 91 | [ --with-included-popt use bundled popt library, not from system]) |
| 92 | |
| 93 | AC_ARG_WITH(rsync-path, |
| 94 | [ --with-rsync-path=PATH set default --rsync-path to PATH (default: rsync)], |
| 95 | [ RSYNC_PATH="$with_rsync_path" ], |
| 96 | [ RSYNC_PATH="rsync" ]) |
| 97 | |
| 98 | AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine]) |
| 99 | |
| 100 | AC_ARG_WITH(rsyncd-conf, |
| 101 | AC_HELP_STRING([--with-rsyncd-conf=PATH], [set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]), |
| 102 | [ if test ! -z "$with_rsyncd_conf" ; then |
| 103 | case $with_rsyncd_conf in |
| 104 | yes|no) |
| 105 | RSYNCD_SYSCONF="/etc/rsyncd.conf" |
| 106 | ;; |
| 107 | /*) |
| 108 | RSYNCD_SYSCONF="$with_rsyncd_conf" |
| 109 | ;; |
| 110 | *) |
| 111 | AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH) |
| 112 | ;; |
| 113 | esac |
| 114 | else |
| 115 | RSYNCD_SYSCONF="/etc/rsyncd.conf" |
| 116 | fi ], |
| 117 | [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ]) |
| 118 | |
| 119 | AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server]) |
| 120 | |
| 121 | AC_ARG_WITH(rsh, |
| 122 | AC_HELP_STRING([--with-rsh=CMD], [set remote shell command to CMD (default: ssh)])) |
| 123 | |
| 124 | AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0) |
| 125 | AC_DEFINE_UNQUOTED(HAVE_REMSH, $HAVE_REMSH, [remote shell is remsh not rsh]) |
| 126 | |
| 127 | if test x"$with_rsh" != x |
| 128 | then |
| 129 | RSYNC_RSH="$with_rsh" |
| 130 | else |
| 131 | RSYNC_RSH="ssh" |
| 132 | fi |
| 133 | |
| 134 | AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command]) |
| 135 | |
| 136 | # arrgh. libc in the current debian stable screws up the largefile |
| 137 | # stuff, getting byte range locking wrong |
| 138 | AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[ |
| 139 | AC_TRY_RUN([ |
| 140 | #define _FILE_OFFSET_BITS 64 |
| 141 | #include <stdio.h> |
| 142 | #include <fcntl.h> |
| 143 | #include <sys/types.h> |
| 144 | #include <sys/wait.h> |
| 145 | |
| 146 | int main(void) |
| 147 | { |
| 148 | struct flock lock; |
| 149 | int status; |
| 150 | char tpl[32] = "/tmp/locktest.XXXXXX"; |
| 151 | int fd = mkstemp(tpl); |
| 152 | if (fd < 0) { |
| 153 | strcpy(tpl, "conftest.dat"); |
| 154 | fd = open(tpl, O_CREAT|O_RDWR, 0600); |
| 155 | } |
| 156 | |
| 157 | lock.l_type = F_WRLCK; |
| 158 | lock.l_whence = SEEK_SET; |
| 159 | lock.l_start = 0; |
| 160 | lock.l_len = 1; |
| 161 | lock.l_pid = 0; |
| 162 | fcntl(fd,F_SETLK,&lock); |
| 163 | if (fork() == 0) { |
| 164 | lock.l_start = 1; |
| 165 | _exit(fcntl(fd,F_SETLK,&lock) == 0); |
| 166 | } |
| 167 | wait(&status); |
| 168 | unlink(tpl); |
| 169 | exit(WEXITSTATUS(status)); |
| 170 | } |
| 171 | ], |
| 172 | rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)]) |
| 173 | if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then |
| 174 | AC_SYS_LARGEFILE |
| 175 | fi |
| 176 | |
| 177 | ipv6type=unknown |
| 178 | ipv6lib=none |
| 179 | ipv6trylibc=yes |
| 180 | |
| 181 | AC_ARG_ENABLE(ipv6, |
| 182 | AC_HELP_STRING([--disable-ipv6], [don't even try to use IPv6])) |
| 183 | |
| 184 | if test "x$enable_ipv6" != xno |
| 185 | then |
| 186 | AC_MSG_CHECKING([ipv6 stack type]) |
| 187 | for i in inria kame linux-glibc linux-inet6 toshiba v6d zeta; do |
| 188 | case $i in |
| 189 | inria) |
| 190 | # http://www.kame.net/ |
| 191 | AC_EGREP_CPP(yes, [ |
| 192 | #include <netinet/in.h> |
| 193 | #ifdef IPV6_INRIA_VERSION |
| 194 | yes |
| 195 | #endif], |
| 196 | [ipv6type=$i; |
| 197 | AC_DEFINE(INET6, 1, [true if you have IPv6]) |
| 198 | ]) |
| 199 | ;; |
| 200 | kame) |
| 201 | # http://www.kame.net/ |
| 202 | AC_EGREP_CPP(yes, [ |
| 203 | #include <netinet/in.h> |
| 204 | #ifdef __KAME__ |
| 205 | yes |
| 206 | #endif], |
| 207 | [ipv6type=$i; |
| 208 | AC_DEFINE(INET6, 1, [true if you have IPv6])]) |
| 209 | ;; |
| 210 | linux-glibc) |
| 211 | # http://www.v6.linux.or.jp/ |
| 212 | AC_EGREP_CPP(yes, [ |
| 213 | #include <features.h> |
| 214 | #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1 |
| 215 | yes |
| 216 | #endif], |
| 217 | [ipv6type=$i; |
| 218 | AC_DEFINE(INET6, 1, [true if you have IPv6])]) |
| 219 | ;; |
| 220 | linux-inet6) |
| 221 | # http://www.v6.linux.or.jp/ |
| 222 | if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then |
| 223 | ipv6type=$i |
| 224 | ipv6lib=inet6 |
| 225 | ipv6libdir=/usr/inet6/lib |
| 226 | ipv6trylibc=yes; |
| 227 | AC_DEFINE(INET6, 1, [true if you have IPv6]) |
| 228 | CFLAGS="-I/usr/inet6/include $CFLAGS" |
| 229 | fi |
| 230 | ;; |
| 231 | toshiba) |
| 232 | AC_EGREP_CPP(yes, [ |
| 233 | #include <sys/param.h> |
| 234 | #ifdef _TOSHIBA_INET6 |
| 235 | yes |
| 236 | #endif], |
| 237 | [ipv6type=$i; |
| 238 | ipv6lib=inet6; |
| 239 | ipv6libdir=/usr/local/v6/lib; |
| 240 | AC_DEFINE(INET6, 1, [true if you have IPv6])]) |
| 241 | ;; |
| 242 | v6d) |
| 243 | AC_EGREP_CPP(yes, [ |
| 244 | #include </usr/local/v6/include/sys/v6config.h> |
| 245 | #ifdef __V6D__ |
| 246 | yes |
| 247 | #endif], |
| 248 | [ipv6type=$i; |
| 249 | ipv6lib=v6; |
| 250 | ipv6libdir=/usr/local/v6/lib; |
| 251 | AC_DEFINE(INET6, 1, [true if you have IPv6])]) |
| 252 | ;; |
| 253 | zeta) |
| 254 | AC_EGREP_CPP(yes, [ |
| 255 | #include <sys/param.h> |
| 256 | #ifdef _ZETA_MINAMI_INET6 |
| 257 | yes |
| 258 | #endif], |
| 259 | [ipv6type=$i; |
| 260 | ipv6lib=inet6; |
| 261 | ipv6libdir=/usr/local/v6/lib; |
| 262 | AC_DEFINE(INET6, 1, [true if you have IPv6])]) |
| 263 | ;; |
| 264 | esac |
| 265 | if test "$ipv6type" != "unknown"; then |
| 266 | break |
| 267 | fi |
| 268 | done |
| 269 | AC_MSG_RESULT($ipv6type) |
| 270 | |
| 271 | AC_SEARCH_LIBS(getaddrinfo, inet6) |
| 272 | fi |
| 273 | |
| 274 | AC_MSG_CHECKING([whether to call shutdown on all sockets]) |
| 275 | case $host_os in |
| 276 | *cygwin* ) AC_MSG_RESULT(yes) |
| 277 | AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1, |
| 278 | [Define if sockets need to be shutdown]) |
| 279 | ;; |
| 280 | * ) AC_MSG_RESULT(no);; |
| 281 | esac |
| 282 | |
| 283 | AC_C_BIGENDIAN |
| 284 | AC_HEADER_DIRENT |
| 285 | AC_HEADER_TIME |
| 286 | AC_HEADER_SYS_WAIT |
| 287 | AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \ |
| 288 | unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \ |
| 289 | sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \ |
| 290 | sys/un.h glob.h mcheck.h arpa/inet.h arpa/nameser.h \ |
| 291 | netdb.h malloc.h float.h) |
| 292 | AC_HEADER_MAJOR |
| 293 | |
| 294 | AC_CHECK_SIZEOF(int) |
| 295 | AC_CHECK_SIZEOF(long) |
| 296 | AC_CHECK_SIZEOF(short) |
| 297 | |
| 298 | AC_C_INLINE |
| 299 | |
| 300 | AC_TYPE_SIGNAL |
| 301 | AC_TYPE_UID_T |
| 302 | AC_TYPE_MODE_T |
| 303 | AC_TYPE_OFF_T |
| 304 | AC_TYPE_SIZE_T |
| 305 | AC_TYPE_PID_T |
| 306 | AC_TYPE_GETGROUPS |
| 307 | AC_CHECK_MEMBERS([struct stat.st_rdev]) |
| 308 | |
| 309 | AC_CHECK_TYPE([ino_t], [unsigned]) |
| 310 | TYPE_SOCKLEN_T |
| 311 | |
| 312 | AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [ |
| 313 | AC_TRY_COMPILE([#include <errno.h>],[int i = errno], |
| 314 | rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)]) |
| 315 | if test x"$rsync_cv_errno" = x"yes"; then |
| 316 | AC_DEFINE(HAVE_ERRNO_DECL, 1, [ ]) |
| 317 | fi |
| 318 | |
| 319 | # The following test taken from the cvs sources |
| 320 | # If we can't find connect, try looking in -lsocket, -lnsl, and -linet. |
| 321 | # These need checks to be before checks for any other functions that |
| 322 | # might be in the same libraries. |
| 323 | # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has |
| 324 | # libsocket.so which has a bad implementation of gethostbyname (it |
| 325 | # only looks in /etc/hosts), so we only look for -lsocket if we need |
| 326 | # it. |
| 327 | AC_CHECK_FUNCS(connect) |
| 328 | if test x"$ac_cv_func_connect" = x"no"; then |
| 329 | case "$LIBS" in |
| 330 | *-lnsl*) ;; |
| 331 | *) AC_CHECK_LIB(nsl_s, printf) ;; |
| 332 | esac |
| 333 | case "$LIBS" in |
| 334 | *-lnsl*) ;; |
| 335 | *) AC_CHECK_LIB(nsl, printf) ;; |
| 336 | esac |
| 337 | case "$LIBS" in |
| 338 | *-lsocket*) ;; |
| 339 | *) AC_CHECK_LIB(socket, connect) ;; |
| 340 | esac |
| 341 | case "$LIBS" in |
| 342 | *-linet*) ;; |
| 343 | *) AC_CHECK_LIB(inet, connect) ;; |
| 344 | esac |
| 345 | dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value |
| 346 | dnl has been cached. |
| 347 | if test x"$ac_cv_lib_socket_connect" = x"yes" || |
| 348 | test x"$ac_cv_lib_inet_connect" = x"yes"; then |
| 349 | # ac_cv_func_connect=yes |
| 350 | # don't! it would cause AC_CHECK_FUNC to succeed next time configure is run |
| 351 | AC_DEFINE(HAVE_CONNECT, 1, [ ]) |
| 352 | fi |
| 353 | fi |
| 354 | |
| 355 | AC_CHECK_LIB(resolv, inet_ntop) |
| 356 | |
| 357 | dnl AC_MSG_NOTICE([Looking in libraries: $LIBS]) |
| 358 | |
| 359 | AC_CHECK_FUNCS(inet_ntop, , [AC_LIBOBJ(lib/inet_ntop)]) |
| 360 | AC_CHECK_FUNCS(inet_pton, , [AC_LIBOBJ(lib/inet_pton)]) |
| 361 | |
| 362 | # Irix 6.5 has getaddrinfo but not the corresponding defines, so use |
| 363 | # builtin getaddrinfo if one of the defines don't exist |
| 364 | AC_CACHE_CHECK([whether defines needed by getaddrinfo exist], |
| 365 | rsync_cv_HAVE_GETADDR_DEFINES,[ |
| 366 | AC_EGREP_CPP(yes, [ |
| 367 | #include <sys/types.h> |
| 368 | #include <sys/socket.h> |
| 369 | #include <netdb.h> |
| 370 | #ifdef AI_PASSIVE |
| 371 | yes |
| 372 | #endif], |
| 373 | rsync_cv_HAVE_GETADDR_DEFINES=yes, |
| 374 | rsync_cv_HAVE_GETADDR_DEFINES=no)]) |
| 375 | if test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes"; then |
| 376 | # Tru64 UNIX has getaddrinfo() but has it renamed in libc as |
| 377 | # something else so we must include <netdb.h> to get the |
| 378 | # redefinition. |
| 379 | AC_CHECK_FUNCS(getaddrinfo, , |
| 380 | [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>]) |
| 381 | AC_TRY_LINK([#include <sys/types.h> |
| 382 | #include <sys/socket.h> |
| 383 | #include <netdb.h>],[getaddrinfo(NULL, NULL, NULL, NULL);], |
| 384 | [AC_MSG_RESULT([yes]) |
| 385 | AC_DEFINE(HAVE_GETADDRINFO, 1, |
| 386 | [Define if you have the `getaddrinfo' function.])], |
| 387 | [AC_MSG_RESULT([no]) |
| 388 | AC_LIBOBJ(lib/getaddrinfo)])]) |
| 389 | AC_CHECK_FUNCS(getnameinfo, , [AC_LIBOBJ(lib/getnameinfo)]) |
| 390 | else |
| 391 | AC_LIBOBJ(lib/getaddrinfo) |
| 392 | AC_LIBOBJ(lib/getnameinfo) |
| 393 | fi |
| 394 | |
| 395 | AC_CHECK_MEMBER([struct sockaddr.sa_len], |
| 396 | [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ], |
| 397 | [], |
| 398 | [ |
| 399 | #include <sys/types.h> |
| 400 | #include <sys/socket.h> |
| 401 | ]) |
| 402 | |
| 403 | AC_CHECK_MEMBER([struct sockaddr_in.sin_len], |
| 404 | [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ], |
| 405 | [], |
| 406 | [ |
| 407 | #include <sys/types.h> |
| 408 | #include <sys/socket.h> |
| 409 | #include <netinet/in.h> |
| 410 | ]) |
| 411 | |
| 412 | AC_CHECK_MEMBER([struct sockaddr_un.sun_len], |
| 413 | [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ], |
| 414 | [], |
| 415 | [ |
| 416 | #include <sys/types.h> |
| 417 | #include <sys/socket.h> |
| 418 | #include <netinet/in.h> |
| 419 | ]) |
| 420 | |
| 421 | AC_MSG_CHECKING(struct sockaddr_storage) |
| 422 | AC_TRY_COMPILE([#include <sys/types.h> |
| 423 | #include <sys/socket.h>], |
| 424 | [struct sockaddr_storage x;], |
| 425 | AC_MSG_RESULT(yes) |
| 426 | AC_DEFINE(HAVE_SOCKADDR_STORAGE, 1, |
| 427 | [Define if you have strct sockaddr_storage.] ), |
| 428 | AC_MSG_RESULT(no)) |
| 429 | |
| 430 | AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id], |
| 431 | [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ], |
| 432 | [], |
| 433 | [ |
| 434 | #include <sys/types.h> |
| 435 | #include <sys/socket.h> |
| 436 | #include <netinet/in.h> |
| 437 | ]) |
| 438 | |
| 439 | # if we can't find strcasecmp, look in -lresolv (for Unixware at least) |
| 440 | # |
| 441 | AC_CHECK_FUNCS(strcasecmp) |
| 442 | if test x"$ac_cv_func_strcasecmp" = x"no"; then |
| 443 | AC_CHECK_LIB(resolv, strcasecmp) |
| 444 | fi |
| 445 | |
| 446 | dnl At the moment we don't test for a broken memcmp(), because all we |
| 447 | dnl need to do is test for equality, not comparison, and it seems that |
| 448 | dnl every platform has a memcmp that can do at least that. |
| 449 | dnl AC_FUNC_MEMCMP |
| 450 | |
| 451 | AC_FUNC_UTIME_NULL |
| 452 | AC_FUNC_ALLOCA |
| 453 | AC_CHECK_FUNCS(waitpid wait4 getcwd strdup strerror chown chmod mknod mkfifo \ |
| 454 | fchmod fstat strchr readlink link utime utimes strftime mtrace ftruncate \ |
| 455 | memmove lchown vsnprintf snprintf asprintf setsid glob strpbrk setmode \ |
| 456 | strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \ |
| 457 | open64 mkstemp64) |
| 458 | |
| 459 | AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[ |
| 460 | AC_TRY_RUN([ |
| 461 | #include <sys/types.h> |
| 462 | #include <sys/socket.h> |
| 463 | |
| 464 | main() { |
| 465 | int fd[2]; |
| 466 | exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1); |
| 467 | }], |
| 468 | rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)]) |
| 469 | if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then |
| 470 | AC_DEFINE(HAVE_SOCKETPAIR, 1, [ ]) |
| 471 | fi |
| 472 | |
| 473 | if test x"$with_included_popt" != x"yes" |
| 474 | then |
| 475 | AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes]) |
| 476 | fi |
| 477 | |
| 478 | AC_MSG_CHECKING([whether to use included libpopt]) |
| 479 | if test x"$with_included_popt" = x"yes" |
| 480 | then |
| 481 | AC_MSG_RESULT($srcdir/popt) |
| 482 | BUILD_POPT='$(popt_OBJS)' |
| 483 | CFLAGS="$CFLAGS -I$srcdir/popt" |
| 484 | if test x"$ALLOCA" != x |
| 485 | then |
| 486 | # this can be removed when/if we add an included alloca.c; |
| 487 | # see autoconf documentation on AC_FUNC_ALLOCA |
| 488 | AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)]) |
| 489 | fi |
| 490 | else |
| 491 | AC_MSG_RESULT(no) |
| 492 | fi |
| 493 | |
| 494 | AC_CACHE_CHECK([for long long],rsync_cv_HAVE_LONGLONG,[ |
| 495 | AC_TRY_RUN([#include <stdio.h> |
| 496 | main() { long long x = 1000000; x *= x; exit(((x/1000000) == 1000000)? 0: 1); }], |
| 497 | rsync_cv_HAVE_LONGLONG=yes,rsync_cv_HAVE_LONGLONG=no,rsync_cv_HAVE_LONGLONG=cross)]) |
| 498 | if test x"$rsync_cv_HAVE_LONGLONG" = x"yes"; then |
| 499 | AC_DEFINE(HAVE_LONGLONG, 1, [ ]) |
| 500 | fi |
| 501 | |
| 502 | AC_CACHE_CHECK([for off64_t],rsync_cv_HAVE_OFF64_T,[ |
| 503 | AC_TRY_RUN([#include <stdio.h> |
| 504 | #include <sys/stat.h> |
| 505 | main() { struct stat64 st; off64_t s; if (sizeof(off_t) == sizeof(off64_t)) exit(1); exit((lstat64("/dev/null", &st)==0)?0:1); }], |
| 506 | rsync_cv_HAVE_OFF64_T=yes,rsync_cv_HAVE_OFF64_T=no,rsync_cv_HAVE_OFF64_T=cross)]) |
| 507 | if test x"$rsync_cv_HAVE_OFF64_T" = x"yes"; then |
| 508 | AC_DEFINE(HAVE_OFF64_T, 1, [ ]) |
| 509 | fi |
| 510 | |
| 511 | AC_CACHE_CHECK([for short ino_t],rsync_cv_HAVE_SHORT_INO_T,[ |
| 512 | AC_TRY_RUN([#include <stdio.h> |
| 513 | #include <sys/types.h> |
| 514 | #include <sys/stat.h> |
| 515 | main() { if (sizeof(ino_t) < sizeof(unsigned int)) return 0; return 1; }], |
| 516 | rsync_cv_HAVE_SHORT_INO_T=yes,rsync_cv_HAVE_SHORT_INO_T=no,rsync_cv_HAVE_SHORT_INO_T=cross)]) |
| 517 | if test x"$rsync_cv_HAVE_SHORT_INO_T" = x"yes"; then |
| 518 | AC_DEFINE(HAVE_SHORT_INO_T, 1, [ ]) |
| 519 | fi |
| 520 | |
| 521 | AC_CACHE_CHECK([for unsigned char],rsync_cv_HAVE_UNSIGNED_CHAR,[ |
| 522 | AC_TRY_RUN([#include <stdio.h> |
| 523 | main() { char c; c=250; exit((c > 0)?0:1); }], |
| 524 | rsync_cv_HAVE_UNSIGNED_CHAR=yes,rsync_cv_HAVE_UNSIGNED_CHAR=no,rsync_cv_HAVE_UNSIGNED_CHAR=cross)]) |
| 525 | if test x"$rsync_cv_HAVE_UNSIGNED_CHAR" = x"yes"; then |
| 526 | AC_DEFINE(HAVE_UNSIGNED_CHAR, 1, [ ]) |
| 527 | fi |
| 528 | |
| 529 | AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[ |
| 530 | AC_TRY_RUN([#include <sys/types.h> |
| 531 | #include <dirent.h> |
| 532 | main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d); |
| 533 | if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 && |
| 534 | di->d_name[0] == 0) exit(0); exit(1);} ], |
| 535 | rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)]) |
| 536 | if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then |
| 537 | AC_DEFINE(HAVE_BROKEN_READDIR, 1, [ ]) |
| 538 | fi |
| 539 | |
| 540 | AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[ |
| 541 | AC_TRY_COMPILE([#include <sys/types.h> |
| 542 | #include <utime.h>], |
| 543 | [struct utimbuf tbuf; tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));], |
| 544 | rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no,rsync_cv_HAVE_UTIMBUF=cross)]) |
| 545 | if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then |
| 546 | AC_DEFINE(HAVE_UTIMBUF, 1, [ ]) |
| 547 | fi |
| 548 | |
| 549 | AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[ |
| 550 | AC_TRY_RUN([ |
| 551 | #include <sys/time.h> |
| 552 | #include <unistd.h> |
| 553 | main() { struct timeval tv; exit(gettimeofday(&tv, NULL));}], |
| 554 | rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no,rsync_cv_HAVE_GETTIMEOFDAY_TZ=cross)]) |
| 555 | if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then |
| 556 | AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [ ]) |
| 557 | fi |
| 558 | |
| 559 | AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[ |
| 560 | AC_TRY_RUN([ |
| 561 | #include <sys/types.h> |
| 562 | #include <stdarg.h> |
| 563 | void foo(const char *format, ...) { |
| 564 | va_list ap; |
| 565 | int len; |
| 566 | char buf[5]; |
| 567 | |
| 568 | va_start(ap, format); |
| 569 | len = vsnprintf(0, 0, format, ap); |
| 570 | va_end(ap); |
| 571 | if (len != 5) exit(1); |
| 572 | |
| 573 | if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1); |
| 574 | |
| 575 | exit(0); |
| 576 | } |
| 577 | main() { foo("hello"); } |
| 578 | ], |
| 579 | rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)]) |
| 580 | if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then |
| 581 | AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [ ]) |
| 582 | fi |
| 583 | |
| 584 | |
| 585 | AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[ |
| 586 | AC_TRY_RUN([#include <stdlib.h> |
| 587 | #include <sys/types.h> |
| 588 | #include <sys/stat.h> |
| 589 | #include <unistd.h> |
| 590 | main() { |
| 591 | struct stat st; |
| 592 | char tpl[20]="/tmp/test.XXXXXX"; |
| 593 | int fd = mkstemp(tpl); |
| 594 | if (fd == -1) exit(1); |
| 595 | unlink(tpl); |
| 596 | if (fstat(fd, &st) != 0) exit(1); |
| 597 | if ((st.st_mode & 0777) != 0600) exit(1); |
| 598 | exit(0); |
| 599 | }], |
| 600 | rsync_cv_HAVE_SECURE_MKSTEMP=yes, |
| 601 | rsync_cv_HAVE_SECURE_MKSTEMP=no, |
| 602 | rsync_cv_HAVE_SECURE_MKSTEMP=cross)]) |
| 603 | if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then |
| 604 | AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [ ]) |
| 605 | fi |
| 606 | |
| 607 | |
| 608 | AC_CACHE_CHECK([for broken inet_ntoa],rsync_cv_REPLACE_INET_NTOA,[ |
| 609 | AC_TRY_RUN([ |
| 610 | #include <stdio.h> |
| 611 | #include <sys/types.h> |
| 612 | #include <netinet/in.h> |
| 613 | #include <arpa/inet.h> |
| 614 | main() { struct in_addr ip; ip.s_addr = 0x12345678; |
| 615 | if (strcmp(inet_ntoa(ip),"18.52.86.120") && |
| 616 | strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(1); } |
| 617 | exit(0);}], |
| 618 | rsync_cv_REPLACE_INET_NTOA=no,rsync_cv_REPLACE_INET_NTOA=yes,rsync_cv_REPLACE_INET_NTOA=cross)]) |
| 619 | if test x"$rsync_cv_REPLACE_INET_NTOA" = x"yes"; then |
| 620 | AC_DEFINE(REPLACE_INET_NTOA, 1, [ ]) |
| 621 | fi |
| 622 | |
| 623 | |
| 624 | AC_CACHE_CHECK([for broken inet_aton],rsync_cv_REPLACE_INET_ATON,[ |
| 625 | AC_TRY_RUN([ |
| 626 | #include <stdio.h> |
| 627 | #include <sys/types.h> |
| 628 | #include <netinet/in.h> |
| 629 | #include <arpa/inet.h> |
| 630 | main() { struct in_addr ip; |
| 631 | if (inet_aton("example", &ip) == 0) exit(0); exit(1);}], |
| 632 | rsync_cv_REPLACE_INET_ATON=no,rsync_cv_REPLACE_INET_ATON=yes,rsync_cv_REPLACE_INET_ATON=cross)]) |
| 633 | if test x"$rsync_cv_REPLACE_INET_ATON" = x"yes"; then |
| 634 | AC_DEFINE(REPLACE_INET_ATON, 1, [ ]) |
| 635 | fi |
| 636 | |
| 637 | AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[ |
| 638 | AC_TRY_RUN([ |
| 639 | #include <stdio.h> |
| 640 | #include <sys/stat.h> |
| 641 | #include <errno.h> |
| 642 | main() { int rc, ec; char *fn = "fifo-test"; |
| 643 | unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn); |
| 644 | if (rc) {printf("%d %d\n",rc,ec); return ec;} |
| 645 | return 0;}], |
| 646 | rsync_cv_MKNOD_CREATES_FIFOS=yes,rsync_cv_MKNOD_CREATES_FIFOS=no,rsync_cv_MKNOD_CREATES_FIFOS=cross)]) |
| 647 | if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then |
| 648 | AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.]) |
| 649 | fi |
| 650 | |
| 651 | AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[ |
| 652 | AC_TRY_RUN([ |
| 653 | #include <stdio.h> |
| 654 | #include <sys/stat.h> |
| 655 | #include <errno.h> |
| 656 | main() { int rc, ec; char *fn = "sock-test"; |
| 657 | unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn); |
| 658 | if (rc) {printf("%d %d\n",rc,ec); return ec;} |
| 659 | return 0;}], |
| 660 | rsync_cv_MKNOD_CREATES_SOCKETS=yes,rsync_cv_MKNOD_CREATES_SOCKETS=no,rsync_cv_MKNOD_CREATES_SOCKETS=cross)]) |
| 661 | if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then |
| 662 | AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.]) |
| 663 | fi |
| 664 | |
| 665 | # |
| 666 | # The following test was mostly taken from the tcl/tk plus patches |
| 667 | # |
| 668 | AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[ |
| 669 | rm -rf conftest* |
| 670 | cat > conftest.$ac_ext <<EOF |
| 671 | int main() { return 0; } |
| 672 | EOF |
| 673 | ${CC-cc} -c -o conftest..o conftest.$ac_ext |
| 674 | if test -f conftest..o; then |
| 675 | rsync_cv_DASHC_WORKS_WITH_DASHO=yes |
| 676 | else |
| 677 | rsync_cv_DASHC_WORKS_WITH_DASHO=no |
| 678 | fi |
| 679 | rm -rf conftest* |
| 680 | ]) |
| 681 | if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then |
| 682 | OBJ_SAVE="#" |
| 683 | OBJ_RESTORE="#" |
| 684 | CC_SHOBJ_FLAG='-o $@' |
| 685 | else |
| 686 | OBJ_SAVE=' @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;' |
| 687 | OBJ_RESTORE=' @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi' |
| 688 | CC_SHOBJ_FLAG="" |
| 689 | fi |
| 690 | |
| 691 | AC_SUBST(OBJ_SAVE) |
| 692 | AC_SUBST(OBJ_RESTORE) |
| 693 | AC_SUBST(CC_SHOBJ_FLAG) |
| 694 | AC_SUBST(BUILD_POPT) |
| 695 | |
| 696 | AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig]) |
| 697 | AC_OUTPUT |
| 698 | |
| 699 | if test x"$with_rsh" = x; then |
| 700 | if test x"$HAVE_REMSH" = x1; then |
| 701 | rmsh1='remsh:' |
| 702 | rmsh2='=remsh' |
| 703 | else |
| 704 | rmsh1='rsh: ' |
| 705 | rmsh2='=rsh ' |
| 706 | fi |
| 707 | AC_MSG_RESULT() |
| 708 | AC_MSG_RESULT([ **********************************************************************]) |
| 709 | AC_MSG_RESULT([ * As of v2.6.0, the default remote shell is ssh instead of rsh!! *]) |
| 710 | AC_MSG_RESULT([ * To use previous default of $rmsh1 ./configure --with-rsh$rmsh2 *]) |
| 711 | AC_MSG_RESULT([ **********************************************************************]) |
| 712 | fi |
| 713 | |
| 714 | AC_MSG_RESULT() |
| 715 | AC_MSG_RESULT([ rsync ${RSYNC_VERSION} configuration successful]) |
| 716 | AC_MSG_RESULT() |