configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT()
   4 AC_CONFIG_SRCDIR([byteorder.h])
   5 AC_CONFIG_HEADER(config.h)
   6 AC_PREREQ(2.59)
   7
   8 RSYNC_VERSION=2.6.9cvs
   9 AC_SUBST(RSYNC_VERSION)
  10 AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION])
  11
  12 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
  13
  14 LDFLAGS=${LDFLAGS-""}
  15
  16 AC_CANONICAL_TARGET([])
  17
  18 dnl Checks for programs.
  19 AC_PROG_CC
  20 AC_PROG_CPP
  21 AC_PROG_EGREP
  22 AC_PROG_INSTALL
  23 AC_PROG_CC_STDC
  24 AC_SUBST(SHELL)
  25
  26 AC_DEFINE([_GNU_SOURCE], 1,
  27           [Define _GNU_SOURCE so that we get all necessary prototypes])
  28
  29 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  30         AC_MSG_WARN([rsync requires an ANSI C compiler and you don't seem to have one])
  31 fi
  32
  33 # We must decide this before testing the compiler.
  34
  35 # Please allow this to default to yes, so that your users have more
  36 # chance of getting a useful stack trace if problems occur.
  37
  38 AC_MSG_CHECKING([whether to include debugging symbols])
  39 AC_ARG_ENABLE(debug,
  40         AC_HELP_STRING([--disable-debug],
  41                 [turn off debugging symbols and features]))
  42
  43 if test x"$enable_debug" = x"no"; then
  44     AC_MSG_RESULT(no)
  45     CFLAGS=${CFLAGS-"-O"}
  46 else
  47     AC_MSG_RESULT([yes])
  48     # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can
  49     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  50     dnl CFLAGS=${CFLAGS-"-g"}
  51 fi
  52
  53
  54 AC_ARG_ENABLE(profile,
  55         AC_HELP_STRING([--enable-profile],
  56                 [turn on CPU profiling]))
  57 if test x"$enable_profile" = x"yes"; then
  58         CFLAGS="$CFLAGS -pg"
  59 fi
  60
  61
  62 # Specifically, this turns on panic_action handling.
  63 AC_ARG_ENABLE(maintainer-mode,
  64         AC_HELP_STRING([--enable-maintainer-mode],
  65                 [turn on extra debug features]))
  66 if test x"$enable_maintainer_mode" = x"yes"; then
  67         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
  68 fi
  69
  70
  71 # This is needed for our included version of popt.  Kind of silly, but
  72 # I don't want our version too far out of sync.
  73 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  74
  75 # If GCC, turn on warnings.
  76 if test x"$GCC" = x"yes"; then
  77         CFLAGS="$CFLAGS -Wall -W"
  78 fi
  79
  80 AC_ARG_WITH(included-popt,
  81         AC_HELP_STRING([--with-included-popt], [use bundled popt library, not from system]))
  82
  83 AC_ARG_WITH(rsync-path,
  84         AC_HELP_STRING([--with-rsync-path=PATH], [set default --rsync-path to PATH (default: rsync)]),
  85         [ RSYNC_PATH="$with_rsync_path" ],
  86         [ RSYNC_PATH="rsync" ])
  87
  88 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
  89
  90 AC_ARG_WITH(rsyncd-conf,
  91         AC_HELP_STRING([--with-rsyncd-conf=PATH], [set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
  92         [ if test ! -z "$with_rsyncd_conf" ; then
  93                 case $with_rsyncd_conf in
  94                         yes|no)
  95                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
  96                                 ;;
  97                         /*)
  98                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
  99                                 ;;
 100                         *)
 101                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 102                                 ;;
 103                 esac
 104         else
 105                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 106         fi ],
 107         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 108
 109 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 110
 111 AC_ARG_WITH(rsh,
 112         AC_HELP_STRING([--with-rsh=CMD], [set remote shell command to CMD (default: ssh)]))
 113
 114 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 115 if test x$HAVE_REMSH = x1; then
 116         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 117 fi
 118
 119 if test x"$with_rsh" != x; then
 120         RSYNC_RSH="$with_rsh"
 121 else
 122         RSYNC_RSH="ssh"
 123 fi
 124 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 125
 126 AC_ARG_WITH(nobody-group,
 127     AC_HELP_STRING([--with-nobody-group=GROUP],
 128                    [set the default unprivileged group (default nobody or nogroup)]),
 129     [ NOBODY_GROUP="$with_nobody_group" ])
 130
 131 if test x"$with_nobody_group" = x; then
 132     AC_MSG_CHECKING([the group for user "nobody"])
 133     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 134         NOBODY_GROUP=nobody
 135     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 136         NOBODY_GROUP=nogroup
 137     else
 138         NOBODY_GROUP=nobody # test for others?
 139     fi
 140     AC_MSG_RESULT($NOBODY_GROUP)
 141 fi
 142
 143 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 144 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 145
 146 # arrgh. libc in some old debian version screwed up the largefile
 147 # stuff, getting byte range locking wrong
 148 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 149 AC_TRY_RUN([
 150 #define _FILE_OFFSET_BITS 64
 151 #include <stdio.h>
 152 #include <fcntl.h>
 153 #include <sys/types.h>
 154 #include <sys/wait.h>
 155
 156 int main(void)
 157 {
 158         struct flock lock;
 159         int status;
 160         char tpl[32] = "/tmp/locktest.XXXXXX";
 161         int fd = mkstemp(tpl);
 162         if (fd < 0) {
 163                 strcpy(tpl, "conftest.dat");
 164                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 165         }
 166
 167         lock.l_type = F_WRLCK;
 168         lock.l_whence = SEEK_SET;
 169         lock.l_start = 0;
 170         lock.l_len = 1;
 171         lock.l_pid = 0;
 172         fcntl(fd,F_SETLK,&lock);
 173         if (fork() == 0) {
 174                 lock.l_start = 1;
 175                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 176         }
 177         wait(&status);
 178         unlink(tpl);
 179         exit(WEXITSTATUS(status));
 180 }
 181 ],
 182 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
 183 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 184    AC_SYS_LARGEFILE
 185 fi
 186
 187 ipv6type=unknown
 188 ipv6lib=none
 189 ipv6trylibc=yes
 190
 191 AC_ARG_ENABLE(ipv6,
 192         AC_HELP_STRING([--disable-ipv6],
 193                 [don't even try to use IPv6]))
 194 if test x"$enable_ipv6" != x"no"; then
 195         AC_MSG_CHECKING([ipv6 stack type])
 196         for i in inria kame linux-glibc linux-inet6 toshiba v6d zeta; do
 197                 case $i in
 198                 inria)
 199                         # http://www.kame.net/
 200                         AC_EGREP_CPP(yes, [
 201 #include <netinet/in.h>
 202 #ifdef IPV6_INRIA_VERSION
 203 yes
 204 #endif],
 205                                 [ipv6type=$i;
 206                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 207                                 ])
 208                         ;;
 209                 kame)
 210                         # http://www.kame.net/
 211                         AC_EGREP_CPP(yes, [
 212 #include <netinet/in.h>
 213 #ifdef __KAME__
 214 yes
 215 #endif],
 216                                 [ipv6type=$i;
 217                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 218                         ;;
 219                 linux-glibc)
 220                         # http://www.v6.linux.or.jp/
 221                         AC_EGREP_CPP(yes, [
 222 #include <features.h>
 223 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 224 yes
 225 #endif],
 226                                 [ipv6type=$i;
 227 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 228                         ;;
 229                 linux-inet6)
 230                         # http://www.v6.linux.or.jp/
 231                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 232                                 ipv6type=$i
 233                                 ipv6lib=inet6
 234                                 ipv6libdir=/usr/inet6/lib
 235                                 ipv6trylibc=yes;
 236                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 237                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 238                         fi
 239                         ;;
 240                 toshiba)
 241                         AC_EGREP_CPP(yes, [
 242 #include <sys/param.h>
 243 #ifdef _TOSHIBA_INET6
 244 yes
 245 #endif],
 246                                 [ipv6type=$i;
 247                                 ipv6lib=inet6;
 248                                 ipv6libdir=/usr/local/v6/lib;
 249                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 250                         ;;
 251                 v6d)
 252                         AC_EGREP_CPP(yes, [
 253 #include </usr/local/v6/include/sys/v6config.h>
 254 #ifdef __V6D__
 255 yes
 256 #endif],
 257                                 [ipv6type=$i;
 258                                 ipv6lib=v6;
 259                                 ipv6libdir=/usr/local/v6/lib;
 260                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 261                         ;;
 262                 zeta)
 263                         AC_EGREP_CPP(yes, [
 264 #include <sys/param.h>
 265 #ifdef _ZETA_MINAMI_INET6
 266 yes
 267 #endif],
 268                                 [ipv6type=$i;
 269                                 ipv6lib=inet6;
 270                                 ipv6libdir=/usr/local/v6/lib;
 271                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 272                         ;;
 273                 esac
 274                 if test "$ipv6type" != "unknown"; then
 275                         break
 276                 fi
 277         done
 278         AC_MSG_RESULT($ipv6type)
 279
 280         AC_SEARCH_LIBS(getaddrinfo, inet6)
 281 fi
 282
 283 dnl Do you want to disable use of locale functions
 284 AC_ARG_ENABLE([locale],
 285         AC_HELP_STRING([--disable-locale],
 286                 [turn off locale features]))
 287 AH_TEMPLATE([CONFIG_LOCALE],
 288 [Undefine if you don't want locale features.  By default this is defined.])
 289 if test x"$enable_locale" != x"no"; then
 290         AC_DEFINE(CONFIG_LOCALE)
 291 fi
 292
 293 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 294 case $host_os in
 295         *cygwin* ) AC_MSG_RESULT(yes)
 296                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 297                             [Define to 1 if sockets need to be shutdown])
 298                    ;;
 299                * ) AC_MSG_RESULT(no);;
 300 esac
 301
 302 AC_C_BIGENDIAN
 303 AC_HEADER_DIRENT
 304 AC_HEADER_TIME
 305 AC_HEADER_SYS_WAIT
 306 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 307     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 308     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 309     sys/un.h glob.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 310     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h)
 311 AC_HEADER_MAJOR
 312
 313 AC_CHECK_SIZEOF(int)
 314 AC_CHECK_SIZEOF(long)
 315 AC_CHECK_SIZEOF(long long)
 316 AC_CHECK_SIZEOF(short)
 317 AC_CHECK_SIZEOF(off_t)
 318 AC_CHECK_SIZEOF(off64_t)
 319
 320 AC_C_INLINE
 321 AC_C_LONG_DOUBLE
 322
 323 AC_TYPE_SIGNAL
 324 AC_TYPE_UID_T
 325 AC_TYPE_MODE_T
 326 AC_TYPE_OFF_T
 327 AC_TYPE_SIZE_T
 328 AC_TYPE_PID_T
 329 AC_TYPE_GETGROUPS
 330 AC_CHECK_MEMBERS([struct stat.st_rdev])
 331
 332 TYPE_SOCKLEN_T
 333
 334 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 335     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
 336         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
 337 if test x"$rsync_cv_errno" = x"yes"; then
 338    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 339 fi
 340
 341 # The following test taken from the cvs sources
 342 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 343 # These need checks to be before checks for any other functions that
 344 #    might be in the same libraries.
 345 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 346 # libsocket.so which has a bad implementation of gethostbyname (it
 347 # only looks in /etc/hosts), so we only look for -lsocket if we need
 348 # it.
 349 AC_CHECK_FUNCS(connect)
 350 if test x"$ac_cv_func_connect" = x"no"; then
 351     case "$LIBS" in
 352     *-lnsl*) ;;
 353     *) AC_CHECK_LIB(nsl_s, printf) ;;
 354     esac
 355     case "$LIBS" in
 356     *-lnsl*) ;;
 357     *) AC_CHECK_LIB(nsl, printf) ;;
 358     esac
 359     case "$LIBS" in
 360     *-lsocket*) ;;
 361     *) AC_CHECK_LIB(socket, connect) ;;
 362     esac
 363     case "$LIBS" in
 364     *-linet*) ;;
 365     *) AC_CHECK_LIB(inet, connect) ;;
 366     esac
 367     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 368     dnl has been cached.
 369     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 370        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 371         # ac_cv_func_connect=yes
 372         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 373         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 374     fi
 375 fi
 376
 377 AC_SEARCH_LIBS(inet_ntop, resolv)
 378
 379 # Solaris and HP-UX weirdness:
 380 # Search for libiconv_open (not iconv_open) to discover if -liconv is needed!
 381 AC_SEARCH_LIBS(libiconv_open, iconv)
 382
 383 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 384
 385 AC_CHECK_FUNCS(inet_ntop, , [AC_LIBOBJ(lib/inet_ntop)])
 386 AC_CHECK_FUNCS(inet_pton, , [AC_LIBOBJ(lib/inet_pton)])
 387
 388 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 389 #   builtin getaddrinfo if one of the defines don't exist
 390 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 391                rsync_cv_HAVE_GETADDR_DEFINES,[
 392                         AC_EGREP_CPP(yes, [
 393                         #include <sys/types.h>
 394                         #include <sys/socket.h>
 395                         #include <netdb.h>
 396                         #ifdef AI_PASSIVE
 397                         yes
 398                         #endif],
 399                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 400                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 401 if test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes"; then
 402         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 403         # something else so we must include <netdb.h> to get the
 404         # redefinition.
 405         AC_CHECK_FUNCS(getaddrinfo, ,
 406                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 407                 AC_TRY_LINK([#include <sys/types.h>
 408                 #include <sys/socket.h>
 409                 #include <netdb.h>],[getaddrinfo(NULL, NULL, NULL, NULL);],
 410                         [AC_MSG_RESULT([yes])
 411                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 412                                 [Define to 1 if you have the "getaddrinfo" function.])],
 413                         [AC_MSG_RESULT([no])
 414                         AC_LIBOBJ(lib/getaddrinfo)])])
 415         AC_CHECK_FUNCS(getnameinfo, , [AC_LIBOBJ(lib/getnameinfo)])
 416 else
 417         AC_LIBOBJ(lib/getaddrinfo)
 418         AC_LIBOBJ(lib/getnameinfo)
 419 fi
 420
 421 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 422                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 423                 [],
 424                 [
 425 #include <sys/types.h>
 426 #include <sys/socket.h>
 427 ])
 428
 429 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 430                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 431                 [],
 432                 [
 433 #include <sys/types.h>
 434 #include <sys/socket.h>
 435 #include <netinet/in.h>
 436 ])
 437
 438 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 439                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 440                 [],
 441                 [
 442 #include <sys/types.h>
 443 #include <sys/socket.h>
 444 #include <netinet/in.h>
 445 ])
 446
 447 AC_MSG_CHECKING(struct sockaddr_storage)
 448 AC_TRY_COMPILE([#include <sys/types.h>
 449 #include <sys/socket.h>],
 450 [struct sockaddr_storage x;],
 451         AC_MSG_RESULT(yes)
 452         AC_DEFINE(HAVE_SOCKADDR_STORAGE, 1,
 453                 [Define to 1 if you have struct sockaddr_storage.] ),
 454         AC_MSG_RESULT(no))
 455
 456 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 457                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 458                 [],
 459                 [
 460 #include <sys/types.h>
 461 #include <sys/socket.h>
 462 #include <netinet/in.h>
 463 ])
 464
 465 AC_MSG_CHECKING(struct stat64)
 466 AC_TRY_COMPILE([#include <stdio.h>
 467 #if HAVE_SYS_TYPES_H
 468 # include <sys/types.h>
 469 #endif
 470 #if HAVE_SYS_STAT_H
 471 # include <sys/stat.h>
 472 #endif
 473 #if STDC_HEADERS
 474 # include <stdlib.h>
 475 # include <stddef.h>
 476 #else
 477 # if HAVE_STDLIB_H
 478 #  include <stdlib.h>
 479 # endif
 480 #endif
 481 ],[struct stat64 st;],
 482     AC_MSG_RESULT(yes)
 483         AC_DEFINE(HAVE_STRUCT_STAT64,1,[Define to 1 if you have struct stat64.]),
 484     AC_MSG_RESULT(no))
 485
 486 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 487 #
 488 AC_CHECK_FUNCS(strcasecmp)
 489 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 490     AC_CHECK_LIB(resolv, strcasecmp)
 491 fi
 492
 493 dnl At the moment we don't test for a broken memcmp(), because all we
 494 dnl need to do is test for equality, not comparison, and it seems that
 495 dnl every platform has a memcmp that can do at least that.
 496 dnl AC_FUNC_MEMCMP
 497
 498 AC_FUNC_UTIME_NULL
 499 AC_FUNC_ALLOCA
 500 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 501     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 502     memmove lchown vsnprintf snprintf vasprintf asprintf setsid glob strpbrk \
 503     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 504     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 505     strerror putenv iconv_open locale_charset nl_langinfo \
 506     sigaction sigprocmask)
 507
 508 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 509 if test $ac_cv_func_getpgrp = yes; then
 510     AC_FUNC_GETPGRP
 511 fi
 512
 513 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 514   AC_TRY_RUN([
 515 #if HAVE_UNISTD_H
 516 # include <unistd.h>
 517 #endif
 518 #include <stdlib.h>
 519 #include <errno.h>
 520     main() {
 521         char const *dangling_symlink = "conftest.dangle";
 522         unlink(dangling_symlink);
 523         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 524         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) exit(1);
 525         exit(0);
 526     }],
 527   rsync_cv_chown_modifies_symlink=yes,rsync_cv_chown_modifies_symlink=no,rsync_cv_chown_modifies_symlink=no)])
 528 if test $rsync_cv_chown_modifies_symlink = yes; then
 529   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 530 fi
 531
 532 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 533   AC_TRY_RUN([
 534 #if HAVE_UNISTD_H
 535 # include <unistd.h>
 536 #endif
 537 #include <stdlib.h>
 538 #include <errno.h>
 539 #define FILENAME "conftest.dangle"
 540     main() {
 541         unlink(FILENAME);
 542         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 543         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 544         exit(0);
 545     }],
 546   rsync_cv_can_hardlink_symlink=yes,rsync_cv_can_hardlink_symlink=no,rsync_cv_can_hardlink_symlink=no)])
 547 if test $rsync_cv_can_hardlink_symlink = yes; then
 548   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 549 fi
 550
 551 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 552   AC_TRY_RUN([
 553 #if HAVE_UNISTD_H
 554 # include <unistd.h>
 555 #endif
 556 #include <stdlib.h>
 557 #include <errno.h>
 558 #define FILENAME "conftest.fifi"
 559     main() {
 560         unlink(FILENAME);
 561         if (mkfifo(FILENAME, 0777) < 0) abort();
 562         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 563         exit(0);
 564     }],
 565   rsync_cv_can_hardlink_special=yes,rsync_cv_can_hardlink_special=no,rsync_cv_can_hardlink_special=no)])
 566 if test $rsync_cv_can_hardlink_special = yes; then
 567     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 568 fi
 569
 570 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 571 AC_TRY_RUN([
 572 #include <sys/types.h>
 573 #include <sys/socket.h>
 574
 575 main() {
 576        int fd[2];
 577        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 578 }],
 579 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
 580 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 581     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 582 fi
 583
 584 if test x"$with_included_popt" != x"yes"; then
 585     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 586 fi
 587
 588 AC_MSG_CHECKING([whether to use included libpopt])
 589 if test x"$with_included_popt" = x"yes"; then
 590     AC_MSG_RESULT($srcdir/popt)
 591     BUILD_POPT='$(popt_OBJS)'
 592     CFLAGS="$CFLAGS -I$srcdir/popt"
 593     if test x"$ALLOCA" != x
 594     then
 595         # this can be removed when/if we add an included alloca.c;
 596         #  see autoconf documentation on AC_FUNC_ALLOCA
 597         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 598     fi
 599 else
 600     AC_MSG_RESULT(no)
 601 fi
 602
 603 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 604 AC_TRY_COMPILE([],[signed char *s = ""],
 605 rsync_cv_SIGNED_CHAR_OK=yes,rsync_cv_SIGNED_CHAR_OK=no)])
 606 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 607     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 608 fi
 609
 610 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 611 AC_TRY_RUN([#include <sys/types.h>
 612 #include <dirent.h>
 613 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 614 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 615 di->d_name[0] == 0) exit(0); exit(1);} ],
 616 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 617 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 618     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
 619 fi
 620
 621 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[
 622 AC_TRY_COMPILE([#include <sys/types.h>
 623 #include <utime.h>],
 624 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 625 rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no)])
 626 if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then
 627     AC_DEFINE(HAVE_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
 628 fi
 629
 630 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 631 AC_TRY_COMPILE([#include <sys/time.h>
 632 #include <unistd.h>],
 633 [struct timeval tv; exit(gettimeofday(&tv, NULL));],
 634 rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no)])
 635 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
 636     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
 637 fi
 638
 639 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 640 AC_TRY_RUN([
 641 #include <sys/types.h>
 642 #include <stdarg.h>
 643 void foo(const char *format, ...) {
 644        va_list ap;
 645        int len;
 646        char buf[5];
 647
 648        va_start(ap, format);
 649        len = vsnprintf(0, 0, format, ap);
 650        va_end(ap);
 651        if (len != 5) exit(1);
 652
 653        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 654
 655        exit(0);
 656 }
 657 main() { foo("hello"); }
 658 ],
 659 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
 660 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 661     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
 662 fi
 663
 664
 665 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 666 AC_TRY_RUN([#include <stdlib.h>
 667 #include <sys/types.h>
 668 #include <sys/stat.h>
 669 #include <unistd.h>
 670 main() {
 671   struct stat st;
 672   char tpl[20]="/tmp/test.XXXXXX";
 673   int fd = mkstemp(tpl);
 674   if (fd == -1) exit(1);
 675   unlink(tpl);
 676   if (fstat(fd, &st) != 0) exit(1);
 677   if ((st.st_mode & 0777) != 0600) exit(1);
 678   exit(0);
 679 }],
 680 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
 681 rsync_cv_HAVE_SECURE_MKSTEMP=no,
 682 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
 683 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 684     case $target_os in
 685     hpux*)
 686         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
 687         dnl so we noisily skip using it.  See HP change request JAGaf34426
 688         dnl for details. (sbonds)
 689         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
 690         ;;
 691     *)
 692         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
 693         ;;
 694     esac
 695 fi
 696
 697
 698 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
 699 AC_TRY_RUN([
 700 #include <stdio.h>
 701 #include <sys/stat.h>
 702 #include <errno.h>
 703 main() { int rc, ec; char *fn = "fifo-test";
 704 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
 705 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 706 return 0;}],
 707            rsync_cv_MKNOD_CREATES_FIFOS=yes,rsync_cv_MKNOD_CREATES_FIFOS=no,rsync_cv_MKNOD_CREATES_FIFOS=cross)])
 708 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
 709     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
 710 fi
 711
 712 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
 713 AC_TRY_RUN([
 714 #include <stdio.h>
 715 #include <sys/stat.h>
 716 #include <errno.h>
 717 main() { int rc, ec; char *fn = "sock-test";
 718 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
 719 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 720 return 0;}],
 721            rsync_cv_MKNOD_CREATES_SOCKETS=yes,rsync_cv_MKNOD_CREATES_SOCKETS=no,rsync_cv_MKNOD_CREATES_SOCKETS=cross)])
 722 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
 723     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
 724 fi
 725
 726 #
 727 # The following test was mostly taken from the tcl/tk plus patches
 728 #
 729 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 730 rm -rf conftest*
 731 cat > conftest.$ac_ext <<EOF
 732 int main() { return 0; }
 733 EOF
 734 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 735 if test -f conftest..o; then
 736     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 737 else
 738     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 739 fi
 740 rm -rf conftest*
 741 ])
 742 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 743     OBJ_SAVE="#"
 744     OBJ_RESTORE="#"
 745     CC_SHOBJ_FLAG='-o $@'
 746 else
 747     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 748     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 749     CC_SHOBJ_FLAG=""
 750 fi
 751
 752 AC_SUBST(OBJ_SAVE)
 753 AC_SUBST(OBJ_RESTORE)
 754 AC_SUBST(CC_SHOBJ_FLAG)
 755 AC_SUBST(BUILD_POPT)
 756
 757 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
 758 AC_OUTPUT
 759
 760 AC_MSG_RESULT()
 761 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
 762 AC_MSG_RESULT()