From 3fa64fd0080caf4b44ac069f3b6172b68f274e6f Mon Sep 17 00:00:00 2001
From: Martin Pool <mbp@samba.org>
Date: Sat, 17 Mar 2001 01:06:34 +0000
Subject: [PATCH] Don't unconditionally define _LARGEFILE_SOURCE, but instead
 include some autoconf-2.13 macros that make the appropriate settings.  Thanks
 to Albert Chin <china@thewrittenword.com> and Paul Eggert
 <eggert@twinsun.com>.

---
 aclocal.m4   | 75 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 configure.in |  1 +
 rsync.h      |  7 -----
 3 files changed, 76 insertions(+), 7 deletions(-)

diff --git a/aclocal.m4 b/aclocal.m4
index cf5e9363..d583b52f 100644
--- a/aclocal.m4
+++ b/aclocal.m4
@@ -21,3 +21,78 @@ AC_DEFUN(AC_VALIDATE_CACHE_SYSTEM_TYPE, [
     ac_cv_build_system_type="$build"
     ac_cv_target_system_type="$target"
 ])
+
+#serial 12
+
+dnl By default, many hosts won't let programs access large files;
+dnl one must use special compiler options to get large-file access to work.
+dnl For more details about this brain damage please see:
+dnl http://www.sas.com/standards/large.file/x_open.20Mar96.html
+
+dnl Written by Paul Eggert <eggert@twinsun.com>.
+
+dnl Internal subroutine of AC_SYS_LARGEFILE.
+dnl AC_SYS_LARGEFILE_TEST_INCLUDES
+AC_DEFUN(AC_SYS_LARGEFILE_TEST_INCLUDES,
+  [[#include <sys/types.h>
+    int a[(off_t) 9223372036854775807 == 9223372036854775807 ? 1 : -1];
+  ]])
+
+dnl Internal subroutine of AC_SYS_LARGEFILE.
+dnl AC_SYS_LARGEFILE_MACRO_VALUE(C-MACRO, VALUE, CACHE-VAR, COMMENT, INCLUDES, FUNCTION-BODY)
+AC_DEFUN(AC_SYS_LARGEFILE_MACRO_VALUE,
+  [AC_CACHE_CHECK([for $1 value needed for large files], $3,
+     [$3=no
+      AC_TRY_COMPILE(AC_SYS_LARGEFILE_TEST_INCLUDES
+$5
+        ,
+        [$6],
+        ,
+        [AC_TRY_COMPILE([#define $1 $2]
+AC_SYS_LARGEFILE_TEST_INCLUDES
+$5
+           ,
+           [$6],
+           [$3=$2])])])
+   if test "[$]$3" != no; then
+     AC_DEFINE_UNQUOTED([$1], [$]$3, [$4])
+   fi])
+
+AC_DEFUN(AC_SYS_LARGEFILE,
+  [AC_ARG_ENABLE(largefile,
+     [  --disable-largefile     omit support for large files])
+   if test "$enable_largefile" != no; then
+
+     AC_CACHE_CHECK([for special C compiler options needed for large files],
+       ac_cv_sys_largefile_CC,
+       [ac_cv_sys_largefile_CC=no
+        if test "$GCC" != yes; then
+          # IRIX 6.2 and later do not support large files by default,
+          # so use the C compiler's -n32 option if that helps.
+          AC_TRY_COMPILE(AC_SYS_LARGEFILE_TEST_INCLUDES, , ,
+            [ac_save_CC="$CC"
+             CC="$CC -n32"
+             AC_TRY_COMPILE(AC_SYS_LARGEFILE_TEST_INCLUDES, ,
+               ac_cv_sys_largefile_CC=' -n32')
+             CC="$ac_save_CC"])
+        fi])
+     if test "$ac_cv_sys_largefile_CC" != no; then
+       CC="$CC$ac_cv_sys_largefile_CC"
+     fi
+
+     AC_SYS_LARGEFILE_MACRO_VALUE(_FILE_OFFSET_BITS, 64,
+       ac_cv_sys_file_offset_bits,
+       [Number of bits in a file offset, on hosts where this is settable.])
+     AC_SYS_LARGEFILE_MACRO_VALUE(_LARGEFILE_SOURCE, 1,
+       ac_cv_sys_largefile_source,
+       [Define to make ftello visible on some hosts (e.g. HP-UX 10.20).],
+       [#include <stdio.h>], [return !ftello;])
+     AC_SYS_LARGEFILE_MACRO_VALUE(_LARGE_FILES, 1,
+       ac_cv_sys_large_files,
+       [Define for large files, on AIX-style hosts.])
+     AC_SYS_LARGEFILE_MACRO_VALUE(_XOPEN_SOURCE, 500,
+       ac_cv_sys_xopen_source,
+       [Define to make ftello visible on some hosts (e.g. glibc 2.1.3).],
+       [#include <stdio.h>], [return !ftello;])
+   fi
+  ])
diff --git a/configure.in b/configure.in
index c0b19e2c..18ff3d21 100644
--- a/configure.in
+++ b/configure.in
@@ -45,6 +45,7 @@ AC_SUBST(SHELL)
 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 AC_DEFINE_UNQUOTED(HAVE_REMSH, $HAVE_REMSH)
 
+AC_SYS_LARGEFILE
 AC_C_BIGENDIAN
 AC_HEADER_DIRENT
 AC_HEADER_TIME
diff --git a/rsync.h b/rsync.h
index 29b09b50..cb138be2 100644
--- a/rsync.h
+++ b/rsync.h
@@ -79,13 +79,6 @@ enum logcode {FNONE=0, FERROR=1, FINFO=2, FLOG=3 };
 #define RSYNC_RSH "rsh"
 #endif
 
-/* This tries to turn on large file support on some Unix platforms,
- * making off_t be a 64-bit type, and so on.
- * 
- * http://www.rs6000.ibm.com/doc_link/en_US/a_doc_lib/aixprggd/genprogc/prg_lrg_files.htm
- */
-#define _LARGE_FILES 1
-
 #include <sys/types.h>
 
 #ifdef HAVE_UNISTD_H
-- 
2.34.1