Fix a potential crash when trying to find a better block match.
[rsync/rsync.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2
3 AC_INIT()
4 AC_CONFIG_SRCDIR([byteorder.h])
5 AC_CONFIG_HEADER(config.h)
6 AC_PREREQ(2.59)
7
8 RSYNC_VERSION=3.1.0dev
9 AC_SUBST(RSYNC_VERSION)
10 AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION])
11
12 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
13
14 LDFLAGS=${LDFLAGS-""}
15
16 AC_CANONICAL_HOST
17
18 # We must decide this before testing the compiler.
19
20 # Please allow this to default to yes, so that your users have more
21 # chance of getting a useful stack trace if problems occur.
22
23 AC_MSG_CHECKING([whether to include debugging symbols])
24 AC_ARG_ENABLE(debug,
25         AC_HELP_STRING([--disable-debug],
26                 [disable debugging symbols and features]))
27
28 if test x"$enable_debug" = x"no"; then
29     AC_MSG_RESULT(no)
30     ac_cv_prog_cc_g=no
31 else
32     AC_MSG_RESULT([yes])
33     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
34     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
35 fi
36
37 dnl Checks for programs.
38 AC_PROG_CC
39 AC_PROG_CPP
40 AC_PROG_EGREP
41 AC_PROG_INSTALL
42 AC_PROG_CC_STDC
43 AC_SUBST(SHELL)
44
45 AC_DEFINE([_GNU_SOURCE], 1,
46           [Define _GNU_SOURCE so that we get all necessary prototypes])
47
48 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
49         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
50 fi
51
52 AC_ARG_ENABLE(profile,
53         AC_HELP_STRING([--enable-profile],
54                 [turn on CPU profiling]))
55 if test x"$enable_profile" = x"yes"; then
56         CFLAGS="$CFLAGS -pg"
57 fi
58
59
60 # Specifically, this turns on panic_action handling.
61 AC_ARG_ENABLE(maintainer-mode,
62         AC_HELP_STRING([--enable-maintainer-mode],
63                 [turn on extra debug features]))
64 if test x"$enable_maintainer_mode" = x"yes"; then
65         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
66 fi
67
68
69 # This is needed for our included version of popt.  Kind of silly, but
70 # I don't want our version too far out of sync.
71 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
72
73 # If GCC, turn on warnings.
74 if test x"$GCC" = x"yes"; then
75         CFLAGS="$CFLAGS -Wall -W"
76 fi
77
78 AC_ARG_WITH(included-popt,
79         AC_HELP_STRING([--with-included-popt], [use bundled popt library, not from system]))
80
81 AC_ARG_WITH(protected-args,
82         AC_HELP_STRING([--with-protected-args], [make --protected-args option the default]))
83 if test x"$with_protected_args" = x"yes"; then
84         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
85 fi
86
87 AC_ARG_WITH(rsync-path,
88         AC_HELP_STRING([--with-rsync-path=PATH], [set default --rsync-path to PATH (default: rsync)]),
89         [ RSYNC_PATH="$with_rsync_path" ],
90         [ RSYNC_PATH="rsync" ])
91
92 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
93
94 AC_ARG_WITH(rsyncd-conf,
95         AC_HELP_STRING([--with-rsyncd-conf=PATH], [set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
96         [ if test ! -z "$with_rsyncd_conf" ; then
97                 case $with_rsyncd_conf in
98                         yes|no)
99                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
100                                 ;;
101                         /*)
102                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
103                                 ;;
104                         *)
105                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
106                                 ;;
107                 esac
108         else
109                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
110         fi ],
111         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
112
113 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
114
115 AC_ARG_WITH(rsh,
116         AC_HELP_STRING([--with-rsh=CMD], [set remote shell command to CMD (default: ssh)]))
117
118 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
119 if test x$HAVE_REMSH = x1; then
120         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
121 fi
122
123 if test x"$with_rsh" != x; then
124         RSYNC_RSH="$with_rsh"
125 else
126         RSYNC_RSH="ssh"
127 fi
128 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
129
130 AC_CHECK_PROG(HAVE_YODL2MAN, yodl2man, 1, 0)
131 if test x$HAVE_YODL2MAN = x1; then
132     MAKE_MAN=man
133 fi
134
135 AC_ARG_WITH(nobody-group,
136     AC_HELP_STRING([--with-nobody-group=GROUP],
137                    [set the default unprivileged group (default nobody or nogroup)]),
138     [ NOBODY_GROUP="$with_nobody_group" ])
139
140 if test x"$with_nobody_group" = x; then
141     AC_MSG_CHECKING([the group for user "nobody"])
142     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
143         NOBODY_GROUP=nobody
144     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
145         NOBODY_GROUP=nogroup
146     else
147         NOBODY_GROUP=nobody # test for others?
148     fi
149     AC_MSG_RESULT($NOBODY_GROUP)
150 fi
151
152 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
153 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
154
155 # arrgh. libc in some old debian version screwed up the largefile
156 # stuff, getting byte range locking wrong
157 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
158 AC_TRY_RUN([
159 #define _FILE_OFFSET_BITS 64
160 #include <stdio.h>
161 #include <fcntl.h>
162 #include <sys/types.h>
163 #include <sys/wait.h>
164
165 int main(void)
166 {
167         struct flock lock;
168         int status;
169         char tpl[32] = "/tmp/locktest.XXXXXX";
170         int fd = mkstemp(tpl);
171         if (fd < 0) {
172                 strcpy(tpl, "conftest.dat");
173                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
174         }
175
176         lock.l_type = F_WRLCK;
177         lock.l_whence = SEEK_SET;
178         lock.l_start = 0;
179         lock.l_len = 1;
180         lock.l_pid = 0;
181         fcntl(fd,F_SETLK,&lock);
182         if (fork() == 0) {
183                 lock.l_start = 1;
184                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
185         }
186         wait(&status);
187         unlink(tpl);
188         exit(WEXITSTATUS(status));
189 }
190 ],
191 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
192 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
193    AC_SYS_LARGEFILE
194 fi
195
196 ipv6type=unknown
197 ipv6lib=none
198 ipv6trylibc=yes
199
200 AC_ARG_ENABLE(ipv6,
201         AC_HELP_STRING([--disable-ipv6],
202                 [do not even try to use IPv6]))
203 if test x"$enable_ipv6" != x"no"; then
204         AC_MSG_CHECKING([ipv6 stack type])
205         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
206                 case $i in
207                 inria)
208                         # http://www.kame.net/
209                         AC_EGREP_CPP(yes, [
210 #include <netinet/in.h>
211 #ifdef IPV6_INRIA_VERSION
212 yes
213 #endif],
214                                 [ipv6type=$i;
215                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
216                                 ])
217                         ;;
218                 kame)
219                         # http://www.kame.net/
220                         AC_EGREP_CPP(yes, [
221 #include <netinet/in.h>
222 #ifdef __KAME__
223 yes
224 #endif],
225                                 [ipv6type=$i;
226                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
227                         ;;
228                 linux-glibc)
229                         # http://www.v6.linux.or.jp/
230                         AC_EGREP_CPP(yes, [
231 #include <features.h>
232 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
233 yes
234 #endif],
235                                 [ipv6type=$i;
236 AC_DEFINE(INET6, 1, [true if you have IPv6])])
237                         ;;
238                 linux-inet6)
239                         # http://www.v6.linux.or.jp/
240                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
241                                 ipv6type=$i
242                                 ipv6lib=inet6
243                                 ipv6libdir=/usr/inet6/lib
244                                 ipv6trylibc=yes;
245                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
246                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
247                         fi
248                         ;;
249                 solaris)
250                         # http://www.sun.com
251                         AC_EGREP_CPP(yes, [
252 #include <netinet/ip6.h>
253 #ifdef __sun
254 yes
255 #endif],
256                                 [ipv6type=$i;
257                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
258                         ;;
259                 toshiba)
260                         AC_EGREP_CPP(yes, [
261 #include <sys/param.h>
262 #ifdef _TOSHIBA_INET6
263 yes
264 #endif],
265                                 [ipv6type=$i;
266                                 ipv6lib=inet6;
267                                 ipv6libdir=/usr/local/v6/lib;
268                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
269                         ;;
270                 v6d)
271                         AC_EGREP_CPP(yes, [
272 #include </usr/local/v6/include/sys/v6config.h>
273 #ifdef __V6D__
274 yes
275 #endif],
276                                 [ipv6type=$i;
277                                 ipv6lib=v6;
278                                 ipv6libdir=/usr/local/v6/lib;
279                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
280                         ;;
281                 zeta)
282                         AC_EGREP_CPP(yes, [
283 #include <sys/param.h>
284 #ifdef _ZETA_MINAMI_INET6
285 yes
286 #endif],
287                                 [ipv6type=$i;
288                                 ipv6lib=inet6;
289                                 ipv6libdir=/usr/local/v6/lib;
290                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
291                         ;;
292                 cygwin)
293                         AC_EGREP_CPP(yes, [
294 #include <netinet/in.h>
295 #ifdef _CYGWIN_IN6_H
296 yes
297 #endif],
298                                 [ipv6type=$i;
299                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
300                         ;;
301                 esac
302                 if test "$ipv6type" != "unknown"; then
303                         break
304                 fi
305         done
306         AC_MSG_RESULT($ipv6type)
307
308         AC_SEARCH_LIBS(getaddrinfo, inet6)
309 fi
310
311 dnl Do you want to disable use of locale functions
312 AC_ARG_ENABLE([locale],
313         AC_HELP_STRING([--disable-locale],
314                 [disable locale features]))
315 AH_TEMPLATE([CONFIG_LOCALE],
316 [Undefine if you do not want locale features.  By default this is defined.])
317 if test x"$enable_locale" != x"no"; then
318         AC_DEFINE(CONFIG_LOCALE)
319 fi
320
321 AC_MSG_CHECKING([whether to call shutdown on all sockets])
322 case $host_os in
323         *cygwin* ) AC_MSG_RESULT(yes)
324                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
325                             [Define to 1 if sockets need to be shutdown])
326                    ;;
327                * ) AC_MSG_RESULT(no);;
328 esac
329
330 AC_C_BIGENDIAN
331 AC_HEADER_DIRENT
332 AC_HEADER_TIME
333 AC_HEADER_SYS_WAIT
334 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
335     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
336     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
337     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
338     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
339     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
340     popt.h popt/popt.h)
341 AC_HEADER_MAJOR
342
343 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
344 AC_TRY_RUN([
345 #include <sys/types.h>
346 #ifdef MAJOR_IN_MKDEV
347 #include <sys/mkdev.h>
348 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
349 #  define makedev mkdev
350 # endif
351 #elif defined MAJOR_IN_SYSMACROS
352 #include <sys/sysmacros.h>
353 #endif
354
355 int main(void)
356 {
357         dev_t dev = makedev(0, 5, 7);
358         if (major(dev) != 5 || minor(dev) != 7)
359                 exit(1);
360         return 0;
361 }
362 ],
363 rsync_cv_MAKEDEV_TAKES_3_ARGS=yes,rsync_cv_MAKEDEV_TAKES_3_ARGS=no,rsync_cv_MAKEDEV_TAKES_3_ARGS=no)])
364 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
365    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
366 fi
367
368 AC_CHECK_SIZEOF(int)
369 AC_CHECK_SIZEOF(long)
370 AC_CHECK_SIZEOF(long long)
371 AC_CHECK_SIZEOF(short)
372 AC_CHECK_SIZEOF(int16_t)
373 AC_CHECK_SIZEOF(uint16_t)
374 AC_CHECK_SIZEOF(int32_t)
375 AC_CHECK_SIZEOF(uint32_t)
376 AC_CHECK_SIZEOF(int64_t)
377 AC_CHECK_SIZEOF(off_t)
378 AC_CHECK_SIZEOF(off64_t)
379 AC_CHECK_SIZEOF(time_t)
380
381 AC_C_INLINE
382 AC_C_LONG_DOUBLE
383
384 AC_TYPE_SIGNAL
385 AC_TYPE_UID_T
386 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
387 AC_TYPE_GETGROUPS
388 AC_CHECK_MEMBERS([struct stat.st_rdev,
389                   struct stat.st_mtimensec,
390                   struct stat.st_mtim.tv_nsec],,,[
391 #ifdef HAVE_SYS_TYPES_H
392 #include <sys/types.h>
393 #endif
394 #ifdef HAVE_SYS_STAT_H
395 #include <sys/stat.h>
396 #endif
397 #ifdef HAVE_UNISTD_H
398 #include <unistd.h>
399 #endif])
400
401 TYPE_SOCKLEN_T
402
403 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
404     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
405         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
406 if test x"$rsync_cv_errno" = x"yes"; then
407    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
408 fi
409
410 # The following test taken from the cvs sources
411 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
412 # These need checks to be before checks for any other functions that
413 #    might be in the same libraries.
414 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
415 # libsocket.so which has a bad implementation of gethostbyname (it
416 # only looks in /etc/hosts), so we only look for -lsocket if we need
417 # it.
418 AC_CHECK_FUNCS(connect)
419 if test x"$ac_cv_func_connect" = x"no"; then
420     case "$LIBS" in
421     *-lnsl*) ;;
422     *) AC_CHECK_LIB(nsl_s, printf) ;;
423     esac
424     case "$LIBS" in
425     *-lnsl*) ;;
426     *) AC_CHECK_LIB(nsl, printf) ;;
427     esac
428     case "$LIBS" in
429     *-lsocket*) ;;
430     *) AC_CHECK_LIB(socket, connect) ;;
431     esac
432     case "$LIBS" in
433     *-linet*) ;;
434     *) AC_CHECK_LIB(inet, connect) ;;
435     esac
436     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
437     dnl has been cached.
438     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
439        test x"$ac_cv_lib_inet_connect" = x"yes"; then
440         # ac_cv_func_connect=yes
441         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
442         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
443     fi
444 fi
445
446 AC_SEARCH_LIBS(inet_ntop, resolv)
447
448 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
449 # accept either iconv_open or libiconv_open, since some include files map
450 # the former to the latter.
451 AC_SEARCH_LIBS(iconv_open, iconv)
452 AC_SEARCH_LIBS(libiconv_open, iconv)
453
454 AC_MSG_CHECKING([for iconv declaration])
455 AC_CACHE_VAL(am_cv_proto_iconv, [
456     AC_TRY_COMPILE([
457 #include <stdlib.h>
458 #include <iconv.h>
459 extern
460 #ifdef __cplusplus
461 "C"
462 #endif
463 #if defined(__STDC__) || defined(__cplusplus)
464 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
465 #else
466 size_t iconv();
467 #endif
468 ], [], am_cv_proto_iconv_arg1="", am_cv_proto_iconv_arg1="const")
469       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
470     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
471 AC_MSG_RESULT([$]{ac_t:-
472          }[$]am_cv_proto_iconv)
473 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
474                    [Define as const if the declaration of iconv() needs const.])
475
476 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
477
478 AC_CHECK_FUNCS(inet_ntop, , [AC_LIBOBJ(lib/inet_ntop)])
479 AC_CHECK_FUNCS(inet_pton, , [AC_LIBOBJ(lib/inet_pton)])
480
481 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
482 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
483 #include <sys/socket.h>])
484
485 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
486 #   builtin getaddrinfo if one of the defines don't exist
487 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
488                rsync_cv_HAVE_GETADDR_DEFINES,[
489                         AC_EGREP_CPP(yes, [
490                         #include <sys/types.h>
491                         #include <sys/socket.h>
492                         #include <netdb.h>
493                         #ifdef AI_PASSIVE
494                         yes
495                         #endif],
496                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
497                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
498 if test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"; then
499         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
500         # something else so we must include <netdb.h> to get the
501         # redefinition.
502         AC_CHECK_FUNCS(getaddrinfo, ,
503                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
504                 AC_TRY_LINK([#include <sys/types.h>
505                 #include <sys/socket.h>
506                 #include <netdb.h>],[getaddrinfo(NULL, NULL, NULL, NULL);],
507                         [AC_MSG_RESULT([yes])
508                         AC_DEFINE(HAVE_GETADDRINFO, 1,
509                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],
510                         [AC_MSG_RESULT([no])
511                         AC_LIBOBJ(lib/getaddrinfo)])])
512 else
513         AC_LIBOBJ(lib/getaddrinfo)
514 fi
515
516 AC_CHECK_MEMBER([struct sockaddr.sa_len],
517                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
518                 [],
519                 [
520 #include <sys/types.h>
521 #include <sys/socket.h>
522 ])
523
524 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
525                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
526                 [],
527                 [
528 #include <sys/types.h>
529 #include <sys/socket.h>
530 #include <netinet/in.h>
531 ])
532
533 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
534                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
535                 [],
536                 [
537 #include <sys/types.h>
538 #include <sys/socket.h>
539 #include <netinet/in.h>
540 ])
541
542 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
543                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
544                 [],
545                 [
546 #include <sys/types.h>
547 #include <sys/socket.h>
548 #include <netinet/in.h>
549 ])
550
551 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
552 #if HAVE_SYS_TYPES_H
553 # include <sys/types.h>
554 #endif
555 #if HAVE_SYS_STAT_H
556 # include <sys/stat.h>
557 #endif
558 #if STDC_HEADERS
559 # include <stdlib.h>
560 # include <stddef.h>
561 #else
562 # if HAVE_STDLIB_H
563 #  include <stdlib.h>
564 # endif
565 #endif
566 ])
567
568 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
569 #
570 AC_CHECK_FUNCS(strcasecmp)
571 if test x"$ac_cv_func_strcasecmp" = x"no"; then
572     AC_CHECK_LIB(resolv, strcasecmp)
573 fi
574
575 AC_CHECK_FUNCS(aclsort)
576 if test x"$ac_cv_func_aclsort" = x"no"; then
577     AC_CHECK_LIB(sec, aclsort)
578 fi
579
580 dnl At the moment we don't test for a broken memcmp(), because all we
581 dnl need to do is test for equality, not comparison, and it seems that
582 dnl every platform has a memcmp that can do at least that.
583 dnl AC_FUNC_MEMCMP
584
585 AC_FUNC_UTIME_NULL
586 AC_FUNC_ALLOCA
587 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
588     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
589     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
590     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
591     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
592     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
593     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
594     initgroups utimensat posix_fallocate)
595
596 dnl cygwin iconv.h defines iconv_open as libiconv_open
597 if test x"$ac_cv_func_iconv_open" != x"yes"; then
598     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
599 fi
600
601 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
602
603 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
604 AC_TRY_LINK([#include <fcntl.h>
605 #include <sys/types.h>],
606 [fallocate(0, 0, 0, 0);],
607 rsync_cv_have_fallocate=yes,rsync_cv_have_fallocate=no)])
608 if test x"$rsync_cv_have_fallocate" = x"yes"; then
609     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
610 fi
611
612 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
613 AC_TRY_COMPILE([#include <sys/syscall.h>
614 #include <sys/types.h>],
615 [syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);],
616 rsync_cv_have_sys_fallocate=yes,rsync_cv_have_sys_fallocate=no)])
617 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
618     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
619 fi
620
621 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
622     AC_MSG_CHECKING([whether posix_fallocate is efficient])
623     case $host_os in
624     *cygwin*)
625         AC_MSG_RESULT(yes)
626         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
627                   [Define if posix_fallocate is efficient (Cygwin)])
628         ;;
629     *)
630         AC_MSG_RESULT(no)
631         ;;
632     esac
633 fi
634
635 dnl End of preallocation stuff
636
637 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
638 if test $ac_cv_func_getpgrp = yes; then
639     AC_FUNC_GETPGRP
640 fi
641
642 AC_ARG_ENABLE(iconv-open,
643     AC_HELP_STRING([--disable-iconv-open],
644             [disable all use of iconv_open() function]),
645     [], [enable_iconv_open=$ac_cv_func_iconv_open])
646
647 if test x"$enable_iconv_open" != x"no"; then
648     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
649 fi
650
651 AC_ARG_ENABLE(iconv,
652     AC_HELP_STRING([--disable-iconv],
653             [disable rsync's --iconv option]),
654     [], [enable_iconv=$enable_iconv_open])
655 AH_TEMPLATE([ICONV_OPTION],
656 [Define if you want the --iconv option.  Specifing a value will set the
657 default iconv setting (a NULL means no --iconv processing by default).])
658 if test x"$enable_iconv" != x"no"; then
659         if test x"$enable_iconv" = x"yes"; then
660                 AC_DEFINE(ICONV_OPTION, NULL)
661         else
662                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
663         fi
664         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
665 fi
666
667 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
668   AC_TRY_RUN([
669 #if HAVE_UNISTD_H
670 # include <unistd.h>
671 #endif
672 #include <stdlib.h>
673 #include <errno.h>
674     main() {
675         char const *dangling_symlink = "conftest.dangle";
676         unlink(dangling_symlink);
677         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
678         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) exit(1);
679         exit(0);
680     }],
681   rsync_cv_chown_modifies_symlink=yes,rsync_cv_chown_modifies_symlink=no,rsync_cv_chown_modifies_symlink=no)])
682 if test $rsync_cv_chown_modifies_symlink = yes; then
683   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
684 fi
685
686 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
687   AC_TRY_RUN([
688 #if HAVE_UNISTD_H
689 # include <unistd.h>
690 #endif
691 #include <stdlib.h>
692 #include <errno.h>
693 #define FILENAME "conftest.dangle"
694     main() {
695         unlink(FILENAME);
696         if (symlink("conftest.no-such", FILENAME) < 0) abort();
697         if (link(FILENAME, FILENAME "2") < 0) exit(1);
698         exit(0);
699     }],
700   rsync_cv_can_hardlink_symlink=yes,rsync_cv_can_hardlink_symlink=no,rsync_cv_can_hardlink_symlink=no)])
701 if test $rsync_cv_can_hardlink_symlink = yes; then
702   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
703 fi
704
705 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
706   AC_TRY_RUN([
707 #if HAVE_UNISTD_H
708 # include <unistd.h>
709 #endif
710 #include <stdlib.h>
711 #include <errno.h>
712 #define FILENAME "conftest.fifi"
713     main() {
714         unlink(FILENAME);
715         if (mkfifo(FILENAME, 0777) < 0) abort();
716         if (link(FILENAME, FILENAME "2") < 0) exit(1);
717         exit(0);
718     }],
719   rsync_cv_can_hardlink_special=yes,rsync_cv_can_hardlink_special=no,rsync_cv_can_hardlink_special=no)])
720 if test $rsync_cv_can_hardlink_special = yes; then
721     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
722 fi
723
724 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
725 AC_TRY_RUN([
726 #include <sys/types.h>
727 #include <sys/socket.h>
728
729 main() {
730        int fd[2];
731        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
732 }],
733 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
734 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
735     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
736 fi
737
738 if test x"$with_included_popt" != x"yes"; then
739     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
740 fi
741 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
742     # If the system has /usr/include/popt/popt.h, we enable the
743     # included popt because an attempt to "#include <popt/popt.h>"
744     # would use our included header file anyway (due to -I.), and
745     # might conflict with the system popt.
746     with_included_popt=yes
747 elif test x"$ac_cv_header_popt_h" != x"yes"; then
748     with_included_popt=yes
749 fi
750
751 AC_MSG_CHECKING([whether to use included libpopt])
752 if test x"$with_included_popt" = x"yes"; then
753     AC_MSG_RESULT($srcdir/popt)
754     BUILD_POPT='$(popt_OBJS)'
755     CFLAGS="$CFLAGS -I$srcdir/popt"
756     if test x"$ALLOCA" != x
757     then
758         # this can be removed when/if we add an included alloca.c;
759         #  see autoconf documentation on AC_FUNC_ALLOCA
760         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
761     fi
762 else
763     AC_MSG_RESULT(no)
764 fi
765
766 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
767 AC_TRY_COMPILE([],[signed char *s = ""],
768 rsync_cv_SIGNED_CHAR_OK=yes,rsync_cv_SIGNED_CHAR_OK=no)])
769 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
770     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
771 fi
772
773 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
774 AC_TRY_RUN([#include <sys/types.h>
775 #include <dirent.h>
776 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
777 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
778 di->d_name[0] == 0) exit(0); exit(1);} ],
779 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
780 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
781     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
782 fi
783
784 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
785 AC_TRY_COMPILE([#include <sys/types.h>
786 #include <utime.h>],
787 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
788 rsync_cv_HAVE_STRUCT_UTIMBUF=yes,rsync_cv_HAVE_STRUCT_UTIMBUF=no)])
789 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
790     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
791 fi
792
793 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
794 AC_TRY_COMPILE([#include <sys/time.h>
795 #include <unistd.h>],
796 [struct timeval tv; exit(gettimeofday(&tv, NULL));],
797 rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no)])
798 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
799     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
800 fi
801
802 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
803 AC_TRY_RUN([
804 #include <sys/types.h>
805 #include <stdarg.h>
806 void foo(const char *format, ...) {
807        va_list ap;
808        int len;
809        char buf[5];
810
811        va_start(ap, format);
812        len = vsnprintf(0, 0, format, ap);
813        va_end(ap);
814        if (len != 5) exit(1);
815
816        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
817
818        exit(0);
819 }
820 main() { foo("hello"); }
821 ],
822 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
823 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
824     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
825 fi
826
827
828 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
829 AC_TRY_RUN([#include <stdlib.h>
830 #include <sys/types.h>
831 #include <sys/stat.h>
832 #include <unistd.h>
833 main() {
834   struct stat st;
835   char tpl[20]="/tmp/test.XXXXXX";
836   int fd = mkstemp(tpl);
837   if (fd == -1) exit(1);
838   unlink(tpl);
839   if (fstat(fd, &st) != 0) exit(1);
840   if ((st.st_mode & 0777) != 0600) exit(1);
841   exit(0);
842 }],
843 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
844 rsync_cv_HAVE_SECURE_MKSTEMP=no,
845 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
846 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
847     case $host_os in
848     hpux*)
849         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
850         dnl so we noisily skip using it.  See HP change request JAGaf34426
851         dnl for details. (sbonds)
852         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
853         ;;
854     *)
855         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
856         ;;
857     esac
858 fi
859
860
861 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
862 AC_TRY_RUN([
863 #include <stdio.h>
864 #include <sys/stat.h>
865 #include <errno.h>
866 main() { int rc, ec; char *fn = "fifo-test";
867 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
868 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
869 return 0;}],
870            rsync_cv_MKNOD_CREATES_FIFOS=yes,rsync_cv_MKNOD_CREATES_FIFOS=no,rsync_cv_MKNOD_CREATES_FIFOS=cross)])
871 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
872     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
873 fi
874
875 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
876 AC_TRY_RUN([
877 #include <stdio.h>
878 #include <sys/stat.h>
879 #include <errno.h>
880 main() { int rc, ec; char *fn = "sock-test";
881 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
882 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
883 return 0;}],
884            rsync_cv_MKNOD_CREATES_SOCKETS=yes,rsync_cv_MKNOD_CREATES_SOCKETS=no,rsync_cv_MKNOD_CREATES_SOCKETS=cross)])
885 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
886     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
887 fi
888
889 #
890 # The following test was mostly taken from the tcl/tk plus patches
891 #
892 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
893 rm -rf conftest*
894 cat > conftest.$ac_ext <<EOF
895 int main() { return 0; }
896 EOF
897 ${CC-cc} -c -o conftest..o conftest.$ac_ext
898 if test -f conftest..o; then
899     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
900 else
901     rsync_cv_DASHC_WORKS_WITH_DASHO=no
902 fi
903 rm -rf conftest*
904 ])
905 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
906     OBJ_SAVE="#"
907     OBJ_RESTORE="#"
908     CC_SHOBJ_FLAG='-o $@'
909 else
910     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
911     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
912     CC_SHOBJ_FLAG=""
913 fi
914
915 AC_SUBST(OBJ_SAVE)
916 AC_SUBST(OBJ_RESTORE)
917 AC_SUBST(CC_SHOBJ_FLAG)
918 AC_SUBST(BUILD_POPT)
919 AC_SUBST(MAKE_MAN)
920
921 AC_CHECK_FUNCS(_acl __acl _facl __facl)
922 #################################################
923 # check for ACL support
924
925 AC_MSG_CHECKING([whether to support ACLs])
926 AC_ARG_ENABLE(acl-support,
927         AC_HELP_STRING([--disable-acl-support],
928                        [disable ACL support]))
929
930 if test x"$enable_acl_support" = x"no"; then
931     AC_MSG_RESULT(no)
932 else
933     case "$host_os" in
934     *sysv5*)
935         AC_MSG_RESULT(Using UnixWare ACLs)
936         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
937         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
938         ;;
939     *solaris*|*cygwin*)
940         AC_MSG_RESULT(Using solaris ACLs)
941         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
942         AC_DEFINE(SUPPORT_ACLS, 1)
943         ;;
944     *hpux*)
945         AC_MSG_RESULT(Using HPUX ACLs)
946         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
947         AC_DEFINE(SUPPORT_ACLS, 1)
948         ;;
949     *irix*)
950         AC_MSG_RESULT(Using IRIX ACLs)
951         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
952         AC_DEFINE(SUPPORT_ACLS, 1)
953         ;;
954     *aix*)
955         AC_MSG_RESULT(Using AIX ACLs)
956         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
957         AC_DEFINE(SUPPORT_ACLS, 1)
958         ;;
959     *osf*)
960         AC_MSG_RESULT(Using Tru64 ACLs)
961         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
962         AC_DEFINE(SUPPORT_ACLS, 1)
963         LIBS="$LIBS -lpacl"
964         ;;
965     darwin*)
966         AC_MSG_RESULT(Using OS X ACLs)
967         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
968         AC_DEFINE(SUPPORT_ACLS, 1)
969         ;;
970     *)
971         AC_MSG_RESULT(running tests:)
972         AC_CHECK_LIB(acl,acl_get_file)
973             AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
974             AC_TRY_LINK([#include <sys/types.h>
975 #include <sys/acl.h>],
976 [ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);],
977 samba_cv_HAVE_POSIX_ACLS=yes,samba_cv_HAVE_POSIX_ACLS=no)])
978         AC_MSG_CHECKING(ACL test results)
979         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
980             AC_MSG_RESULT(Using posix ACLs)
981             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
982             AC_DEFINE(SUPPORT_ACLS, 1)
983             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
984                 AC_TRY_LINK([#include <sys/types.h>
985 #include <sys/acl.h>],
986 [ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);],
987 samba_cv_HAVE_ACL_GET_PERM_NP=yes,samba_cv_HAVE_ACL_GET_PERM_NP=no)])
988             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
989                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
990             fi
991         else
992             if test x"$enable_acl_support" = x"yes"; then
993                 AC_MSG_ERROR(Failed to find ACL support)
994             else
995                 AC_MSG_RESULT(No ACL support found)
996             fi
997         fi
998         ;;
999     esac
1000 fi
1001
1002 #################################################
1003 # check for extended attribute support
1004 AC_MSG_CHECKING(whether to support extended attributes)
1005 AC_ARG_ENABLE(xattr-support,
1006     AC_HELP_STRING([--disable-xattr-support],
1007             [disable extended attributes]),
1008     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link" in
1009         *yes*) enable_xattr_support=maybe ;;
1010         *) enable_xattr_support=no ;;
1011         esac])
1012 AH_TEMPLATE([SUPPORT_XATTRS],
1013 [Define to 1 to add support for extended attributes])
1014 if test x"$enable_xattr_support" = x"no"; then
1015     AC_MSG_RESULT(no)
1016 else
1017     case "$host_os" in
1018     *linux*)
1019         AC_MSG_RESULT(Using Linux xattrs)
1020         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs])
1021         AC_DEFINE(SUPPORT_XATTRS, 1)
1022         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1023         ;;
1024     darwin*)
1025         AC_MSG_RESULT(Using OS X xattrs)
1026         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1027         AC_DEFINE(SUPPORT_XATTRS, 1)
1028         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1029         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1030         ;;
1031     freebsd*)
1032         AC_MSG_RESULT(Using FreeBSD extattrs)
1033         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1034         AC_DEFINE(SUPPORT_XATTRS, 1)
1035         ;;
1036     solaris*)
1037         AC_MSG_RESULT(Using Solaris xattrs)
1038         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1039         AC_DEFINE(SUPPORT_XATTRS, 1)
1040         AC_DEFINE(NO_SYMLINK_XATTRS, 1)
1041         ;;
1042     *)
1043         if test x"$enable_xattr_support" = x"yes"; then
1044             AC_MSG_ERROR(Failed to find extended attribute support)
1045         else
1046             AC_MSG_RESULT(No extended attribute support found)
1047         fi
1048         ;;
1049     esac
1050 fi
1051
1052 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1053     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1054     OLD_CFLAGS="$CFLAGS"
1055     CFLAGS="$CFLAGS -Wno-unused-parameter"
1056     AC_TRY_LINK([#include <stdio.h>], [printf("hello\n");], [rsync_warn_flag=yes], [rsync_warn_flag=no])
1057     AC_MSG_RESULT([$rsync_warn_flag])
1058     if test x"$rsync_warn_flag" = x"no"; then
1059         CFLAGS="$OLD_CFLAGS"
1060     fi
1061 fi
1062
1063 case "$CC" in
1064 ' checker'*|checker*)
1065     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1066     ;;
1067 esac
1068
1069 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1070 AC_OUTPUT
1071
1072 AC_MSG_RESULT()
1073 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1074 AC_MSG_RESULT()