support/patch-update

   1 #!/usr/bin/perl -w
   2 # This script is used to turn one or more of the "patch/*" branches
   3 # into one or more diffs in the "patches" directory.  Pass the option
   4 # --gen if you want generated files in the diffs.  Pass the name of
   5 # one or more diffs if you want to just update a subset of all the
   6 # diffs.
   7
   8 use strict;
   9 use Getopt::Long;
  10
  11 my $patches_dir = 'patches';
  12 my $tmp_dir = "patches.$$";
  13
  14 &Getopt::Long::Configure('bundling');
  15 &usage if !&GetOptions(
  16     'skip-check' => \( my $skip_branch_check ),
  17     'gen:s' => \( my $incl_generated_files ),
  18     'help|h' => \( my $help_opt ),
  19 );
  20 &usage if $help_opt;
  21
  22 if (defined $incl_generated_files) {
  23     $patches_dir = $incl_generated_files if $incl_generated_files ne '';
  24     $incl_generated_files = 1;
  25 }
  26
  27 die "No '$patches_dir' directory was found.\n" unless -d $patches_dir;
  28 die "No '.git' directory present in the current dir.\n" unless -d '.git';
  29
  30 open(IN, '-|', 'git status') or die $!;
  31 my $status = join('', <IN>);
  32 close IN;
  33 unless ($skip_branch_check) {
  34     die "The checkout is not clean:\n", $status unless $status =~ /\nnothing to commit \(working directory clean\)/;
  35 }
  36 my($starting_branch) = $status =~ /^# On branch (.+)\n/;
  37
  38 my @extra_files;
  39 open(IN, '<', 'Makefile.in') or die "Couldn't open Makefile.in: $!\n";
  40 while (<IN>) {
  41     if (s/^GENFILES=//) {
  42         while (s/\\$//) {
  43             $_ .= <IN>;
  44         }
  45         @extra_files = split(' ', $_);
  46         last;
  47     }
  48 }
  49 close IN;
  50
  51 if ($incl_generated_files) {
  52     die "'$tmp_dir' must not exist in the current directory.\n" if -e $tmp_dir;
  53     mkdir($tmp_dir, 0700) or die "Unable to mkdir($tmp_dir): $!\n";
  54     system "./config.status Makefile && make gen && rsync -a @extra_files $tmp_dir/master/" and exit 1;
  55 }
  56 my $last_touch = time;
  57
  58 my(%patches, %local_patch);
  59
  60 # Start by finding all patches so that we can load all possible parents.
  61 open(PIPE, '-|', 'git', 'branch', '-a') or die $!;
  62 while (<PIPE>) {
  63     if (m# origin/patch/(.*)#) {
  64         $patches{$1} = 1;
  65     } elsif (m# patch/(.*)#) {
  66         $patches{$1} = $local_patch{$1} = 1;
  67     }
  68 }
  69 close PIPE;
  70
  71 my @patches = sort keys %patches;
  72
  73 my(%parent, %description);
  74 foreach my $patch (@patches) {
  75     my $branch = ($local_patch{$patch} ? '' : 'origin/') . "patch/$patch";
  76     my $desc = '';
  77     open(PIPE, '-|', 'git', 'diff', '-U1000', "master...$branch", '--', "PATCH.$patch") or die $!;
  78     while (<PIPE>) {
  79         last if /^@@ /;
  80     }
  81     while (<PIPE>) {
  82         next unless s/^[ +]//;
  83         if (m#patch -p1 <patches/(\S+)\.diff# && $1 ne $patch) {
  84             $parent{$patch} = $1;
  85         }
  86         $desc .= $_;
  87     }
  88     $description{$patch} = $desc;
  89 }
  90
  91 if (@ARGV) {
  92     # Limit the list of patches to actually process based on @ARGV.
  93     @patches = ( );
  94     foreach (@ARGV) {
  95         s{^(patches|patch|origin/patch)/} {};
  96         s{\.diff$} {};
  97         push(@patches, $_);
  98     }
  99 }
 100
 101 my %completed;
 102 foreach my $patch (@patches) {
 103     next if $completed{$patch}++;
 104     update_patch($patch);
 105 }
 106
 107 if ($incl_generated_files) {
 108     system "rm -rf $tmp_dir";
 109 }
 110
 111 sleep 1 if $last_touch == time;
 112 system "git checkout $starting_branch" and exit 1;
 113
 114 exit;
 115
 116
 117 sub update_patch
 118 {
 119     my($patch) = @_;
 120
 121     my $parent = $parent{$patch};
 122     if (defined $parent) {
 123         unless ($completed{$parent}++) {
 124             update_patch($parent);
 125         }
 126         $parent = "patch/$parent";
 127     } else {
 128         $parent = 'master';
 129     }
 130
 131     print "======== $patch ========\n";
 132
 133     sleep 1 if $incl_generated_files && $last_touch == time;
 134     if ($local_patch{$patch}) {
 135         system "git checkout patch/$patch" and exit 1;
 136     } else {
 137         system "git checkout --track -b patch/$patch origin/patch/$patch" and exit 1;
 138     }
 139
 140     open(OUT, '>', "$patches_dir/$patch.diff") or die $!;
 141     print OUT $description{$patch}, "\n";
 142
 143     if (system("git merge $parent") != 0) {
 144         print qq|"git merge $parent" incomplete -- please fix.\n|;
 145         $ENV{PS1} = "[$parent] patch/$patch: ";
 146         system $ENV{SHELL} and exit 1;
 147     }
 148
 149     if ($incl_generated_files) {
 150         system "./config.status Makefile && make gen && rsync -a @extra_files $tmp_dir/$patch/" and exit 1;
 151     }
 152     $last_touch = time;
 153
 154     open(PIPE, '-|', 'git', 'diff', $parent) or die $!;
 155     DIFF: while (<PIPE>) {
 156         while (m{^diff --git a/PATCH}) {
 157             while (<PIPE>) {
 158                 last if m{^diff --git a/};
 159             }
 160             last DIFF if !defined $_;
 161         }
 162         next if /^index /;
 163         print OUT $_;
 164     }
 165     close PIPE;
 166
 167     if ($incl_generated_files) {
 168         $parent =~ s#.*/##;
 169         open(PIPE, '-|', 'diff', '-up', "$tmp_dir/$parent", "$tmp_dir/$patch") or die $!;
 170         while (<PIPE>) {
 171             s#^(diff -up) $tmp_dir/[^/]+/(.*?) $tmp_dir/[^/]+/(.*)#$1 a/$2 b/$3#o;
 172             s#^\Q---\E $tmp_dir/[^/]+/([^\t]+)\t.*#--- a/$1#o;
 173             s#^\Q+++\E $tmp_dir/[^/]+/([^\t]+)\t.*#+++ b/$1#o;
 174             print OUT $_;
 175         }
 176         close PIPE;
 177     }
 178
 179     close OUT;
 180 }
 181
 182 exit;
 183
 184 sub usage
 185 {
 186     die <<EOT;
 187 Usage: patch-update [OPTIONS]
 188
 189 --gen[=DIR]   Include generated files.  Optional dest DIR overrides "patches".
 190 --skip-check  Skip the check that ensures starting with a clean branch.
 191 EOT
 192 }