Fix copyright.
[rsync/rsync.git] / configure.in
1 dnl Process this file with autoconf to produce a configure script.
2
3 AC_INIT()
4 AC_CONFIG_SRCDIR([byteorder.h])
5 AC_CONFIG_HEADER(config.h)
6 AC_PREREQ(2.52)
7
8 RSYNC_VERSION=2.5.6cvs
9 AC_SUBST(RSYNC_VERSION)
10 AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION])
11
12 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
13
14 LDFLAGS=${LDFLAGS-""}
15
16 AC_CANONICAL_TARGET([])
17
18 dnl Checks for programs.
19 AC_PROG_CC
20 AC_PROG_CPP
21 AC_PROG_INSTALL
22 AC_PROG_CC_STDC
23 AC_SUBST(SHELL)
24
25 AC_DEFINE([_GNU_SOURCE], 1,
26           [Define _GNU_SOURCE so that we get all necessary prototypes])
27
28 if test "$xac_cv_prog_cc_stdc" = xno
29 then
30         AC_MSG_WARN([rsync requires an ANSI C compiler and you don't seem to have one])
31 fi
32
33 # We must decide this before testing the compiler.
34
35 # Please allow this to default to yes, so that your users have more
36 # chance of getting a useful stack trace if problems occur.
37
38 AC_MSG_CHECKING([whether to include debugging symbols])
39 AC_ARG_ENABLE(debug,
40         AC_HELP_STRING([--enable-debug],
41                 [including debugging symbols and features (default yes)]),
42                 [], [])
43
44 if test x"$enable_debug" = x"no"
45 then
46     AC_MSG_RESULT(no)
47     CFLAGS=${CFLAGS-"-O"}
48 else
49     AC_MSG_RESULT([yes])
50     # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can
51     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
52     dnl CFLAGS=${CFLAGS-"-g"}
53 fi
54
55
56
57
58 AC_ARG_ENABLE(profile,
59         AC_HELP_STRING([--enable-profile],      
60                 [turn on CPU profiling (default no)],
61                 [], []))
62 if test x"$enable_profile" = xyes
63 then
64         CFLAGS="$CFLAGS -pg"
65 fi
66
67
68 # Specifically, this turns on panic_action handling.
69 AC_ARG_ENABLE(maintainer-mode,
70         AC_HELP_STRING([--enable-maintainer-mode],      
71                 [turn on extra debug features],
72                 [], []))
73 if test x"$enable_maintainer_mode" = xyes
74 then
75         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
76 fi
77
78
79 # This is needed for our included version of popt.  Kind of silly, but
80 # I don't want our version too far out of sync.
81 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
82
83 # If GCC, turn on warnings.
84 if test "x$GCC" = "xyes"
85 then
86         CFLAGS="$CFLAGS -Wall -W"
87 fi
88
89 AC_ARG_WITH(included-popt,
90         [  --with-included-popt    use bundled popt library, not from system])
91
92 AC_ARG_WITH(rsync-path,
93         [  --with-rsync-path=PATH  set default --rsync-path to PATH (default: \"rsync\")],
94         [ RSYNC_PATH="$with_rsync_path" ],
95         [ RSYNC_PATH="rsync" ])
96
97 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
98
99 AC_ARG_WITH(rsh,
100         AC_HELP_STRING([--with-rsh=CMD], [set rsh command to CMD (default: \"remsh\" or \"rsh\")]))
101
102 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
103 AC_DEFINE_UNQUOTED(HAVE_REMSH, $HAVE_REMSH, [remote shell is remsh not rsh])
104
105 if test x"$with_rsh" != x
106 then
107         RSYNC_RSH="$with_rsh"
108 elif test x"$HAVE_REMSH" = x1
109 then 
110         RSYNC_RSH="remsh"
111 else
112         RSYNC_RSH="rsh"
113 fi
114
115 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
116
117 # arrgh. libc in the current debian stable screws up the largefile
118 # stuff, getting byte range locking wrong
119 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
120 AC_TRY_RUN([
121 #define _FILE_OFFSET_BITS 64
122 #include <stdio.h>
123 #include <fcntl.h>
124 #include <sys/types.h>
125 #include <sys/wait.h>
126
127 int main(void) 
128 {
129         struct flock lock;
130         int status;
131         int fd = open("conftest.dat", O_CREAT|O_RDWR, 0600);
132         lock.l_type = F_WRLCK;
133         lock.l_whence = SEEK_SET;
134         lock.l_start = 0;
135         lock.l_len = 1;
136         lock.l_pid = 0;
137         
138         fcntl(fd,F_SETLK,&lock);
139         if (fork() == 0) {
140                 lock.l_start = 1;               
141                 exit(fcntl(fd,F_SETLK,&lock) == 0);
142         }
143         wait(&status);
144         unlink("conftest.dat");
145         exit(WEXITSTATUS(status));
146 }
147 ],
148 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
149 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
150    AC_SYS_LARGEFILE
151 fi
152
153 ipv6type=unknown
154 ipv6lib=none
155 ipv6trylibc=yes
156
157 AC_ARG_ENABLE(ipv6, 
158         AC_HELP_STRING([--disable-ipv6], [don't even try to use IPv6]))
159
160 if test "x$enable_ipv6" != xno
161 then
162         AC_MSG_CHECKING([ipv6 stack type])
163         for i in inria kame linux-glibc linux-inet6 toshiba v6d zeta; do
164                 case $i in
165                 inria)
166                         # http://www.kame.net/
167                         AC_EGREP_CPP(yes, [
168 #include <netinet/in.h>
169 #ifdef IPV6_INRIA_VERSION
170 yes
171 #endif],
172                                 [ipv6type=$i;
173                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
174                                 ])
175                         ;;
176                 kame)
177                         # http://www.kame.net/
178                         AC_EGREP_CPP(yes, [
179 #include <netinet/in.h>
180 #ifdef __KAME__
181 yes
182 #endif],
183                                 [ipv6type=$i; 
184                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
185                         ;;
186                 linux-glibc)
187                         # http://www.v6.linux.or.jp/
188                         AC_EGREP_CPP(yes, [
189 #include <features.h>
190 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
191 yes
192 #endif],
193                                 [ipv6type=$i;
194 AC_DEFINE(INET6, 1, [true if you have IPv6])])
195                         ;;
196                 linux-inet6)
197                         # http://www.v6.linux.or.jp/
198                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
199                                 ipv6type=$i
200                                 ipv6lib=inet6
201                                 ipv6libdir=/usr/inet6/lib
202                                 ipv6trylibc=yes;
203                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
204                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
205                         fi
206                         ;;
207                 toshiba)
208                         AC_EGREP_CPP(yes, [
209 #include <sys/param.h>
210 #ifdef _TOSHIBA_INET6
211 yes
212 #endif],
213                                 [ipv6type=$i;
214                                 ipv6lib=inet6;
215                                 ipv6libdir=/usr/local/v6/lib;
216                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
217                         ;;
218                 v6d)
219                         AC_EGREP_CPP(yes, [
220 #include </usr/local/v6/include/sys/v6config.h>
221 #ifdef __V6D__
222 yes
223 #endif],
224                                 [ipv6type=$i;
225                                 ipv6lib=v6;
226                                 ipv6libdir=/usr/local/v6/lib;
227                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
228                         ;;
229                 zeta)
230                         AC_EGREP_CPP(yes, [
231 #include <sys/param.h>
232 #ifdef _ZETA_MINAMI_INET6
233 yes
234 #endif],
235                                 [ipv6type=$i;
236                                 ipv6lib=inet6;
237                                 ipv6libdir=/usr/local/v6/lib;
238                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
239                         ;;
240                 esac
241                 if test "$ipv6type" != "unknown"; then
242                         break
243                 fi
244         done
245         AC_MSG_RESULT($ipv6type)
246
247         AC_SEARCH_LIBS(getaddrinfo, inet6)
248 fi
249
250 AC_C_BIGENDIAN
251 AC_HEADER_DIRENT
252 AC_HEADER_TIME
253 AC_HEADER_SYS_WAIT
254 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h unistd.h utime.h grp.h)
255 AC_CHECK_HEADERS(compat.h sys/param.h ctype.h sys/wait.h sys/ioctl.h)
256 AC_CHECK_HEADERS(sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h sys/un.h)
257 AC_CHECK_HEADERS(glob.h alloca.h mcheck.h sys/sysctl.h arpa/inet.h arpa/nameser.h)
258 AC_CHECK_HEADERS(netdb.h)
259 AC_CHECK_HEADERS(malloc.h)
260
261 AC_CHECK_SIZEOF(int)
262 AC_CHECK_SIZEOF(long)
263 AC_CHECK_SIZEOF(short)
264
265 AC_C_INLINE
266
267 AC_TYPE_SIGNAL
268 AC_TYPE_UID_T
269 AC_TYPE_MODE_T
270 AC_TYPE_OFF_T
271 AC_TYPE_SIZE_T
272 AC_TYPE_PID_T
273 AC_TYPE_GETGROUPS
274 AC_CHECK_MEMBERS([struct stat.st_rdev])
275
276 AC_CHECK_TYPE([ino_t], [unsigned])
277 TYPE_SOCKLEN_T
278
279 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
280     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
281         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
282 if test x"$rsync_cv_errno" = x"yes"; then
283    AC_DEFINE(HAVE_ERRNO_DECL, 1, [ ])
284 fi
285
286 # The following test taken from the cvs sources
287 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
288 # These need checks to be before checks for any other functions that
289 #    might be in the same libraries.
290 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
291 # libsocket.so which has a bad implementation of gethostbyname (it
292 # only looks in /etc/hosts), so we only look for -lsocket if we need
293 # it.
294 AC_CHECK_FUNCS(connect)
295 if test x"$ac_cv_func_connect" = x"no"; then
296     case "$LIBS" in
297     *-lnsl*) ;;
298     *) AC_CHECK_LIB(nsl_s, printf) ;;
299     esac
300     case "$LIBS" in
301     *-lnsl*) ;;
302     *) AC_CHECK_LIB(nsl, printf) ;;
303     esac
304     case "$LIBS" in
305     *-lsocket*) ;;
306     *) AC_CHECK_LIB(socket, connect) ;;
307     esac
308     case "$LIBS" in
309     *-linet*) ;;
310     *) AC_CHECK_LIB(inet, connect) ;;
311     esac
312     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
313     dnl has been cached.
314     if test x"$ac_cv_lib_socket_connect" = x"yes" || 
315        test x"$ac_cv_lib_inet_connect" = x"yes"; then
316         # ac_cv_func_connect=yes
317         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
318         AC_DEFINE(HAVE_CONNECT, 1, [ ])
319     fi
320 fi
321
322 AC_CHECK_LIB(resolv, inet_ntop)
323
324 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
325
326 AC_CHECK_FUNCS(inet_ntop, , AC_LIBOBJ(lib/inet_ntop)) 
327 AC_CHECK_FUNCS(inet_pton, , AC_LIBOBJ(lib/inet_pton))
328
329 # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
330 # something else so we must include <netdb.h> to get the
331 # redefinition.
332 AC_CHECK_FUNCS(getaddrinfo, ,
333         [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
334         AC_TRY_LINK([#include <sys/types.h>
335         #include <sys/socket.h>
336         #include <netdb.h>],[getaddrinfo(NULL, NULL, NULL, NULL);],
337                 [AC_MSG_RESULT([yes])
338                 AC_DEFINE(HAVE_GETADDRINFO, 1,
339                         [Define if you have the `getaddrinfo' function.])],
340                 [AC_MSG_RESULT([no])
341                 AC_LIBOBJ(lib/getaddrinfo)])])
342 AC_CHECK_FUNCS(getnameinfo, , AC_LIBOBJ(lib/getnameinfo))
343
344 AC_CHECK_MEMBER([struct sockaddr.sa_len], 
345                 [ AC_DEFINE(HAVE_SOCKADDR_LEN) ],
346                 [],
347                 [
348 #include <sys/types.h>
349 #include <sys/socket.h>
350 ])
351
352 AC_MSG_CHECKING(struct sockaddr_storage)
353 AC_TRY_COMPILE([#include <sys/types.h>
354 #include <sys/socket.h>],
355 [struct sockaddr_storage x;],
356         AC_MSG_RESULT(yes)
357         AC_DEFINE(HAVE_SOCKADDR_STORAGE, 1, 
358                 [Define if you have strct sockaddr_storage.] ),
359         AC_MSG_RESULT(no))
360
361 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
362 #
363 AC_CHECK_FUNCS(strcasecmp)
364 if test x"$ac_cv_func_strcasecmp" = x"no"; then
365     AC_CHECK_LIB(resolv, strcasecmp)
366 fi
367
368 dnl At the moment we don't test for a broken memcmp(), because all we
369 dnl need to do is test for equality, not comparison, and it seems that
370 dnl every platform has a memcmp that can do at least that.  
371 dnl AC_FUNC_MEMCMP
372
373 AC_FUNC_UTIME_NULL
374 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup strerror chown chmod mknod mkfifo)
375 AC_CHECK_FUNCS(fchmod fstat strchr readlink link utime utimes strftime)
376 AC_CHECK_FUNCS(memmove lchown vsnprintf snprintf asprintf setsid glob strpbrk)
377 AC_CHECK_FUNCS(strlcat strlcpy mtrace mallinfo setgroups)
378
379 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
380 AC_TRY_RUN([
381 #include <sys/types.h>
382 #include <sys/socket.h>
383
384 main() {
385        int fd[2];
386        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
387 }],
388 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
389 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
390     AC_DEFINE(HAVE_SOCKETPAIR, 1, [ ])
391 fi
392
393 AC_CACHE_CHECK([for working fnmatch],rsync_cv_HAVE_FNMATCH,[
394 AC_TRY_RUN([#include <fnmatch.h>
395 main() { exit((fnmatch("*.o", "x.o", FNM_PATHNAME) == 0 &&
396                fnmatch("a/b/*", "a/b/c/d", FNM_PATHNAME) != 0) ? 0: 1); }],
397 rsync_cv_HAVE_FNMATCH=yes,rsync_cv_HAVE_FNMATCH=no,rsync_cv_HAVE_FNMATCH=cross)])
398 if test x"$rsync_cv_HAVE_FNMATCH" = x"yes"; then
399     AC_DEFINE(HAVE_FNMATCH, 1, [ ])
400 fi
401
402 if test x"$with_included_popt" != x"yes"
403 then
404     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
405 fi
406
407 AC_MSG_CHECKING([whether to use included libpopt])
408 if test x"$with_included_popt" = x"yes"
409 then
410     AC_MSG_RESULT($srcdir/popt)
411     BUILD_POPT='$(popt_OBJS)'
412     CFLAGS="$CFLAGS -I$srcdir/popt"
413 else
414     AC_MSG_RESULT(no)
415 fi
416
417 AC_CACHE_CHECK([for long long],rsync_cv_HAVE_LONGLONG,[
418 AC_TRY_RUN([#include <stdio.h>
419 main() { long long x = 1000000; x *= x; exit(((x/1000000) == 1000000)? 0: 1); }],
420 rsync_cv_HAVE_LONGLONG=yes,rsync_cv_HAVE_LONGLONG=no,rsync_cv_HAVE_LONGLONG=cross)])
421 if test x"$rsync_cv_HAVE_LONGLONG" = x"yes"; then
422     AC_DEFINE(HAVE_LONGLONG, 1, [ ])
423 fi
424
425 AC_CACHE_CHECK([for off64_t],rsync_cv_HAVE_OFF64_T,[
426 AC_TRY_RUN([#include <stdio.h>
427 #include <sys/stat.h>
428 main() { struct stat64 st; off64_t s; if (sizeof(off_t) == sizeof(off64_t)) exit(1); exit((lstat64("/dev/null", &st)==0)?0:1); }],
429 rsync_cv_HAVE_OFF64_T=yes,rsync_cv_HAVE_OFF64_T=no,rsync_cv_HAVE_OFF64_T=cross)])
430 if test x"$rsync_cv_HAVE_OFF64_T" = x"yes"; then
431     AC_DEFINE(HAVE_OFF64_T, 1, [ ])
432 fi
433
434 AC_CACHE_CHECK([for short ino_t],rsync_cv_HAVE_SHORT_INO_T,[
435 AC_TRY_RUN([#include <stdio.h>
436 #include <sys/types.h>
437 #include <sys/stat.h>
438 main() { if (sizeof(ino_t) < sizeof(unsigned int)) return 0; return 1; }],
439 rsync_cv_HAVE_SHORT_INO_T=yes,rsync_cv_HAVE_SHORT_INO_T=no,rsync_cv_HAVE_SHORT_INO_T=cross)])
440 if test x"$rsync_cv_HAVE_SHORT_INO_T" = x"yes"; then
441     AC_DEFINE(HAVE_SHORT_INO_T, 1, [ ])
442 fi
443
444 AC_CACHE_CHECK([for unsigned char],rsync_cv_HAVE_UNSIGNED_CHAR,[
445 AC_TRY_RUN([#include <stdio.h>
446 main() { char c; c=250; exit((c > 0)?0:1); }],
447 rsync_cv_HAVE_UNSIGNED_CHAR=yes,rsync_cv_HAVE_UNSIGNED_CHAR=no,rsync_cv_HAVE_UNSIGNED_CHAR=cross)])
448 if test x"$rsync_cv_HAVE_UNSIGNED_CHAR" = x"yes"; then
449     AC_DEFINE(HAVE_UNSIGNED_CHAR, 1, [ ])
450 fi
451
452 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
453 AC_TRY_RUN([#include <sys/types.h>
454 #include <dirent.h>
455 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
456 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
457 di->d_name[0] == 0) exit(0); exit(1);} ],
458 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
459 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
460     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [ ])
461 fi
462
463 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[
464 AC_TRY_COMPILE([#include <sys/types.h>
465 #include <utime.h>],
466 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
467 rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no,rsync_cv_HAVE_UTIMBUF=cross)])
468 if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then
469     AC_DEFINE(HAVE_UTIMBUF, 1, [ ])
470 fi
471
472 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
473 AC_TRY_RUN([
474 #include <sys/time.h>
475 #include <unistd.h>
476 main() { struct timeval tv; exit(gettimeofday(&tv, NULL));}],
477            rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no,rsync_cv_HAVE_GETTIMEOFDAY_TZ=cross)])
478 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" = x"yes"; then
479     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [ ])
480 fi
481
482 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
483 AC_TRY_RUN([
484 #include <sys/types.h>
485 #include <stdarg.h>
486 void foo(const char *format, ...) { 
487        va_list ap;
488        int len;
489        char buf[5];
490
491        va_start(ap, format);
492        len = vsnprintf(0, 0, format, ap);
493        va_end(ap);
494        if (len != 5) exit(1);
495
496        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
497
498        exit(0);
499 }
500 main() { foo("hello"); }
501 ],
502 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
503 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
504     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [ ])
505 fi
506
507
508 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
509 AC_TRY_RUN([#include <stdlib.h>
510 #include <sys/types.h>
511 #include <sys/stat.h>
512 #include <unistd.h>
513 main() { 
514   struct stat st;
515   char tpl[20]="/tmp/test.XXXXXX"; 
516   int fd = mkstemp(tpl); 
517   if (fd == -1) exit(1);
518   unlink(tpl);
519   if (fstat(fd, &st) != 0) exit(1);
520   if ((st.st_mode & 0777) != 0600) exit(1);
521   exit(0);
522 }],
523 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
524 rsync_cv_HAVE_SECURE_MKSTEMP=no,
525 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
526 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
527     AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [ ])
528 fi
529
530
531 AC_CACHE_CHECK([for broken inet_ntoa],rsync_cv_REPLACE_INET_NTOA,[
532 AC_TRY_RUN([
533 #include <stdio.h>
534 #include <sys/types.h>
535 #include <netinet/in.h>
536 #include <arpa/inet.h>
537 main() { struct in_addr ip; ip.s_addr = 0x12345678;
538 if (strcmp(inet_ntoa(ip),"18.52.86.120") &&
539     strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(1); } 
540 exit(0);}],
541            rsync_cv_REPLACE_INET_NTOA=no,rsync_cv_REPLACE_INET_NTOA=yes,rsync_cv_REPLACE_INET_NTOA=cross)])
542 if test x"$rsync_cv_REPLACE_INET_NTOA" = x"yes"; then
543     AC_DEFINE(REPLACE_INET_NTOA, 1, [ ])
544 fi
545
546
547 AC_CACHE_CHECK([for broken inet_aton],rsync_cv_REPLACE_INET_ATON,[
548 AC_TRY_RUN([
549 #include <stdio.h>
550 #include <sys/types.h>
551 #include <netinet/in.h>
552 #include <arpa/inet.h>
553 main() { struct in_addr ip; 
554 if (inet_aton("example", &ip) == 0) exit(0); exit(1);}],
555            rsync_cv_REPLACE_INET_ATON=no,rsync_cv_REPLACE_INET_ATON=yes,rsync_cv_REPLACE_INET_ATON=cross)])
556 if test x"$rsync_cv_REPLACE_INET_ATON" = x"yes"; then
557     AC_DEFINE(REPLACE_INET_ATON, 1, [ ])
558 fi
559
560 #
561 # The following test was mostly taken from the tcl/tk plus patches
562 #
563 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
564 rm -rf conftest*
565 cat > conftest.$ac_ext <<EOF
566 int main() { return 0; }
567 EOF
568 ${CC-cc} -c -o conftest..o conftest.$ac_ext
569 if test -f conftest..o; then
570     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
571 else
572     rsync_cv_DASHC_WORKS_WITH_DASHO=no
573 fi
574 rm -rf conftest*
575 ])
576 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
577     OBJ_SAVE="#"
578     OBJ_RESTORE="#"
579     CC_SHOBJ_FLAG='-o $@'
580 else
581     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
582     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
583     CC_SHOBJ_FLAG=""
584 fi
585
586 AC_SUBST(OBJ_SAVE)
587 AC_SUBST(OBJ_RESTORE)
588 AC_SUBST(CC_SHOBJ_FLAG)
589 AC_SUBST(BUILD_POPT)
590
591 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
592 AC_OUTPUT
593
594 AC_MSG_RESULT()
595 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
596 AC_MSG_RESULT()