configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT()
   4 AC_CONFIG_SRCDIR([byteorder.h])
   5 AC_CONFIG_HEADER(config.h)
   6 AC_PREREQ(2.59)
   7
   8 RSYNC_VERSION=3.0.0cvs
   9 AC_SUBST(RSYNC_VERSION)
  10 AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION])
  11
  12 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
  13
  14 LDFLAGS=${LDFLAGS-""}
  15
  16 AC_CANONICAL_TARGET([])
  17
  18 dnl Checks for programs.
  19 AC_PROG_CC
  20 AC_PROG_CPP
  21 AC_PROG_EGREP
  22 AC_PROG_INSTALL
  23 AC_PROG_CC_STDC
  24 AC_SUBST(SHELL)
  25
  26 AC_DEFINE([_GNU_SOURCE], 1,
  27           [Define _GNU_SOURCE so that we get all necessary prototypes])
  28
  29 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  30         AC_MSG_WARN([rsync requires an ANSI C compiler and you don't seem to have one])
  31 fi
  32
  33 # We must decide this before testing the compiler.
  34
  35 # Please allow this to default to yes, so that your users have more
  36 # chance of getting a useful stack trace if problems occur.
  37
  38 AC_MSG_CHECKING([whether to include debugging symbols])
  39 AC_ARG_ENABLE(debug,
  40         AC_HELP_STRING([--disable-debug],
  41                 [turn off debugging symbols and features]))
  42
  43 if test x"$enable_debug" = x"no"; then
  44     AC_MSG_RESULT(no)
  45     CFLAGS=${CFLAGS-"-O"}
  46 else
  47     AC_MSG_RESULT([yes])
  48     # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can
  49     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  50     dnl CFLAGS=${CFLAGS-"-g"}
  51 fi
  52
  53
  54 AC_ARG_ENABLE(profile,
  55         AC_HELP_STRING([--enable-profile],
  56                 [turn on CPU profiling]))
  57 if test x"$enable_profile" = x"yes"; then
  58         CFLAGS="$CFLAGS -pg"
  59 fi
  60
  61
  62 # Specifically, this turns on panic_action handling.
  63 AC_ARG_ENABLE(maintainer-mode,
  64         AC_HELP_STRING([--enable-maintainer-mode],
  65                 [turn on extra debug features]))
  66 if test x"$enable_maintainer_mode" = x"yes"; then
  67         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
  68 fi
  69
  70
  71 # This is needed for our included version of popt.  Kind of silly, but
  72 # I don't want our version too far out of sync.
  73 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  74
  75 # If GCC, turn on warnings.
  76 if test x"$GCC" = x"yes"; then
  77         CFLAGS="$CFLAGS -Wall -W"
  78 fi
  79
  80 AC_ARG_WITH(included-popt,
  81         AC_HELP_STRING([--with-included-popt], [use bundled popt library, not from system]))
  82
  83 AC_ARG_WITH(rsync-path,
  84         AC_HELP_STRING([--with-rsync-path=PATH], [set default --rsync-path to PATH (default: rsync)]),
  85         [ RSYNC_PATH="$with_rsync_path" ],
  86         [ RSYNC_PATH="rsync" ])
  87
  88 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
  89
  90 AC_ARG_WITH(rsyncd-conf,
  91         AC_HELP_STRING([--with-rsyncd-conf=PATH], [set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
  92         [ if test ! -z "$with_rsyncd_conf" ; then
  93                 case $with_rsyncd_conf in
  94                         yes|no)
  95                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
  96                                 ;;
  97                         /*)
  98                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
  99                                 ;;
 100                         *)
 101                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 102                                 ;;
 103                 esac
 104         else
 105                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 106         fi ],
 107         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 108
 109 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 110
 111 AC_ARG_WITH(rsh,
 112         AC_HELP_STRING([--with-rsh=CMD], [set remote shell command to CMD (default: ssh)]))
 113
 114 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 115 if test x$HAVE_REMSH = x1; then
 116         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 117 fi
 118
 119 if test x"$with_rsh" != x; then
 120         RSYNC_RSH="$with_rsh"
 121 else
 122         RSYNC_RSH="ssh"
 123 fi
 124 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 125
 126 AC_ARG_WITH(nobody-group,
 127     AC_HELP_STRING([--with-nobody-group=GROUP],
 128                    [set the default unprivileged group (default nobody or nogroup)]),
 129     [ NOBODY_GROUP="$with_nobody_group" ])
 130
 131 if test x"$with_nobody_group" = x; then
 132     AC_MSG_CHECKING([the group for user "nobody"])
 133     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 134         NOBODY_GROUP=nobody
 135     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 136         NOBODY_GROUP=nogroup
 137     else
 138         NOBODY_GROUP=nobody # test for others?
 139     fi
 140     AC_MSG_RESULT($NOBODY_GROUP)
 141 fi
 142
 143 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 144 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 145
 146 # arrgh. libc in some old debian version screwed up the largefile
 147 # stuff, getting byte range locking wrong
 148 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 149 AC_TRY_RUN([
 150 #define _FILE_OFFSET_BITS 64
 151 #include <stdio.h>
 152 #include <fcntl.h>
 153 #include <sys/types.h>
 154 #include <sys/wait.h>
 155
 156 int main(void)
 157 {
 158         struct flock lock;
 159         int status;
 160         char tpl[32] = "/tmp/locktest.XXXXXX";
 161         int fd = mkstemp(tpl);
 162         if (fd < 0) {
 163                 strcpy(tpl, "conftest.dat");
 164                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 165         }
 166
 167         lock.l_type = F_WRLCK;
 168         lock.l_whence = SEEK_SET;
 169         lock.l_start = 0;
 170         lock.l_len = 1;
 171         lock.l_pid = 0;
 172         fcntl(fd,F_SETLK,&lock);
 173         if (fork() == 0) {
 174                 lock.l_start = 1;
 175                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 176         }
 177         wait(&status);
 178         unlink(tpl);
 179         exit(WEXITSTATUS(status));
 180 }
 181 ],
 182 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
 183 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 184    AC_SYS_LARGEFILE
 185 fi
 186
 187 ipv6type=unknown
 188 ipv6lib=none
 189 ipv6trylibc=yes
 190
 191 AC_ARG_ENABLE(ipv6,
 192         AC_HELP_STRING([--disable-ipv6],
 193                 [don't even try to use IPv6]))
 194 if test x"$enable_ipv6" != x"no"; then
 195         AC_MSG_CHECKING([ipv6 stack type])
 196         for i in inria kame linux-glibc linux-inet6 toshiba v6d zeta; do
 197                 case $i in
 198                 inria)
 199                         # http://www.kame.net/
 200                         AC_EGREP_CPP(yes, [
 201 #include <netinet/in.h>
 202 #ifdef IPV6_INRIA_VERSION
 203 yes
 204 #endif],
 205                                 [ipv6type=$i;
 206                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 207                                 ])
 208                         ;;
 209                 kame)
 210                         # http://www.kame.net/
 211                         AC_EGREP_CPP(yes, [
 212 #include <netinet/in.h>
 213 #ifdef __KAME__
 214 yes
 215 #endif],
 216                                 [ipv6type=$i;
 217                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 218                         ;;
 219                 linux-glibc)
 220                         # http://www.v6.linux.or.jp/
 221                         AC_EGREP_CPP(yes, [
 222 #include <features.h>
 223 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 224 yes
 225 #endif],
 226                                 [ipv6type=$i;
 227 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 228                         ;;
 229                 linux-inet6)
 230                         # http://www.v6.linux.or.jp/
 231                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 232                                 ipv6type=$i
 233                                 ipv6lib=inet6
 234                                 ipv6libdir=/usr/inet6/lib
 235                                 ipv6trylibc=yes;
 236                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 237                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 238                         fi
 239                         ;;
 240                 toshiba)
 241                         AC_EGREP_CPP(yes, [
 242 #include <sys/param.h>
 243 #ifdef _TOSHIBA_INET6
 244 yes
 245 #endif],
 246                                 [ipv6type=$i;
 247                                 ipv6lib=inet6;
 248                                 ipv6libdir=/usr/local/v6/lib;
 249                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 250                         ;;
 251                 v6d)
 252                         AC_EGREP_CPP(yes, [
 253 #include </usr/local/v6/include/sys/v6config.h>
 254 #ifdef __V6D__
 255 yes
 256 #endif],
 257                                 [ipv6type=$i;
 258                                 ipv6lib=v6;
 259                                 ipv6libdir=/usr/local/v6/lib;
 260                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 261                         ;;
 262                 zeta)
 263                         AC_EGREP_CPP(yes, [
 264 #include <sys/param.h>
 265 #ifdef _ZETA_MINAMI_INET6
 266 yes
 267 #endif],
 268                                 [ipv6type=$i;
 269                                 ipv6lib=inet6;
 270                                 ipv6libdir=/usr/local/v6/lib;
 271                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 272                         ;;
 273                 esac
 274                 if test "$ipv6type" != "unknown"; then
 275                         break
 276                 fi
 277         done
 278         AC_MSG_RESULT($ipv6type)
 279
 280         AC_SEARCH_LIBS(getaddrinfo, inet6)
 281 fi
 282
 283 dnl Do you want to disable use of locale functions
 284 AC_ARG_ENABLE([locale],
 285         AC_HELP_STRING([--disable-locale],
 286                 [turn off locale features]))
 287 AH_TEMPLATE([CONFIG_LOCALE],
 288 [Undefine if you don't want locale features.  By default this is defined.])
 289 if test x"$enable_locale" != x"no"; then
 290         AC_DEFINE(CONFIG_LOCALE)
 291 fi
 292
 293 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 294 case $host_os in
 295         *cygwin* ) AC_MSG_RESULT(yes)
 296                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 297                             [Define to 1 if sockets need to be shutdown])
 298                    ;;
 299                * ) AC_MSG_RESULT(no);;
 300 esac
 301
 302 AC_C_BIGENDIAN
 303 AC_HEADER_DIRENT
 304 AC_HEADER_TIME
 305 AC_HEADER_SYS_WAIT
 306 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 307     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 308     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 309     sys/un.h glob.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 310     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h)
 311 AC_HEADER_MAJOR
 312
 313 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 314 AC_TRY_RUN([
 315 #include <sys/types.h>
 316 #ifdef MAJOR_IN_MKDEV
 317 #include <sys/mkdev.h>
 318 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 319 #  define makedev mkdev
 320 # endif
 321 #elif defined MAJOR_IN_SYSMACROS
 322 #include <sys/sysmacros.h>
 323 #endif
 324
 325 int main(void)
 326 {
 327         dev_t dev = makedev(0, 5, 7);
 328         if (major(dev) != 5 || minor(dev) != 7)
 329                 exit(1);
 330         return 0;
 331 }
 332 ],
 333 rsync_cv_MAKEDEV_TAKES_3_ARGS=yes,rsync_cv_MAKEDEV_TAKES_3_ARGS=no,rsync_cv_MAKEDEV_TAKES_3_ARGS=no)])
 334 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 335    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 336 fi
 337
 338 AC_CHECK_SIZEOF(int)
 339 AC_CHECK_SIZEOF(long)
 340 AC_CHECK_SIZEOF(long long)
 341 AC_CHECK_SIZEOF(short)
 342 AC_CHECK_SIZEOF(int16_t)
 343 AC_CHECK_SIZEOF(uint16_t)
 344 AC_CHECK_SIZEOF(int32_t)
 345 AC_CHECK_SIZEOF(uint32_t)
 346 AC_CHECK_SIZEOF(int64_t)
 347 AC_CHECK_SIZEOF(off_t)
 348 AC_CHECK_SIZEOF(off64_t)
 349
 350 AC_C_INLINE
 351 AC_C_LONG_DOUBLE
 352
 353 AC_TYPE_SIGNAL
 354 AC_TYPE_UID_T
 355 AC_TYPE_MODE_T
 356 AC_TYPE_OFF_T
 357 AC_TYPE_SIZE_T
 358 AC_TYPE_PID_T
 359 AC_TYPE_GETGROUPS
 360 AC_CHECK_MEMBERS([struct stat.st_rdev])
 361
 362 TYPE_SOCKLEN_T
 363
 364 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 365     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
 366         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
 367 if test x"$rsync_cv_errno" = x"yes"; then
 368    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 369 fi
 370
 371 # The following test taken from the cvs sources
 372 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 373 # These need checks to be before checks for any other functions that
 374 #    might be in the same libraries.
 375 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 376 # libsocket.so which has a bad implementation of gethostbyname (it
 377 # only looks in /etc/hosts), so we only look for -lsocket if we need
 378 # it.
 379 AC_CHECK_FUNCS(connect)
 380 if test x"$ac_cv_func_connect" = x"no"; then
 381     case "$LIBS" in
 382     *-lnsl*) ;;
 383     *) AC_CHECK_LIB(nsl_s, printf) ;;
 384     esac
 385     case "$LIBS" in
 386     *-lnsl*) ;;
 387     *) AC_CHECK_LIB(nsl, printf) ;;
 388     esac
 389     case "$LIBS" in
 390     *-lsocket*) ;;
 391     *) AC_CHECK_LIB(socket, connect) ;;
 392     esac
 393     case "$LIBS" in
 394     *-linet*) ;;
 395     *) AC_CHECK_LIB(inet, connect) ;;
 396     esac
 397     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 398     dnl has been cached.
 399     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 400        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 401         # ac_cv_func_connect=yes
 402         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 403         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 404     fi
 405 fi
 406
 407 AC_SEARCH_LIBS(inet_ntop, resolv)
 408
 409 # Solaris and HP-UX weirdness:
 410 # Search for libiconv_open (not iconv_open) to discover if -liconv is needed!
 411 AC_SEARCH_LIBS(libiconv_open, iconv)
 412
 413 AC_MSG_CHECKING([for iconv declaration])
 414 AC_CACHE_VAL(am_cv_proto_iconv, [
 415     AC_TRY_COMPILE([
 416 #include <stdlib.h>
 417 #include <iconv.h>
 418 extern
 419 #ifdef __cplusplus
 420 "C"
 421 #endif
 422 #if defined(__STDC__) || defined(__cplusplus)
 423 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 424 #else
 425 size_t iconv();
 426 #endif
 427 ], [], am_cv_proto_iconv_arg1="", am_cv_proto_iconv_arg1="const")
 428       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 429     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 430 AC_MSG_RESULT([$]{ac_t:-
 431          }[$]am_cv_proto_iconv)
 432 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 433                    [Define as const if the declaration of iconv() needs const.])
 434
 435 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 436
 437 AC_CHECK_FUNCS(inet_ntop, , [AC_LIBOBJ(lib/inet_ntop)])
 438 AC_CHECK_FUNCS(inet_pton, , [AC_LIBOBJ(lib/inet_pton)])
 439
 440 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 441 #   builtin getaddrinfo if one of the defines don't exist
 442 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 443                rsync_cv_HAVE_GETADDR_DEFINES,[
 444                         AC_EGREP_CPP(yes, [
 445                         #include <sys/types.h>
 446                         #include <sys/socket.h>
 447                         #include <netdb.h>
 448                         #ifdef AI_PASSIVE
 449                         yes
 450                         #endif],
 451                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 452                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 453 if test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes"; then
 454         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 455         # something else so we must include <netdb.h> to get the
 456         # redefinition.
 457         AC_CHECK_FUNCS(getaddrinfo, ,
 458                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 459                 AC_TRY_LINK([#include <sys/types.h>
 460                 #include <sys/socket.h>
 461                 #include <netdb.h>],[getaddrinfo(NULL, NULL, NULL, NULL);],
 462                         [AC_MSG_RESULT([yes])
 463                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 464                                 [Define to 1 if you have the "getaddrinfo" function.])],
 465                         [AC_MSG_RESULT([no])
 466                         AC_LIBOBJ(lib/getaddrinfo)])])
 467         AC_CHECK_FUNCS(getnameinfo, , [AC_LIBOBJ(lib/getnameinfo)])
 468 else
 469         AC_LIBOBJ(lib/getaddrinfo)
 470         AC_LIBOBJ(lib/getnameinfo)
 471 fi
 472
 473 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 474                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 475                 [],
 476                 [
 477 #include <sys/types.h>
 478 #include <sys/socket.h>
 479 ])
 480
 481 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 482                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 483                 [],
 484                 [
 485 #include <sys/types.h>
 486 #include <sys/socket.h>
 487 #include <netinet/in.h>
 488 ])
 489
 490 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 491                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 492                 [],
 493                 [
 494 #include <sys/types.h>
 495 #include <sys/socket.h>
 496 #include <netinet/in.h>
 497 ])
 498
 499 AC_MSG_CHECKING(struct sockaddr_storage)
 500 AC_TRY_COMPILE([#include <sys/types.h>
 501 #include <sys/socket.h>],
 502 [struct sockaddr_storage x;],
 503         AC_MSG_RESULT(yes)
 504         AC_DEFINE(HAVE_SOCKADDR_STORAGE, 1,
 505                 [Define to 1 if you have struct sockaddr_storage.] ),
 506         AC_MSG_RESULT(no))
 507
 508 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 509                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 510                 [],
 511                 [
 512 #include <sys/types.h>
 513 #include <sys/socket.h>
 514 #include <netinet/in.h>
 515 ])
 516
 517 AC_MSG_CHECKING(struct stat64)
 518 AC_TRY_COMPILE([#include <stdio.h>
 519 #if HAVE_SYS_TYPES_H
 520 # include <sys/types.h>
 521 #endif
 522 #if HAVE_SYS_STAT_H
 523 # include <sys/stat.h>
 524 #endif
 525 #if STDC_HEADERS
 526 # include <stdlib.h>
 527 # include <stddef.h>
 528 #else
 529 # if HAVE_STDLIB_H
 530 #  include <stdlib.h>
 531 # endif
 532 #endif
 533 ],[struct stat64 st;],
 534     AC_MSG_RESULT(yes)
 535         AC_DEFINE(HAVE_STRUCT_STAT64,1,[Define to 1 if you have struct stat64.]),
 536     AC_MSG_RESULT(no))
 537
 538 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 539 #
 540 AC_CHECK_FUNCS(strcasecmp)
 541 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 542     AC_CHECK_LIB(resolv, strcasecmp)
 543 fi
 544
 545 dnl At the moment we don't test for a broken memcmp(), because all we
 546 dnl need to do is test for equality, not comparison, and it seems that
 547 dnl every platform has a memcmp that can do at least that.
 548 dnl AC_FUNC_MEMCMP
 549
 550 AC_FUNC_UTIME_NULL
 551 AC_FUNC_ALLOCA
 552 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 553     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 554     memmove lchown vsnprintf snprintf vasprintf asprintf setsid glob strpbrk \
 555     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 556     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 557     strerror putenv iconv_open locale_charset nl_langinfo \
 558     sigaction sigprocmask)
 559
 560 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 561 if test $ac_cv_func_getpgrp = yes; then
 562     AC_FUNC_GETPGRP
 563 fi
 564
 565 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 566   AC_TRY_RUN([
 567 #if HAVE_UNISTD_H
 568 # include <unistd.h>
 569 #endif
 570 #include <stdlib.h>
 571 #include <errno.h>
 572     main() {
 573         char const *dangling_symlink = "conftest.dangle";
 574         unlink(dangling_symlink);
 575         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 576         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) exit(1);
 577         exit(0);
 578     }],
 579   rsync_cv_chown_modifies_symlink=yes,rsync_cv_chown_modifies_symlink=no,rsync_cv_chown_modifies_symlink=no)])
 580 if test $rsync_cv_chown_modifies_symlink = yes; then
 581   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 582 fi
 583
 584 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 585   AC_TRY_RUN([
 586 #if HAVE_UNISTD_H
 587 # include <unistd.h>
 588 #endif
 589 #include <stdlib.h>
 590 #include <errno.h>
 591 #define FILENAME "conftest.dangle"
 592     main() {
 593         unlink(FILENAME);
 594         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 595         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 596         exit(0);
 597     }],
 598   rsync_cv_can_hardlink_symlink=yes,rsync_cv_can_hardlink_symlink=no,rsync_cv_can_hardlink_symlink=no)])
 599 if test $rsync_cv_can_hardlink_symlink = yes; then
 600   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 601 fi
 602
 603 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 604   AC_TRY_RUN([
 605 #if HAVE_UNISTD_H
 606 # include <unistd.h>
 607 #endif
 608 #include <stdlib.h>
 609 #include <errno.h>
 610 #define FILENAME "conftest.fifi"
 611     main() {
 612         unlink(FILENAME);
 613         if (mkfifo(FILENAME, 0777) < 0) abort();
 614         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 615         exit(0);
 616     }],
 617   rsync_cv_can_hardlink_special=yes,rsync_cv_can_hardlink_special=no,rsync_cv_can_hardlink_special=no)])
 618 if test $rsync_cv_can_hardlink_special = yes; then
 619     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 620 fi
 621
 622 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 623 AC_TRY_RUN([
 624 #include <sys/types.h>
 625 #include <sys/socket.h>
 626
 627 main() {
 628        int fd[2];
 629        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 630 }],
 631 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
 632 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 633     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 634 fi
 635
 636 if test x"$with_included_popt" != x"yes"; then
 637     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 638 fi
 639
 640 AC_MSG_CHECKING([whether to use included libpopt])
 641 if test x"$with_included_popt" = x"yes"; then
 642     AC_MSG_RESULT($srcdir/popt)
 643     BUILD_POPT='$(popt_OBJS)'
 644     CFLAGS="$CFLAGS -I$srcdir/popt"
 645     if test x"$ALLOCA" != x
 646     then
 647         # this can be removed when/if we add an included alloca.c;
 648         #  see autoconf documentation on AC_FUNC_ALLOCA
 649         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 650     fi
 651 else
 652     AC_MSG_RESULT(no)
 653 fi
 654
 655 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 656 AC_TRY_COMPILE([],[signed char *s = ""],
 657 rsync_cv_SIGNED_CHAR_OK=yes,rsync_cv_SIGNED_CHAR_OK=no)])
 658 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 659     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 660 fi
 661
 662 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 663 AC_TRY_RUN([#include <sys/types.h>
 664 #include <dirent.h>
 665 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 666 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 667 di->d_name[0] == 0) exit(0); exit(1);} ],
 668 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 669 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 670     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
 671 fi
 672
 673 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[
 674 AC_TRY_COMPILE([#include <sys/types.h>
 675 #include <utime.h>],
 676 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 677 rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no)])
 678 if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then
 679     AC_DEFINE(HAVE_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
 680 fi
 681
 682 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 683 AC_TRY_COMPILE([#include <sys/time.h>
 684 #include <unistd.h>],
 685 [struct timeval tv; exit(gettimeofday(&tv, NULL));],
 686 rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no)])
 687 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
 688     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
 689 fi
 690
 691 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 692 AC_TRY_RUN([
 693 #include <sys/types.h>
 694 #include <stdarg.h>
 695 void foo(const char *format, ...) {
 696        va_list ap;
 697        int len;
 698        char buf[5];
 699
 700        va_start(ap, format);
 701        len = vsnprintf(0, 0, format, ap);
 702        va_end(ap);
 703        if (len != 5) exit(1);
 704
 705        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 706
 707        exit(0);
 708 }
 709 main() { foo("hello"); }
 710 ],
 711 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
 712 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 713     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
 714 fi
 715
 716
 717 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 718 AC_TRY_RUN([#include <stdlib.h>
 719 #include <sys/types.h>
 720 #include <sys/stat.h>
 721 #include <unistd.h>
 722 main() {
 723   struct stat st;
 724   char tpl[20]="/tmp/test.XXXXXX";
 725   int fd = mkstemp(tpl);
 726   if (fd == -1) exit(1);
 727   unlink(tpl);
 728   if (fstat(fd, &st) != 0) exit(1);
 729   if ((st.st_mode & 0777) != 0600) exit(1);
 730   exit(0);
 731 }],
 732 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
 733 rsync_cv_HAVE_SECURE_MKSTEMP=no,
 734 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
 735 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 736     case $target_os in
 737     hpux*)
 738         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
 739         dnl so we noisily skip using it.  See HP change request JAGaf34426
 740         dnl for details. (sbonds)
 741         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
 742         ;;
 743     *)
 744         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
 745         ;;
 746     esac
 747 fi
 748
 749
 750 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
 751 AC_TRY_RUN([
 752 #include <stdio.h>
 753 #include <sys/stat.h>
 754 #include <errno.h>
 755 main() { int rc, ec; char *fn = "fifo-test";
 756 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
 757 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 758 return 0;}],
 759            rsync_cv_MKNOD_CREATES_FIFOS=yes,rsync_cv_MKNOD_CREATES_FIFOS=no,rsync_cv_MKNOD_CREATES_FIFOS=cross)])
 760 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
 761     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
 762 fi
 763
 764 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
 765 AC_TRY_RUN([
 766 #include <stdio.h>
 767 #include <sys/stat.h>
 768 #include <errno.h>
 769 main() { int rc, ec; char *fn = "sock-test";
 770 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
 771 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 772 return 0;}],
 773            rsync_cv_MKNOD_CREATES_SOCKETS=yes,rsync_cv_MKNOD_CREATES_SOCKETS=no,rsync_cv_MKNOD_CREATES_SOCKETS=cross)])
 774 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
 775     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
 776 fi
 777
 778 #
 779 # The following test was mostly taken from the tcl/tk plus patches
 780 #
 781 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 782 rm -rf conftest*
 783 cat > conftest.$ac_ext <<EOF
 784 int main() { return 0; }
 785 EOF
 786 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 787 if test -f conftest..o; then
 788     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 789 else
 790     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 791 fi
 792 rm -rf conftest*
 793 ])
 794 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 795     OBJ_SAVE="#"
 796     OBJ_RESTORE="#"
 797     CC_SHOBJ_FLAG='-o $@'
 798 else
 799     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 800     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 801     CC_SHOBJ_FLAG=""
 802 fi
 803
 804 AC_SUBST(OBJ_SAVE)
 805 AC_SUBST(OBJ_RESTORE)
 806 AC_SUBST(CC_SHOBJ_FLAG)
 807 AC_SUBST(BUILD_POPT)
 808
 809 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
 810 AC_OUTPUT
 811
 812 AC_MSG_RESULT()
 813 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
 814 AC_MSG_RESULT()