configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT()
   4 AC_CONFIG_SRCDIR([byteorder.h])
   5 AC_CONFIG_HEADER(config.h)
   6 AC_PREREQ(2.52)
   7
   8 RSYNC_VERSION=2.6.3
   9 AC_SUBST(RSYNC_VERSION)
  10 AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION])
  11
  12 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
  13
  14 LDFLAGS=${LDFLAGS-""}
  15
  16 AC_CANONICAL_TARGET([])
  17
  18 dnl Checks for programs.
  19 AC_PROG_CC
  20 AC_PROG_CPP
  21 AC_PROG_EGREP
  22 AC_PROG_INSTALL
  23 AC_PROG_CC_STDC
  24 AC_SUBST(SHELL)
  25
  26 AC_DEFINE([_GNU_SOURCE], 1,
  27           [Define _GNU_SOURCE so that we get all necessary prototypes])
  28
  29 if test "x$ac_cv_prog_cc_stdc" = xno
  30 then
  31         AC_MSG_WARN([rsync requires an ANSI C compiler and you don't seem to have one])
  32 fi
  33
  34 # We must decide this before testing the compiler.
  35
  36 # Please allow this to default to yes, so that your users have more
  37 # chance of getting a useful stack trace if problems occur.
  38
  39 AC_MSG_CHECKING([whether to include debugging symbols])
  40 AC_ARG_ENABLE(debug,
  41         AC_HELP_STRING([--enable-debug],
  42                 [including debugging symbols and features (default yes)]),
  43                 [], [])
  44
  45 if test x"$enable_debug" = x"no"
  46 then
  47     AC_MSG_RESULT(no)
  48     CFLAGS=${CFLAGS-"-O"}
  49 else
  50     AC_MSG_RESULT([yes])
  51     # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can
  52     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  53     dnl CFLAGS=${CFLAGS-"-g"}
  54 fi
  55
  56
  57
  58
  59 AC_ARG_ENABLE(profile,
  60         AC_HELP_STRING([--enable-profile],
  61                 [turn on CPU profiling (default no)],
  62                 [], []))
  63 if test x"$enable_profile" = xyes
  64 then
  65         CFLAGS="$CFLAGS -pg"
  66 fi
  67
  68
  69 # Specifically, this turns on panic_action handling.
  70 AC_ARG_ENABLE(maintainer-mode,
  71         AC_HELP_STRING([--enable-maintainer-mode],
  72                 [turn on extra debug features],
  73                 [], []))
  74 if test x"$enable_maintainer_mode" = xyes
  75 then
  76         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
  77 fi
  78
  79
  80 # This is needed for our included version of popt.  Kind of silly, but
  81 # I don't want our version too far out of sync.
  82 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  83
  84 # If GCC, turn on warnings.
  85 if test "x$GCC" = "xyes"
  86 then
  87         CFLAGS="$CFLAGS -Wall -W"
  88 fi
  89
  90 AC_ARG_WITH(included-popt,
  91         [  --with-included-popt    use bundled popt library, not from system])
  92
  93 AC_ARG_WITH(rsync-path,
  94         [  --with-rsync-path=PATH  set default --rsync-path to PATH (default: rsync)],
  95         [ RSYNC_PATH="$with_rsync_path" ],
  96         [ RSYNC_PATH="rsync" ])
  97
  98 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
  99
 100 AC_ARG_WITH(rsyncd-conf,
 101         AC_HELP_STRING([--with-rsyncd-conf=PATH], [set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 102         [ if test ! -z "$with_rsyncd_conf" ; then
 103                 case $with_rsyncd_conf in
 104                         yes|no)
 105                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 106                                 ;;
 107                         /*)
 108                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 109                                 ;;
 110                         *)
 111                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 112                                 ;;
 113                 esac
 114         else
 115                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 116         fi ],
 117         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 118
 119 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 120
 121 AC_ARG_WITH(rsh,
 122         AC_HELP_STRING([--with-rsh=CMD], [set remote shell command to CMD (default: ssh)]))
 123
 124 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 125 AC_DEFINE_UNQUOTED(HAVE_REMSH, $HAVE_REMSH, [remote shell is remsh not rsh])
 126
 127 if test x"$with_rsh" != x
 128 then
 129         RSYNC_RSH="$with_rsh"
 130 else
 131         RSYNC_RSH="ssh"
 132 fi
 133
 134 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 135
 136 # arrgh. libc in the current debian stable screws up the largefile
 137 # stuff, getting byte range locking wrong
 138 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 139 AC_TRY_RUN([
 140 #define _FILE_OFFSET_BITS 64
 141 #include <stdio.h>
 142 #include <fcntl.h>
 143 #include <sys/types.h>
 144 #include <sys/wait.h>
 145
 146 int main(void)
 147 {
 148         struct flock lock;
 149         int status;
 150         char tpl[32] = "/tmp/locktest.XXXXXX";
 151         int fd = mkstemp(tpl);
 152         if (fd < 0) {
 153                 strcpy(tpl, "conftest.dat");
 154                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 155         }
 156
 157         lock.l_type = F_WRLCK;
 158         lock.l_whence = SEEK_SET;
 159         lock.l_start = 0;
 160         lock.l_len = 1;
 161         lock.l_pid = 0;
 162         fcntl(fd,F_SETLK,&lock);
 163         if (fork() == 0) {
 164                 lock.l_start = 1;
 165                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 166         }
 167         wait(&status);
 168         unlink(tpl);
 169         exit(WEXITSTATUS(status));
 170 }
 171 ],
 172 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
 173 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 174    AC_SYS_LARGEFILE
 175 fi
 176
 177 ipv6type=unknown
 178 ipv6lib=none
 179 ipv6trylibc=yes
 180
 181 AC_ARG_ENABLE(ipv6,
 182         AC_HELP_STRING([--disable-ipv6], [don't even try to use IPv6]))
 183
 184 if test "x$enable_ipv6" != xno
 185 then
 186         AC_MSG_CHECKING([ipv6 stack type])
 187         for i in inria kame linux-glibc linux-inet6 toshiba v6d zeta; do
 188                 case $i in
 189                 inria)
 190                         # http://www.kame.net/
 191                         AC_EGREP_CPP(yes, [
 192 #include <netinet/in.h>
 193 #ifdef IPV6_INRIA_VERSION
 194 yes
 195 #endif],
 196                                 [ipv6type=$i;
 197                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 198                                 ])
 199                         ;;
 200                 kame)
 201                         # http://www.kame.net/
 202                         AC_EGREP_CPP(yes, [
 203 #include <netinet/in.h>
 204 #ifdef __KAME__
 205 yes
 206 #endif],
 207                                 [ipv6type=$i;
 208                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 209                         ;;
 210                 linux-glibc)
 211                         # http://www.v6.linux.or.jp/
 212                         AC_EGREP_CPP(yes, [
 213 #include <features.h>
 214 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 215 yes
 216 #endif],
 217                                 [ipv6type=$i;
 218 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 219                         ;;
 220                 linux-inet6)
 221                         # http://www.v6.linux.or.jp/
 222                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 223                                 ipv6type=$i
 224                                 ipv6lib=inet6
 225                                 ipv6libdir=/usr/inet6/lib
 226                                 ipv6trylibc=yes;
 227                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 228                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 229                         fi
 230                         ;;
 231                 toshiba)
 232                         AC_EGREP_CPP(yes, [
 233 #include <sys/param.h>
 234 #ifdef _TOSHIBA_INET6
 235 yes
 236 #endif],
 237                                 [ipv6type=$i;
 238                                 ipv6lib=inet6;
 239                                 ipv6libdir=/usr/local/v6/lib;
 240                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 241                         ;;
 242                 v6d)
 243                         AC_EGREP_CPP(yes, [
 244 #include </usr/local/v6/include/sys/v6config.h>
 245 #ifdef __V6D__
 246 yes
 247 #endif],
 248                                 [ipv6type=$i;
 249                                 ipv6lib=v6;
 250                                 ipv6libdir=/usr/local/v6/lib;
 251                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 252                         ;;
 253                 zeta)
 254                         AC_EGREP_CPP(yes, [
 255 #include <sys/param.h>
 256 #ifdef _ZETA_MINAMI_INET6
 257 yes
 258 #endif],
 259                                 [ipv6type=$i;
 260                                 ipv6lib=inet6;
 261                                 ipv6libdir=/usr/local/v6/lib;
 262                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 263                         ;;
 264                 esac
 265                 if test "$ipv6type" != "unknown"; then
 266                         break
 267                 fi
 268         done
 269         AC_MSG_RESULT($ipv6type)
 270
 271         AC_SEARCH_LIBS(getaddrinfo, inet6)
 272 fi
 273
 274 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 275 case $host_os in
 276         *cygwin* ) AC_MSG_RESULT(yes)
 277                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 278                             [Define if sockets need to be shutdown])
 279                    ;;
 280                * ) AC_MSG_RESULT(no);;
 281 esac
 282
 283 AC_C_BIGENDIAN
 284 AC_HEADER_DIRENT
 285 AC_HEADER_TIME
 286 AC_HEADER_SYS_WAIT
 287 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 288     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 289     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 290     sys/un.h glob.h mcheck.h arpa/inet.h arpa/nameser.h \
 291     netdb.h malloc.h float.h)
 292 AC_HEADER_MAJOR
 293
 294 AC_CHECK_SIZEOF(int)
 295 AC_CHECK_SIZEOF(long)
 296 AC_CHECK_SIZEOF(short)
 297
 298 AC_C_INLINE
 299
 300 AC_TYPE_SIGNAL
 301 AC_TYPE_UID_T
 302 AC_TYPE_MODE_T
 303 AC_TYPE_OFF_T
 304 AC_TYPE_SIZE_T
 305 AC_TYPE_PID_T
 306 AC_TYPE_GETGROUPS
 307 AC_CHECK_MEMBERS([struct stat.st_rdev])
 308
 309 AC_CHECK_TYPE([ino_t], [unsigned])
 310 TYPE_SOCKLEN_T
 311
 312 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 313     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
 314         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
 315 if test x"$rsync_cv_errno" = x"yes"; then
 316    AC_DEFINE(HAVE_ERRNO_DECL, 1, [ ])
 317 fi
 318
 319 # The following test taken from the cvs sources
 320 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 321 # These need checks to be before checks for any other functions that
 322 #    might be in the same libraries.
 323 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 324 # libsocket.so which has a bad implementation of gethostbyname (it
 325 # only looks in /etc/hosts), so we only look for -lsocket if we need
 326 # it.
 327 AC_CHECK_FUNCS(connect)
 328 if test x"$ac_cv_func_connect" = x"no"; then
 329     case "$LIBS" in
 330     *-lnsl*) ;;
 331     *) AC_CHECK_LIB(nsl_s, printf) ;;
 332     esac
 333     case "$LIBS" in
 334     *-lnsl*) ;;
 335     *) AC_CHECK_LIB(nsl, printf) ;;
 336     esac
 337     case "$LIBS" in
 338     *-lsocket*) ;;
 339     *) AC_CHECK_LIB(socket, connect) ;;
 340     esac
 341     case "$LIBS" in
 342     *-linet*) ;;
 343     *) AC_CHECK_LIB(inet, connect) ;;
 344     esac
 345     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 346     dnl has been cached.
 347     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 348        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 349         # ac_cv_func_connect=yes
 350         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 351         AC_DEFINE(HAVE_CONNECT, 1, [ ])
 352     fi
 353 fi
 354
 355 AC_CHECK_LIB(resolv, inet_ntop)
 356
 357 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 358
 359 AC_CHECK_FUNCS(inet_ntop, , [AC_LIBOBJ(lib/inet_ntop)])
 360 AC_CHECK_FUNCS(inet_pton, , [AC_LIBOBJ(lib/inet_pton)])
 361
 362 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 363 #   builtin getaddrinfo if one of the defines don't exist
 364 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 365                rsync_cv_HAVE_GETADDR_DEFINES,[
 366                         AC_EGREP_CPP(yes, [
 367                         #include <sys/types.h>
 368                         #include <sys/socket.h>
 369                         #include <netdb.h>
 370                         #ifdef AI_PASSIVE
 371                         yes
 372                         #endif],
 373                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 374                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 375 if test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes"; then
 376         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 377         # something else so we must include <netdb.h> to get the
 378         # redefinition.
 379         AC_CHECK_FUNCS(getaddrinfo, ,
 380                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 381                 AC_TRY_LINK([#include <sys/types.h>
 382                 #include <sys/socket.h>
 383                 #include <netdb.h>],[getaddrinfo(NULL, NULL, NULL, NULL);],
 384                         [AC_MSG_RESULT([yes])
 385                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 386                                 [Define if you have the `getaddrinfo' function.])],
 387                         [AC_MSG_RESULT([no])
 388                         AC_LIBOBJ(lib/getaddrinfo)])])
 389         AC_CHECK_FUNCS(getnameinfo, , [AC_LIBOBJ(lib/getnameinfo)])
 390 else
 391         AC_LIBOBJ(lib/getaddrinfo)
 392         AC_LIBOBJ(lib/getnameinfo)
 393 fi
 394
 395 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 396                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 397                 [],
 398                 [
 399 #include <sys/types.h>
 400 #include <sys/socket.h>
 401 ])
 402
 403 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 404                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 405                 [],
 406                 [
 407 #include <sys/types.h>
 408 #include <sys/socket.h>
 409 #include <netinet/in.h>
 410 ])
 411
 412 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 413                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 414                 [],
 415                 [
 416 #include <sys/types.h>
 417 #include <sys/socket.h>
 418 #include <netinet/in.h>
 419 ])
 420
 421 AC_MSG_CHECKING(struct sockaddr_storage)
 422 AC_TRY_COMPILE([#include <sys/types.h>
 423 #include <sys/socket.h>],
 424 [struct sockaddr_storage x;],
 425         AC_MSG_RESULT(yes)
 426         AC_DEFINE(HAVE_SOCKADDR_STORAGE, 1,
 427                 [Define if you have strct sockaddr_storage.] ),
 428         AC_MSG_RESULT(no))
 429
 430 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 431                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 432                 [],
 433                 [
 434 #include <sys/types.h>
 435 #include <sys/socket.h>
 436 #include <netinet/in.h>
 437 ])
 438
 439 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 440 #
 441 AC_CHECK_FUNCS(strcasecmp)
 442 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 443     AC_CHECK_LIB(resolv, strcasecmp)
 444 fi
 445
 446 dnl At the moment we don't test for a broken memcmp(), because all we
 447 dnl need to do is test for equality, not comparison, and it seems that
 448 dnl every platform has a memcmp that can do at least that.
 449 dnl AC_FUNC_MEMCMP
 450
 451 AC_FUNC_UTIME_NULL
 452 AC_FUNC_ALLOCA
 453 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup strerror chown chmod mknod mkfifo \
 454     fchmod fstat strchr readlink link utime utimes strftime mtrace ftruncate \
 455     memmove lchown vsnprintf snprintf asprintf setsid glob strpbrk setmode \
 456     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 457     open64 mkstemp64)
 458
 459 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 460 if test $ac_cv_func_getpgrp = yes; then
 461     AC_FUNC_GETPGRP
 462 fi
 463
 464 # Determine whether chown follows symlinks (it should).
 465 AC_CACHE_CHECK([whether chown() dereferences symlinks],rsync_cv_chown_follows_symlink,[
 466   AC_TRY_RUN([
 467 #if HAVE_UNISTD_H
 468 # include <unistd.h>
 469 #endif
 470 #include <stdlib.h>
 471 #include <errno.h>
 472     main() {
 473         char const *dangling_symlink = "conftest.dangle";
 474         unlink(dangling_symlink);
 475         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 476         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) exit(0);
 477         exit(1);
 478     }],
 479   rsync_cv_chown_follows_symlink=yes,rsync_cv_chown_follows_symlink=no,rsync_cv_chown_follows_symlink=yes)])
 480 if test $rsync_cv_chown_follows_symlink = no; then
 481   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define if chown modifies symlinks.])
 482 fi
 483
 484 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 485 AC_TRY_RUN([
 486 #include <sys/types.h>
 487 #include <sys/socket.h>
 488
 489 main() {
 490        int fd[2];
 491        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 492 }],
 493 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
 494 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 495     AC_DEFINE(HAVE_SOCKETPAIR, 1, [ ])
 496 fi
 497
 498 if test x"$with_included_popt" != x"yes"
 499 then
 500     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 501 fi
 502
 503 AC_MSG_CHECKING([whether to use included libpopt])
 504 if test x"$with_included_popt" = x"yes"
 505 then
 506     AC_MSG_RESULT($srcdir/popt)
 507     BUILD_POPT='$(popt_OBJS)'
 508     CFLAGS="$CFLAGS -I$srcdir/popt"
 509     if test x"$ALLOCA" != x
 510     then
 511         # this can be removed when/if we add an included alloca.c;
 512         #  see autoconf documentation on AC_FUNC_ALLOCA
 513         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 514     fi
 515 else
 516     AC_MSG_RESULT(no)
 517 fi
 518
 519 AC_CACHE_CHECK([for long long],rsync_cv_HAVE_LONGLONG,[
 520 AC_TRY_RUN([#include <stdio.h>
 521 main() { long long x = 1000000; x *= x; exit(((x/1000000) == 1000000)? 0: 1); }],
 522 rsync_cv_HAVE_LONGLONG=yes,rsync_cv_HAVE_LONGLONG=no,rsync_cv_HAVE_LONGLONG=cross)])
 523 if test x"$rsync_cv_HAVE_LONGLONG" = x"yes"; then
 524     AC_DEFINE(HAVE_LONGLONG, 1, [ ])
 525 fi
 526
 527 AC_CACHE_CHECK([for off64_t],rsync_cv_HAVE_OFF64_T,[
 528 AC_TRY_RUN([#include <stdio.h>
 529 #include <sys/stat.h>
 530 main() { struct stat64 st; off64_t s; if (sizeof(off_t) == sizeof(off64_t)) exit(1); exit((lstat64("/dev/null", &st)==0)?0:1); }],
 531 rsync_cv_HAVE_OFF64_T=yes,rsync_cv_HAVE_OFF64_T=no,rsync_cv_HAVE_OFF64_T=cross)])
 532 if test x"$rsync_cv_HAVE_OFF64_T" = x"yes"; then
 533     AC_DEFINE(HAVE_OFF64_T, 1, [ ])
 534 fi
 535
 536 AC_CACHE_CHECK([for short ino_t],rsync_cv_HAVE_SHORT_INO_T,[
 537 AC_TRY_RUN([#include <stdio.h>
 538 #include <sys/types.h>
 539 #include <sys/stat.h>
 540 main() { if (sizeof(ino_t) < sizeof(unsigned int)) return 0; return 1; }],
 541 rsync_cv_HAVE_SHORT_INO_T=yes,rsync_cv_HAVE_SHORT_INO_T=no,rsync_cv_HAVE_SHORT_INO_T=cross)])
 542 if test x"$rsync_cv_HAVE_SHORT_INO_T" = x"yes"; then
 543     AC_DEFINE(HAVE_SHORT_INO_T, 1, [ ])
 544 fi
 545
 546 AC_CACHE_CHECK([for unsigned char],rsync_cv_HAVE_UNSIGNED_CHAR,[
 547 AC_TRY_RUN([#include <stdio.h>
 548 main() { char c; c=250; exit((c > 0)?0:1); }],
 549 rsync_cv_HAVE_UNSIGNED_CHAR=yes,rsync_cv_HAVE_UNSIGNED_CHAR=no,rsync_cv_HAVE_UNSIGNED_CHAR=cross)])
 550 if test x"$rsync_cv_HAVE_UNSIGNED_CHAR" = x"yes"; then
 551     AC_DEFINE(HAVE_UNSIGNED_CHAR, 1, [ ])
 552 fi
 553
 554 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 555 AC_TRY_RUN([#include <sys/types.h>
 556 #include <dirent.h>
 557 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 558 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 559 di->d_name[0] == 0) exit(0); exit(1);} ],
 560 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 561 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 562     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [ ])
 563 fi
 564
 565 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[
 566 AC_TRY_COMPILE([#include <sys/types.h>
 567 #include <utime.h>],
 568 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 569 rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no,rsync_cv_HAVE_UTIMBUF=cross)])
 570 if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then
 571     AC_DEFINE(HAVE_UTIMBUF, 1, [ ])
 572 fi
 573
 574 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 575 AC_TRY_RUN([
 576 #include <sys/time.h>
 577 #include <unistd.h>
 578 main() { struct timeval tv; exit(gettimeofday(&tv, NULL));}],
 579            rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no,rsync_cv_HAVE_GETTIMEOFDAY_TZ=cross)])
 580 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
 581     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [ ])
 582 fi
 583
 584 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 585 AC_TRY_RUN([
 586 #include <sys/types.h>
 587 #include <stdarg.h>
 588 void foo(const char *format, ...) {
 589        va_list ap;
 590        int len;
 591        char buf[5];
 592
 593        va_start(ap, format);
 594        len = vsnprintf(0, 0, format, ap);
 595        va_end(ap);
 596        if (len != 5) exit(1);
 597
 598        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 599
 600        exit(0);
 601 }
 602 main() { foo("hello"); }
 603 ],
 604 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
 605 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 606     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [ ])
 607 fi
 608
 609
 610 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 611 AC_TRY_RUN([#include <stdlib.h>
 612 #include <sys/types.h>
 613 #include <sys/stat.h>
 614 #include <unistd.h>
 615 main() {
 616   struct stat st;
 617   char tpl[20]="/tmp/test.XXXXXX";
 618   int fd = mkstemp(tpl);
 619   if (fd == -1) exit(1);
 620   unlink(tpl);
 621   if (fstat(fd, &st) != 0) exit(1);
 622   if ((st.st_mode & 0777) != 0600) exit(1);
 623   exit(0);
 624 }],
 625 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
 626 rsync_cv_HAVE_SECURE_MKSTEMP=no,
 627 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
 628 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 629     AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [ ])
 630 fi
 631
 632
 633 AC_CACHE_CHECK([for broken inet_ntoa],rsync_cv_REPLACE_INET_NTOA,[
 634 AC_TRY_RUN([
 635 #include <stdio.h>
 636 #include <sys/types.h>
 637 #include <netinet/in.h>
 638 #include <arpa/inet.h>
 639 main() { struct in_addr ip; ip.s_addr = 0x12345678;
 640 if (strcmp(inet_ntoa(ip),"18.52.86.120") &&
 641     strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(1); }
 642 exit(0);}],
 643            rsync_cv_REPLACE_INET_NTOA=no,rsync_cv_REPLACE_INET_NTOA=yes,rsync_cv_REPLACE_INET_NTOA=cross)])
 644 if test x"$rsync_cv_REPLACE_INET_NTOA" = x"yes"; then
 645     AC_DEFINE(REPLACE_INET_NTOA, 1, [ ])
 646 fi
 647
 648
 649 AC_CACHE_CHECK([for broken inet_aton],rsync_cv_REPLACE_INET_ATON,[
 650 AC_TRY_RUN([
 651 #include <stdio.h>
 652 #include <sys/types.h>
 653 #include <netinet/in.h>
 654 #include <arpa/inet.h>
 655 main() { struct in_addr ip;
 656 if (inet_aton("example", &ip) == 0) exit(0); exit(1);}],
 657            rsync_cv_REPLACE_INET_ATON=no,rsync_cv_REPLACE_INET_ATON=yes,rsync_cv_REPLACE_INET_ATON=cross)])
 658 if test x"$rsync_cv_REPLACE_INET_ATON" = x"yes"; then
 659     AC_DEFINE(REPLACE_INET_ATON, 1, [ ])
 660 fi
 661
 662 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
 663 AC_TRY_RUN([
 664 #include <stdio.h>
 665 #include <sys/stat.h>
 666 #include <errno.h>
 667 main() { int rc, ec; char *fn = "fifo-test";
 668 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
 669 if (rc) {printf("%d %d\n",rc,ec); return ec;}
 670 return 0;}],
 671            rsync_cv_MKNOD_CREATES_FIFOS=yes,rsync_cv_MKNOD_CREATES_FIFOS=no,rsync_cv_MKNOD_CREATES_FIFOS=cross)])
 672 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
 673     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
 674 fi
 675
 676 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
 677 AC_TRY_RUN([
 678 #include <stdio.h>
 679 #include <sys/stat.h>
 680 #include <errno.h>
 681 main() { int rc, ec; char *fn = "sock-test";
 682 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
 683 if (rc) {printf("%d %d\n",rc,ec); return ec;}
 684 return 0;}],
 685            rsync_cv_MKNOD_CREATES_SOCKETS=yes,rsync_cv_MKNOD_CREATES_SOCKETS=no,rsync_cv_MKNOD_CREATES_SOCKETS=cross)])
 686 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
 687     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
 688 fi
 689
 690 #
 691 # The following test was mostly taken from the tcl/tk plus patches
 692 #
 693 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 694 rm -rf conftest*
 695 cat > conftest.$ac_ext <<EOF
 696 int main() { return 0; }
 697 EOF
 698 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 699 if test -f conftest..o; then
 700     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 701 else
 702     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 703 fi
 704 rm -rf conftest*
 705 ])
 706 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 707     OBJ_SAVE="#"
 708     OBJ_RESTORE="#"
 709     CC_SHOBJ_FLAG='-o $@'
 710 else
 711     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 712     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 713     CC_SHOBJ_FLAG=""
 714 fi
 715
 716 AC_SUBST(OBJ_SAVE)
 717 AC_SUBST(OBJ_RESTORE)
 718 AC_SUBST(CC_SHOBJ_FLAG)
 719 AC_SUBST(BUILD_POPT)
 720
 721 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
 722 AC_OUTPUT
 723
 724 if test x"$with_rsh" = x; then
 725         if test x"$HAVE_REMSH" = x1; then
 726                 rmsh1='remsh:'
 727                 rmsh2='=remsh'
 728         else
 729                 rmsh1='rsh:  '
 730                 rmsh2='=rsh  '
 731         fi
 732         AC_MSG_RESULT()
 733         AC_MSG_RESULT([    **********************************************************************])
 734         AC_MSG_RESULT([    *   As of v2.6.0, the default remote shell is ssh instead of rsh!!   *])
 735         AC_MSG_RESULT([    *   To use previous default of $rmsh1 ./configure --with-rsh$rmsh2   *])
 736         AC_MSG_RESULT([    **********************************************************************])
 737 fi
 738
 739 AC_MSG_RESULT()
 740 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
 741 AC_MSG_RESULT()