configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT()
   4 AC_CONFIG_SRCDIR([byteorder.h])
   5 AC_CONFIG_HEADER(config.h)
   6 AC_PREREQ(2.59)
   7
   8 RSYNC_VERSION=3.1.0dev
   9 AC_SUBST(RSYNC_VERSION)
  10 AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION])
  11
  12 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
  13
  14 LDFLAGS=${LDFLAGS-""}
  15
  16 AC_CANONICAL_HOST
  17
  18 # We must decide this before testing the compiler.
  19
  20 # Please allow this to default to yes, so that your users have more
  21 # chance of getting a useful stack trace if problems occur.
  22
  23 AC_MSG_CHECKING([whether to include debugging symbols])
  24 AC_ARG_ENABLE(debug,
  25         AC_HELP_STRING([--disable-debug],
  26                 [disable debugging symbols and features]))
  27
  28 if test x"$enable_debug" = x"no"; then
  29     AC_MSG_RESULT(no)
  30     ac_cv_prog_cc_g=no
  31 else
  32     AC_MSG_RESULT([yes])
  33     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  34     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  35 fi
  36
  37 dnl Checks for programs.
  38 AC_PROG_CC
  39 AC_PROG_CPP
  40 AC_PROG_EGREP
  41 AC_PROG_INSTALL
  42 AC_PROG_CC_STDC
  43 AC_SUBST(SHELL)
  44
  45 AC_DEFINE([_GNU_SOURCE], 1,
  46           [Define _GNU_SOURCE so that we get all necessary prototypes])
  47
  48 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  49         AC_MSG_WARN([rsync requires an ANSI C compiler and you don't seem to have one])
  50 fi
  51
  52 AC_ARG_ENABLE(profile,
  53         AC_HELP_STRING([--enable-profile],
  54                 [turn on CPU profiling]))
  55 if test x"$enable_profile" = x"yes"; then
  56         CFLAGS="$CFLAGS -pg"
  57 fi
  58
  59
  60 # Specifically, this turns on panic_action handling.
  61 AC_ARG_ENABLE(maintainer-mode,
  62         AC_HELP_STRING([--enable-maintainer-mode],
  63                 [turn on extra debug features]))
  64 if test x"$enable_maintainer_mode" = x"yes"; then
  65         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
  66 fi
  67
  68
  69 # This is needed for our included version of popt.  Kind of silly, but
  70 # I don't want our version too far out of sync.
  71 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  72
  73 # If GCC, turn on warnings.
  74 if test x"$GCC" = x"yes"; then
  75         CFLAGS="$CFLAGS -Wall -W"
  76 fi
  77
  78 AC_ARG_WITH(included-popt,
  79         AC_HELP_STRING([--with-included-popt], [use bundled popt library, not from system]))
  80
  81 AC_ARG_WITH(rsync-path,
  82         AC_HELP_STRING([--with-rsync-path=PATH], [set default --rsync-path to PATH (default: rsync)]),
  83         [ RSYNC_PATH="$with_rsync_path" ],
  84         [ RSYNC_PATH="rsync" ])
  85
  86 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
  87
  88 AC_ARG_WITH(rsyncd-conf,
  89         AC_HELP_STRING([--with-rsyncd-conf=PATH], [set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
  90         [ if test ! -z "$with_rsyncd_conf" ; then
  91                 case $with_rsyncd_conf in
  92                         yes|no)
  93                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
  94                                 ;;
  95                         /*)
  96                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
  97                                 ;;
  98                         *)
  99                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 100                                 ;;
 101                 esac
 102         else
 103                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 104         fi ],
 105         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 106
 107 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 108
 109 AC_ARG_WITH(rsh,
 110         AC_HELP_STRING([--with-rsh=CMD], [set remote shell command to CMD (default: ssh)]))
 111
 112 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 113 if test x$HAVE_REMSH = x1; then
 114         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 115 fi
 116
 117 if test x"$with_rsh" != x; then
 118         RSYNC_RSH="$with_rsh"
 119 else
 120         RSYNC_RSH="ssh"
 121 fi
 122 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 123
 124 AC_CHECK_PROG(HAVE_YODL2MAN, yodl2man, 1, 0)
 125 if test x$HAVE_YODL2MAN = x1; then
 126     MAKE_MAN=man
 127 fi
 128
 129 AC_ARG_WITH(nobody-group,
 130     AC_HELP_STRING([--with-nobody-group=GROUP],
 131                    [set the default unprivileged group (default nobody or nogroup)]),
 132     [ NOBODY_GROUP="$with_nobody_group" ])
 133
 134 if test x"$with_nobody_group" = x; then
 135     AC_MSG_CHECKING([the group for user "nobody"])
 136     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 137         NOBODY_GROUP=nobody
 138     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 139         NOBODY_GROUP=nogroup
 140     else
 141         NOBODY_GROUP=nobody # test for others?
 142     fi
 143     AC_MSG_RESULT($NOBODY_GROUP)
 144 fi
 145
 146 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 147 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 148
 149 # arrgh. libc in some old debian version screwed up the largefile
 150 # stuff, getting byte range locking wrong
 151 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 152 AC_TRY_RUN([
 153 #define _FILE_OFFSET_BITS 64
 154 #include <stdio.h>
 155 #include <fcntl.h>
 156 #include <sys/types.h>
 157 #include <sys/wait.h>
 158
 159 int main(void)
 160 {
 161         struct flock lock;
 162         int status;
 163         char tpl[32] = "/tmp/locktest.XXXXXX";
 164         int fd = mkstemp(tpl);
 165         if (fd < 0) {
 166                 strcpy(tpl, "conftest.dat");
 167                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 168         }
 169
 170         lock.l_type = F_WRLCK;
 171         lock.l_whence = SEEK_SET;
 172         lock.l_start = 0;
 173         lock.l_len = 1;
 174         lock.l_pid = 0;
 175         fcntl(fd,F_SETLK,&lock);
 176         if (fork() == 0) {
 177                 lock.l_start = 1;
 178                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 179         }
 180         wait(&status);
 181         unlink(tpl);
 182         exit(WEXITSTATUS(status));
 183 }
 184 ],
 185 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
 186 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 187    AC_SYS_LARGEFILE
 188 fi
 189
 190 ipv6type=unknown
 191 ipv6lib=none
 192 ipv6trylibc=yes
 193
 194 AC_ARG_ENABLE(ipv6,
 195         AC_HELP_STRING([--disable-ipv6],
 196                 [don't even try to use IPv6]))
 197 if test x"$enable_ipv6" != x"no"; then
 198         AC_MSG_CHECKING([ipv6 stack type])
 199         for i in inria kame linux-glibc linux-inet6 toshiba v6d zeta; do
 200                 case $i in
 201                 inria)
 202                         # http://www.kame.net/
 203                         AC_EGREP_CPP(yes, [
 204 #include <netinet/in.h>
 205 #ifdef IPV6_INRIA_VERSION
 206 yes
 207 #endif],
 208                                 [ipv6type=$i;
 209                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 210                                 ])
 211                         ;;
 212                 kame)
 213                         # http://www.kame.net/
 214                         AC_EGREP_CPP(yes, [
 215 #include <netinet/in.h>
 216 #ifdef __KAME__
 217 yes
 218 #endif],
 219                                 [ipv6type=$i;
 220                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 221                         ;;
 222                 linux-glibc)
 223                         # http://www.v6.linux.or.jp/
 224                         AC_EGREP_CPP(yes, [
 225 #include <features.h>
 226 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 227 yes
 228 #endif],
 229                                 [ipv6type=$i;
 230 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 231                         ;;
 232                 linux-inet6)
 233                         # http://www.v6.linux.or.jp/
 234                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 235                                 ipv6type=$i
 236                                 ipv6lib=inet6
 237                                 ipv6libdir=/usr/inet6/lib
 238                                 ipv6trylibc=yes;
 239                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 240                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 241                         fi
 242                         ;;
 243                 toshiba)
 244                         AC_EGREP_CPP(yes, [
 245 #include <sys/param.h>
 246 #ifdef _TOSHIBA_INET6
 247 yes
 248 #endif],
 249                                 [ipv6type=$i;
 250                                 ipv6lib=inet6;
 251                                 ipv6libdir=/usr/local/v6/lib;
 252                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 253                         ;;
 254                 v6d)
 255                         AC_EGREP_CPP(yes, [
 256 #include </usr/local/v6/include/sys/v6config.h>
 257 #ifdef __V6D__
 258 yes
 259 #endif],
 260                                 [ipv6type=$i;
 261                                 ipv6lib=v6;
 262                                 ipv6libdir=/usr/local/v6/lib;
 263                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 264                         ;;
 265                 zeta)
 266                         AC_EGREP_CPP(yes, [
 267 #include <sys/param.h>
 268 #ifdef _ZETA_MINAMI_INET6
 269 yes
 270 #endif],
 271                                 [ipv6type=$i;
 272                                 ipv6lib=inet6;
 273                                 ipv6libdir=/usr/local/v6/lib;
 274                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 275                         ;;
 276                 esac
 277                 if test "$ipv6type" != "unknown"; then
 278                         break
 279                 fi
 280         done
 281         AC_MSG_RESULT($ipv6type)
 282
 283         AC_SEARCH_LIBS(getaddrinfo, inet6)
 284 fi
 285
 286 dnl Do you want to disable use of locale functions
 287 AC_ARG_ENABLE([locale],
 288         AC_HELP_STRING([--disable-locale],
 289                 [disable locale features]))
 290 AH_TEMPLATE([CONFIG_LOCALE],
 291 [Undefine if you don't want locale features.  By default this is defined.])
 292 if test x"$enable_locale" != x"no"; then
 293         AC_DEFINE(CONFIG_LOCALE)
 294 fi
 295
 296 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 297 case $host_os in
 298         *cygwin* ) AC_MSG_RESULT(yes)
 299                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 300                             [Define to 1 if sockets need to be shutdown])
 301                    ;;
 302                * ) AC_MSG_RESULT(no);;
 303 esac
 304
 305 AC_C_BIGENDIAN
 306 AC_HEADER_DIRENT
 307 AC_HEADER_TIME
 308 AC_HEADER_SYS_WAIT
 309 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 310     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 311     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 312     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 313     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 314     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
 315     popt.h popt/popt.h)
 316 AC_HEADER_MAJOR
 317
 318 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 319 AC_TRY_RUN([
 320 #include <sys/types.h>
 321 #ifdef MAJOR_IN_MKDEV
 322 #include <sys/mkdev.h>
 323 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 324 #  define makedev mkdev
 325 # endif
 326 #elif defined MAJOR_IN_SYSMACROS
 327 #include <sys/sysmacros.h>
 328 #endif
 329
 330 int main(void)
 331 {
 332         dev_t dev = makedev(0, 5, 7);
 333         if (major(dev) != 5 || minor(dev) != 7)
 334                 exit(1);
 335         return 0;
 336 }
 337 ],
 338 rsync_cv_MAKEDEV_TAKES_3_ARGS=yes,rsync_cv_MAKEDEV_TAKES_3_ARGS=no,rsync_cv_MAKEDEV_TAKES_3_ARGS=no)])
 339 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 340    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 341 fi
 342
 343 AC_CHECK_SIZEOF(int)
 344 AC_CHECK_SIZEOF(long)
 345 AC_CHECK_SIZEOF(long long)
 346 AC_CHECK_SIZEOF(short)
 347 AC_CHECK_SIZEOF(int16_t)
 348 AC_CHECK_SIZEOF(uint16_t)
 349 AC_CHECK_SIZEOF(int32_t)
 350 AC_CHECK_SIZEOF(uint32_t)
 351 AC_CHECK_SIZEOF(int64_t)
 352 AC_CHECK_SIZEOF(off_t)
 353 AC_CHECK_SIZEOF(off64_t)
 354 AC_CHECK_SIZEOF(time_t)
 355
 356 AC_C_INLINE
 357 AC_C_LONG_DOUBLE
 358
 359 AC_TYPE_SIGNAL
 360 AC_TYPE_UID_T
 361 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 362 AC_TYPE_GETGROUPS
 363 AC_CHECK_MEMBERS([struct stat.st_rdev])
 364
 365 TYPE_SOCKLEN_T
 366
 367 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 368     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
 369         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
 370 if test x"$rsync_cv_errno" = x"yes"; then
 371    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 372 fi
 373
 374 # The following test taken from the cvs sources
 375 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 376 # These need checks to be before checks for any other functions that
 377 #    might be in the same libraries.
 378 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 379 # libsocket.so which has a bad implementation of gethostbyname (it
 380 # only looks in /etc/hosts), so we only look for -lsocket if we need
 381 # it.
 382 AC_CHECK_FUNCS(connect)
 383 if test x"$ac_cv_func_connect" = x"no"; then
 384     case "$LIBS" in
 385     *-lnsl*) ;;
 386     *) AC_CHECK_LIB(nsl_s, printf) ;;
 387     esac
 388     case "$LIBS" in
 389     *-lnsl*) ;;
 390     *) AC_CHECK_LIB(nsl, printf) ;;
 391     esac
 392     case "$LIBS" in
 393     *-lsocket*) ;;
 394     *) AC_CHECK_LIB(socket, connect) ;;
 395     esac
 396     case "$LIBS" in
 397     *-linet*) ;;
 398     *) AC_CHECK_LIB(inet, connect) ;;
 399     esac
 400     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 401     dnl has been cached.
 402     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 403        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 404         # ac_cv_func_connect=yes
 405         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 406         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 407     fi
 408 fi
 409
 410 AC_SEARCH_LIBS(inet_ntop, resolv)
 411
 412 # Solaris and HP-UX weirdness:
 413 # Search for libiconv_open (not iconv_open) to discover if -liconv is needed!
 414 AC_SEARCH_LIBS(libiconv_open, iconv)
 415
 416 AC_MSG_CHECKING([for iconv declaration])
 417 AC_CACHE_VAL(am_cv_proto_iconv, [
 418     AC_TRY_COMPILE([
 419 #include <stdlib.h>
 420 #include <iconv.h>
 421 extern
 422 #ifdef __cplusplus
 423 "C"
 424 #endif
 425 #if defined(__STDC__) || defined(__cplusplus)
 426 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 427 #else
 428 size_t iconv();
 429 #endif
 430 ], [], am_cv_proto_iconv_arg1="", am_cv_proto_iconv_arg1="const")
 431       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 432     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 433 AC_MSG_RESULT([$]{ac_t:-
 434          }[$]am_cv_proto_iconv)
 435 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 436                    [Define as const if the declaration of iconv() needs const.])
 437
 438 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 439
 440 AC_CHECK_FUNCS(inet_ntop, , [AC_LIBOBJ(lib/inet_ntop)])
 441 AC_CHECK_FUNCS(inet_pton, , [AC_LIBOBJ(lib/inet_pton)])
 442
 443 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 444 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 445 #include <sys/socket.h>])
 446
 447 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 448 #   builtin getaddrinfo if one of the defines don't exist
 449 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 450                rsync_cv_HAVE_GETADDR_DEFINES,[
 451                         AC_EGREP_CPP(yes, [
 452                         #include <sys/types.h>
 453                         #include <sys/socket.h>
 454                         #include <netdb.h>
 455                         #ifdef AI_PASSIVE
 456                         yes
 457                         #endif],
 458                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 459                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 460 if test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"; then
 461         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 462         # something else so we must include <netdb.h> to get the
 463         # redefinition.
 464         AC_CHECK_FUNCS(getaddrinfo, ,
 465                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 466                 AC_TRY_LINK([#include <sys/types.h>
 467                 #include <sys/socket.h>
 468                 #include <netdb.h>],[getaddrinfo(NULL, NULL, NULL, NULL);],
 469                         [AC_MSG_RESULT([yes])
 470                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 471                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],
 472                         [AC_MSG_RESULT([no])
 473                         AC_LIBOBJ(lib/getaddrinfo)])])
 474 else
 475         AC_LIBOBJ(lib/getaddrinfo)
 476 fi
 477
 478 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 479                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 480                 [],
 481                 [
 482 #include <sys/types.h>
 483 #include <sys/socket.h>
 484 ])
 485
 486 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 487                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 488                 [],
 489                 [
 490 #include <sys/types.h>
 491 #include <sys/socket.h>
 492 #include <netinet/in.h>
 493 ])
 494
 495 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 496                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 497                 [],
 498                 [
 499 #include <sys/types.h>
 500 #include <sys/socket.h>
 501 #include <netinet/in.h>
 502 ])
 503
 504 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 505                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 506                 [],
 507                 [
 508 #include <sys/types.h>
 509 #include <sys/socket.h>
 510 #include <netinet/in.h>
 511 ])
 512
 513 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 514 #if HAVE_SYS_TYPES_H
 515 # include <sys/types.h>
 516 #endif
 517 #if HAVE_SYS_STAT_H
 518 # include <sys/stat.h>
 519 #endif
 520 #if STDC_HEADERS
 521 # include <stdlib.h>
 522 # include <stddef.h>
 523 #else
 524 # if HAVE_STDLIB_H
 525 #  include <stdlib.h>
 526 # endif
 527 #endif
 528 ])
 529
 530 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 531 #
 532 AC_CHECK_FUNCS(strcasecmp)
 533 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 534     AC_CHECK_LIB(resolv, strcasecmp)
 535 fi
 536
 537 AC_CHECK_FUNCS(aclsort)
 538 if test x"$ac_cv_func_aclsort" = x"no"; then
 539     AC_CHECK_LIB(sec, aclsort)
 540 fi
 541
 542 dnl At the moment we don't test for a broken memcmp(), because all we
 543 dnl need to do is test for equality, not comparison, and it seems that
 544 dnl every platform has a memcmp that can do at least that.
 545 dnl AC_FUNC_MEMCMP
 546
 547 AC_FUNC_UTIME_NULL
 548 AC_FUNC_ALLOCA
 549 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 550     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 551     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 552     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 553     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 554     strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 555     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 556     initgroups)
 557
 558 dnl cygwin iconv.h defines iconv_open as libiconv_open
 559 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 560     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 561 fi
 562
 563 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 564 if test $ac_cv_func_getpgrp = yes; then
 565     AC_FUNC_GETPGRP
 566 fi
 567
 568 AC_ARG_ENABLE(iconv-open,
 569     AC_HELP_STRING([--disable-iconv-open],
 570             [disable all use of iconv_open() function]),
 571     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 572
 573 if test x"$enable_iconv_open" != x"no"; then
 574     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 575 fi
 576
 577 AC_ARG_ENABLE(iconv,
 578     AC_HELP_STRING([--disable-iconv],
 579             [disable rsync's --iconv option]),
 580     [], [enable_iconv=$enable_iconv_open])
 581 AH_TEMPLATE([ICONV_OPTION],
 582 [Define if you want the --iconv option.  Specifing a value will set the
 583 default iconv setting (a NULL means no --iconv processing by default).])
 584 if test x"$enable_iconv" != x"no"; then
 585         if test x"$enable_iconv" = x"yes"; then
 586                 AC_DEFINE(ICONV_OPTION, NULL)
 587         else
 588                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 589         fi
 590         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 591 fi
 592
 593 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 594   AC_TRY_RUN([
 595 #if HAVE_UNISTD_H
 596 # include <unistd.h>
 597 #endif
 598 #include <stdlib.h>
 599 #include <errno.h>
 600     main() {
 601         char const *dangling_symlink = "conftest.dangle";
 602         unlink(dangling_symlink);
 603         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 604         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) exit(1);
 605         exit(0);
 606     }],
 607   rsync_cv_chown_modifies_symlink=yes,rsync_cv_chown_modifies_symlink=no,rsync_cv_chown_modifies_symlink=no)])
 608 if test $rsync_cv_chown_modifies_symlink = yes; then
 609   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 610 fi
 611
 612 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 613   AC_TRY_RUN([
 614 #if HAVE_UNISTD_H
 615 # include <unistd.h>
 616 #endif
 617 #include <stdlib.h>
 618 #include <errno.h>
 619 #define FILENAME "conftest.dangle"
 620     main() {
 621         unlink(FILENAME);
 622         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 623         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 624         exit(0);
 625     }],
 626   rsync_cv_can_hardlink_symlink=yes,rsync_cv_can_hardlink_symlink=no,rsync_cv_can_hardlink_symlink=no)])
 627 if test $rsync_cv_can_hardlink_symlink = yes; then
 628   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 629 fi
 630
 631 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 632   AC_TRY_RUN([
 633 #if HAVE_UNISTD_H
 634 # include <unistd.h>
 635 #endif
 636 #include <stdlib.h>
 637 #include <errno.h>
 638 #define FILENAME "conftest.fifi"
 639     main() {
 640         unlink(FILENAME);
 641         if (mkfifo(FILENAME, 0777) < 0) abort();
 642         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 643         exit(0);
 644     }],
 645   rsync_cv_can_hardlink_special=yes,rsync_cv_can_hardlink_special=no,rsync_cv_can_hardlink_special=no)])
 646 if test $rsync_cv_can_hardlink_special = yes; then
 647     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 648 fi
 649
 650 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 651 AC_TRY_RUN([
 652 #include <sys/types.h>
 653 #include <sys/socket.h>
 654
 655 main() {
 656        int fd[2];
 657        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 658 }],
 659 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
 660 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 661     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 662 fi
 663
 664 if test x"$with_included_popt" != x"yes"; then
 665     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 666 fi
 667 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
 668     # If the system has /usr/include/popt/popt.h, we enable the
 669     # included popt because an attempt to "#include <popt/popt.h>"
 670     # would use our included header file anyway (due to -I.), and
 671     # might conflict with the system popt.
 672     with_included_popt=yes
 673 elif test x"$ac_cv_header_popt_h" != x"yes"; then
 674     with_included_popt=yes
 675 fi
 676
 677 AC_MSG_CHECKING([whether to use included libpopt])
 678 if test x"$with_included_popt" = x"yes"; then
 679     AC_MSG_RESULT($srcdir/popt)
 680     BUILD_POPT='$(popt_OBJS)'
 681     CFLAGS="$CFLAGS -I$srcdir/popt"
 682     if test x"$ALLOCA" != x
 683     then
 684         # this can be removed when/if we add an included alloca.c;
 685         #  see autoconf documentation on AC_FUNC_ALLOCA
 686         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 687     fi
 688 else
 689     AC_MSG_RESULT(no)
 690 fi
 691
 692 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 693 AC_TRY_COMPILE([],[signed char *s = ""],
 694 rsync_cv_SIGNED_CHAR_OK=yes,rsync_cv_SIGNED_CHAR_OK=no)])
 695 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 696     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 697 fi
 698
 699 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 700 AC_TRY_RUN([#include <sys/types.h>
 701 #include <dirent.h>
 702 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 703 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 704 di->d_name[0] == 0) exit(0); exit(1);} ],
 705 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 706 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 707     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
 708 fi
 709
 710 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
 711 AC_TRY_COMPILE([#include <sys/types.h>
 712 #include <utime.h>],
 713 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 714 rsync_cv_HAVE_STRUCT_UTIMBUF=yes,rsync_cv_HAVE_STRUCT_UTIMBUF=no)])
 715 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
 716     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
 717 fi
 718
 719 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 720 AC_TRY_COMPILE([#include <sys/time.h>
 721 #include <unistd.h>],
 722 [struct timeval tv; exit(gettimeofday(&tv, NULL));],
 723 rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no)])
 724 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
 725     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
 726 fi
 727
 728 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 729 AC_TRY_RUN([
 730 #include <sys/types.h>
 731 #include <stdarg.h>
 732 void foo(const char *format, ...) {
 733        va_list ap;
 734        int len;
 735        char buf[5];
 736
 737        va_start(ap, format);
 738        len = vsnprintf(0, 0, format, ap);
 739        va_end(ap);
 740        if (len != 5) exit(1);
 741
 742        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 743
 744        exit(0);
 745 }
 746 main() { foo("hello"); }
 747 ],
 748 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
 749 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 750     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
 751 fi
 752
 753
 754 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 755 AC_TRY_RUN([#include <stdlib.h>
 756 #include <sys/types.h>
 757 #include <sys/stat.h>
 758 #include <unistd.h>
 759 main() {
 760   struct stat st;
 761   char tpl[20]="/tmp/test.XXXXXX";
 762   int fd = mkstemp(tpl);
 763   if (fd == -1) exit(1);
 764   unlink(tpl);
 765   if (fstat(fd, &st) != 0) exit(1);
 766   if ((st.st_mode & 0777) != 0600) exit(1);
 767   exit(0);
 768 }],
 769 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
 770 rsync_cv_HAVE_SECURE_MKSTEMP=no,
 771 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
 772 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 773     case $host_os in
 774     hpux*)
 775         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
 776         dnl so we noisily skip using it.  See HP change request JAGaf34426
 777         dnl for details. (sbonds)
 778         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
 779         ;;
 780     *)
 781         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
 782         ;;
 783     esac
 784 fi
 785
 786
 787 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
 788 AC_TRY_RUN([
 789 #include <stdio.h>
 790 #include <sys/stat.h>
 791 #include <errno.h>
 792 main() { int rc, ec; char *fn = "fifo-test";
 793 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
 794 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 795 return 0;}],
 796            rsync_cv_MKNOD_CREATES_FIFOS=yes,rsync_cv_MKNOD_CREATES_FIFOS=no,rsync_cv_MKNOD_CREATES_FIFOS=cross)])
 797 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
 798     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
 799 fi
 800
 801 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
 802 AC_TRY_RUN([
 803 #include <stdio.h>
 804 #include <sys/stat.h>
 805 #include <errno.h>
 806 main() { int rc, ec; char *fn = "sock-test";
 807 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
 808 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 809 return 0;}],
 810            rsync_cv_MKNOD_CREATES_SOCKETS=yes,rsync_cv_MKNOD_CREATES_SOCKETS=no,rsync_cv_MKNOD_CREATES_SOCKETS=cross)])
 811 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
 812     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
 813 fi
 814
 815 #
 816 # The following test was mostly taken from the tcl/tk plus patches
 817 #
 818 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 819 rm -rf conftest*
 820 cat > conftest.$ac_ext <<EOF
 821 int main() { return 0; }
 822 EOF
 823 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 824 if test -f conftest..o; then
 825     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 826 else
 827     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 828 fi
 829 rm -rf conftest*
 830 ])
 831 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 832     OBJ_SAVE="#"
 833     OBJ_RESTORE="#"
 834     CC_SHOBJ_FLAG='-o $@'
 835 else
 836     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 837     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 838     CC_SHOBJ_FLAG=""
 839 fi
 840
 841 AC_SUBST(OBJ_SAVE)
 842 AC_SUBST(OBJ_RESTORE)
 843 AC_SUBST(CC_SHOBJ_FLAG)
 844 AC_SUBST(BUILD_POPT)
 845 AC_SUBST(MAKE_MAN)
 846
 847 AC_CHECK_FUNCS(_acl __acl _facl __facl)
 848 #################################################
 849 # check for ACL support
 850
 851 AC_MSG_CHECKING([whether to support ACLs])
 852 AC_ARG_ENABLE(acl-support,
 853         AC_HELP_STRING([--disable-acl-support],
 854                        [disable ACL support]))
 855
 856 if test x"$enable_acl_support" = x"no"; then
 857     AC_MSG_RESULT(no)
 858 else
 859     case "$host_os" in
 860     *sysv5*)
 861         AC_MSG_RESULT(Using UnixWare ACLs)
 862         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
 863         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
 864         ;;
 865     *solaris*|*cygwin*)
 866         AC_MSG_RESULT(Using solaris ACLs)
 867         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
 868         AC_DEFINE(SUPPORT_ACLS, 1)
 869         ;;
 870     *hpux*)
 871         AC_MSG_RESULT(Using HPUX ACLs)
 872         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
 873         AC_DEFINE(SUPPORT_ACLS, 1)
 874         ;;
 875     *irix*)
 876         AC_MSG_RESULT(Using IRIX ACLs)
 877         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
 878         AC_DEFINE(SUPPORT_ACLS, 1)
 879         ;;
 880     *aix*)
 881         AC_MSG_RESULT(Using AIX ACLs)
 882         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
 883         AC_DEFINE(SUPPORT_ACLS, 1)
 884         ;;
 885     *osf*)
 886         AC_MSG_RESULT(Using Tru64 ACLs)
 887         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
 888         AC_DEFINE(SUPPORT_ACLS, 1)
 889         LIBS="$LIBS -lpacl"
 890         ;;
 891     darwin*)
 892         AC_MSG_RESULT(Using OS X ACLs)
 893         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
 894         AC_DEFINE(SUPPORT_ACLS, 1)
 895         ;;
 896     *)
 897         AC_MSG_RESULT(running tests:)
 898         AC_CHECK_LIB(acl,acl_get_file)
 899             AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
 900             AC_TRY_LINK([#include <sys/types.h>
 901 #include <sys/acl.h>],
 902 [ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);],
 903 samba_cv_HAVE_POSIX_ACLS=yes,samba_cv_HAVE_POSIX_ACLS=no)])
 904         AC_MSG_CHECKING(ACL test results)
 905         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
 906             AC_MSG_RESULT(Using posix ACLs)
 907             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
 908             AC_DEFINE(SUPPORT_ACLS, 1)
 909             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
 910                 AC_TRY_LINK([#include <sys/types.h>
 911 #include <sys/acl.h>],
 912 [ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);],
 913 samba_cv_HAVE_ACL_GET_PERM_NP=yes,samba_cv_HAVE_ACL_GET_PERM_NP=no)])
 914             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
 915                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
 916             fi
 917         else
 918             if test x"$enable_acl_support" = x"yes"; then
 919                 AC_MSG_ERROR(Failed to find ACL support)
 920             else
 921                 AC_MSG_RESULT(No ACL support found)
 922             fi
 923         fi
 924         ;;
 925     esac
 926 fi
 927
 928 #################################################
 929 # check for extended attribute support
 930 AC_MSG_CHECKING(whether to support extended attributes)
 931 AC_ARG_ENABLE(xattr-support,
 932     AC_HELP_STRING([--disable-xattr-support],
 933             [disable extended attributes]),
 934     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link" in
 935         *yes*) enable_xattr_support=maybe ;;
 936         *) enable_xattr_support=no ;;
 937         esac])
 938 AH_TEMPLATE([SUPPORT_XATTRS],
 939 [Define to 1 to add support for extended attributes])
 940 if test x"$enable_xattr_support" = x"no"; then
 941     AC_MSG_RESULT(no)
 942 else
 943     case "$host_os" in
 944     *linux*)
 945         AC_MSG_RESULT(Using Linux xattrs)
 946         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs])
 947         AC_DEFINE(SUPPORT_XATTRS, 1)
 948         ;;
 949     darwin*)
 950         AC_MSG_RESULT(Using OS X xattrs)
 951         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
 952         AC_DEFINE(SUPPORT_XATTRS, 1)
 953         ;;
 954     freebsd*)
 955         AC_MSG_RESULT(Using FreeBSD extattrs)
 956         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
 957         AC_DEFINE(SUPPORT_XATTRS, 1)
 958         ;;
 959     *)
 960         if test x"$enable_xattr_support" = x"yes"; then
 961             AC_MSG_ERROR(Failed to find extended attribute support)
 962         else
 963             AC_MSG_RESULT(No extended attribute support found)
 964         fi
 965         ;;
 966     esac
 967 fi
 968
 969 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
 970     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
 971     OLD_CFLAGS="$CFLAGS"
 972     CFLAGS="$CFLAGS -Wno-unused-parameter"
 973     AC_COMPILE_IFELSE([ ], [rsync_warn_flag=yes], [rsync_warn_flag=no])
 974     AC_MSG_RESULT([$rsync_warn_flag])
 975     if test x"$rsync_warn_flag" = x"no"; then
 976         CFLAGS="$OLD_CFLAGS"
 977     fi
 978 fi
 979
 980 case "$CC" in
 981 ' checker'*|checker*)
 982     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
 983     ;;
 984 esac
 985
 986 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
 987 AC_OUTPUT
 988
 989 AC_MSG_RESULT()
 990 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
 991 AC_MSG_RESULT()