configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT()
   4 AC_CONFIG_SRCDIR([byteorder.h])
   5 AC_CONFIG_HEADER(config.h)
   6 AC_PREREQ(2.52)
   7
   8 RSYNC_VERSION=2.5.6pre3cvs
   9 AC_SUBST(RSYNC_VERSION)
  10 AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION])
  11
  12 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
  13
  14 LDFLAGS=${LDFLAGS-""}
  15
  16 AC_CANONICAL_TARGET([])
  17
  18 dnl Checks for programs.
  19 AC_PROG_CC
  20 AC_PROG_CPP
  21 AC_PROG_INSTALL
  22 AC_PROG_CC_STDC
  23 AC_SUBST(SHELL)
  24
  25 AC_DEFINE([_GNU_SOURCE], 1,
  26           [Define _GNU_SOURCE so that we get all necessary prototypes])
  27
  28 if test "x$ac_cv_prog_cc_stdc" = xno
  29 then
  30         AC_MSG_WARN([rsync requires an ANSI C compiler and you don't seem to have one])
  31 fi
  32
  33 # We must decide this before testing the compiler.
  34
  35 # Please allow this to default to yes, so that your users have more
  36 # chance of getting a useful stack trace if problems occur.
  37
  38 AC_MSG_CHECKING([whether to include debugging symbols])
  39 AC_ARG_ENABLE(debug,
  40         AC_HELP_STRING([--enable-debug],
  41                 [including debugging symbols and features (default yes)]),
  42                 [], [])
  43
  44 if test x"$enable_debug" = x"no"
  45 then
  46     AC_MSG_RESULT(no)
  47     CFLAGS=${CFLAGS-"-O"}
  48 else
  49     AC_MSG_RESULT([yes])
  50     # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can
  51     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  52     dnl CFLAGS=${CFLAGS-"-g"}
  53 fi
  54
  55
  56
  57
  58 AC_ARG_ENABLE(profile,
  59         AC_HELP_STRING([--enable-profile],
  60                 [turn on CPU profiling (default no)],
  61                 [], []))
  62 if test x"$enable_profile" = xyes
  63 then
  64         CFLAGS="$CFLAGS -pg"
  65 fi
  66
  67
  68 # Specifically, this turns on panic_action handling.
  69 AC_ARG_ENABLE(maintainer-mode,
  70         AC_HELP_STRING([--enable-maintainer-mode],
  71                 [turn on extra debug features],
  72                 [], []))
  73 if test x"$enable_maintainer_mode" = xyes
  74 then
  75         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
  76 fi
  77
  78
  79 # This is needed for our included version of popt.  Kind of silly, but
  80 # I don't want our version too far out of sync.
  81 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  82
  83 # If GCC, turn on warnings.
  84 if test "x$GCC" = "xyes"
  85 then
  86         CFLAGS="$CFLAGS -Wall -W"
  87 fi
  88
  89 AC_ARG_WITH(included-popt,
  90         [  --with-included-popt    use bundled popt library, not from system])
  91
  92 AC_ARG_WITH(rsync-path,
  93         [  --with-rsync-path=PATH  set default --rsync-path to PATH (default: \"rsync\")],
  94         [ RSYNC_PATH="$with_rsync_path" ],
  95         [ RSYNC_PATH="rsync" ])
  96
  97 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
  98
  99 AC_ARG_WITH(rsh,
 100         AC_HELP_STRING([--with-rsh=CMD], [set rsh command to CMD (default: \"remsh\" or \"rsh\")]))
 101
 102 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 103 AC_DEFINE_UNQUOTED(HAVE_REMSH, $HAVE_REMSH, [remote shell is remsh not rsh])
 104
 105 if test x"$with_rsh" != x
 106 then
 107         RSYNC_RSH="$with_rsh"
 108 elif test x"$HAVE_REMSH" = x1
 109 then
 110         RSYNC_RSH="remsh"
 111 else
 112         RSYNC_RSH="rsh"
 113 fi
 114
 115 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 116
 117 # arrgh. libc in the current debian stable screws up the largefile
 118 # stuff, getting byte range locking wrong
 119 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 120 AC_TRY_RUN([
 121 #define _FILE_OFFSET_BITS 64
 122 #include <stdio.h>
 123 #include <fcntl.h>
 124 #include <sys/types.h>
 125 #include <sys/wait.h>
 126
 127 int main(void)
 128 {
 129         struct flock lock;
 130         int status;
 131         int fd = open("conftest.dat", O_CREAT|O_RDWR, 0600);
 132         lock.l_type = F_WRLCK;
 133         lock.l_whence = SEEK_SET;
 134         lock.l_start = 0;
 135         lock.l_len = 1;
 136         lock.l_pid = 0;
 137
 138         fcntl(fd,F_SETLK,&lock);
 139         if (fork() == 0) {
 140                 lock.l_start = 1;
 141                 exit(fcntl(fd,F_SETLK,&lock) == 0);
 142         }
 143         wait(&status);
 144         unlink("conftest.dat");
 145         exit(WEXITSTATUS(status));
 146 }
 147 ],
 148 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
 149 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 150    AC_SYS_LARGEFILE
 151 fi
 152
 153 ipv6type=unknown
 154 ipv6lib=none
 155 ipv6trylibc=yes
 156
 157 AC_ARG_ENABLE(ipv6,
 158         AC_HELP_STRING([--disable-ipv6], [don't even try to use IPv6]))
 159
 160 if test "x$enable_ipv6" != xno
 161 then
 162         AC_MSG_CHECKING([ipv6 stack type])
 163         for i in inria kame linux-glibc linux-inet6 toshiba v6d zeta; do
 164                 case $i in
 165                 inria)
 166                         # http://www.kame.net/
 167                         AC_EGREP_CPP(yes, [
 168 #include <netinet/in.h>
 169 #ifdef IPV6_INRIA_VERSION
 170 yes
 171 #endif],
 172                                 [ipv6type=$i;
 173                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 174                                 ])
 175                         ;;
 176                 kame)
 177                         # http://www.kame.net/
 178                         AC_EGREP_CPP(yes, [
 179 #include <netinet/in.h>
 180 #ifdef __KAME__
 181 yes
 182 #endif],
 183                                 [ipv6type=$i;
 184                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 185                         ;;
 186                 linux-glibc)
 187                         # http://www.v6.linux.or.jp/
 188                         AC_EGREP_CPP(yes, [
 189 #include <features.h>
 190 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 191 yes
 192 #endif],
 193                                 [ipv6type=$i;
 194 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 195                         ;;
 196                 linux-inet6)
 197                         # http://www.v6.linux.or.jp/
 198                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 199                                 ipv6type=$i
 200                                 ipv6lib=inet6
 201                                 ipv6libdir=/usr/inet6/lib
 202                                 ipv6trylibc=yes;
 203                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 204                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 205                         fi
 206                         ;;
 207                 toshiba)
 208                         AC_EGREP_CPP(yes, [
 209 #include <sys/param.h>
 210 #ifdef _TOSHIBA_INET6
 211 yes
 212 #endif],
 213                                 [ipv6type=$i;
 214                                 ipv6lib=inet6;
 215                                 ipv6libdir=/usr/local/v6/lib;
 216                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 217                         ;;
 218                 v6d)
 219                         AC_EGREP_CPP(yes, [
 220 #include </usr/local/v6/include/sys/v6config.h>
 221 #ifdef __V6D__
 222 yes
 223 #endif],
 224                                 [ipv6type=$i;
 225                                 ipv6lib=v6;
 226                                 ipv6libdir=/usr/local/v6/lib;
 227                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 228                         ;;
 229                 zeta)
 230                         AC_EGREP_CPP(yes, [
 231 #include <sys/param.h>
 232 #ifdef _ZETA_MINAMI_INET6
 233 yes
 234 #endif],
 235                                 [ipv6type=$i;
 236                                 ipv6lib=inet6;
 237                                 ipv6libdir=/usr/local/v6/lib;
 238                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 239                         ;;
 240                 esac
 241                 if test "$ipv6type" != "unknown"; then
 242                         break
 243                 fi
 244         done
 245         AC_MSG_RESULT($ipv6type)
 246
 247         AC_SEARCH_LIBS(getaddrinfo, inet6)
 248 fi
 249
 250 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 251 case $host_os in
 252         *cygwin* ) AC_MSG_RESULT(yes)
 253                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 254                             [Define if sockets need to be shutdown])
 255                    ;;
 256                * ) AC_MSG_RESULT(no);;
 257 esac
 258
 259 AC_MSG_CHECKING([whether generator should delay before signaling receiver])
 260 case $host_os in
 261         *cygwin* ) AC_MSG_RESULT(yes)
 262                    AC_DEFINE(DELAY_BEFORE_SIGNALING_RECEIVER, 1,
 263                             [Define if generator should delay before signaling receiver])
 264                    ;;
 265                * ) AC_MSG_RESULT(no);;
 266 esac
 267
 268 AC_C_BIGENDIAN
 269 AC_HEADER_DIRENT
 270 AC_HEADER_TIME
 271 AC_HEADER_SYS_WAIT
 272 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h unistd.h utime.h grp.h)
 273 AC_CHECK_HEADERS(compat.h sys/param.h ctype.h sys/wait.h sys/ioctl.h)
 274 AC_CHECK_HEADERS(sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h sys/un.h)
 275 AC_CHECK_HEADERS(glob.h mcheck.h sys/sysctl.h arpa/inet.h arpa/nameser.h)
 276 AC_CHECK_HEADERS(netdb.h)
 277 AC_CHECK_HEADERS(malloc.h)
 278 AC_CHECK_HEADERS(float.h)
 279
 280 AC_CHECK_SIZEOF(int)
 281 AC_CHECK_SIZEOF(long)
 282 AC_CHECK_SIZEOF(short)
 283
 284 AC_C_INLINE
 285
 286 AC_TYPE_SIGNAL
 287 AC_TYPE_UID_T
 288 AC_TYPE_MODE_T
 289 AC_TYPE_OFF_T
 290 AC_TYPE_SIZE_T
 291 AC_TYPE_PID_T
 292 AC_TYPE_GETGROUPS
 293 AC_CHECK_MEMBERS([struct stat.st_rdev])
 294
 295 AC_CHECK_TYPE([ino_t], [unsigned])
 296 TYPE_SOCKLEN_T
 297
 298 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 299     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
 300         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
 301 if test x"$rsync_cv_errno" = x"yes"; then
 302    AC_DEFINE(HAVE_ERRNO_DECL, 1, [ ])
 303 fi
 304
 305 # The following test taken from the cvs sources
 306 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 307 # These need checks to be before checks for any other functions that
 308 #    might be in the same libraries.
 309 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 310 # libsocket.so which has a bad implementation of gethostbyname (it
 311 # only looks in /etc/hosts), so we only look for -lsocket if we need
 312 # it.
 313 AC_CHECK_FUNCS(connect)
 314 if test x"$ac_cv_func_connect" = x"no"; then
 315     case "$LIBS" in
 316     *-lnsl*) ;;
 317     *) AC_CHECK_LIB(nsl_s, printf) ;;
 318     esac
 319     case "$LIBS" in
 320     *-lnsl*) ;;
 321     *) AC_CHECK_LIB(nsl, printf) ;;
 322     esac
 323     case "$LIBS" in
 324     *-lsocket*) ;;
 325     *) AC_CHECK_LIB(socket, connect) ;;
 326     esac
 327     case "$LIBS" in
 328     *-linet*) ;;
 329     *) AC_CHECK_LIB(inet, connect) ;;
 330     esac
 331     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 332     dnl has been cached.
 333     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 334        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 335         # ac_cv_func_connect=yes
 336         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 337         AC_DEFINE(HAVE_CONNECT, 1, [ ])
 338     fi
 339 fi
 340
 341 AC_CHECK_LIB(resolv, inet_ntop)
 342
 343 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 344
 345 AC_CHECK_FUNCS(inet_ntop, , AC_LIBOBJ(lib/inet_ntop))
 346 AC_CHECK_FUNCS(inet_pton, , AC_LIBOBJ(lib/inet_pton))
 347
 348 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 349 #   builtin getaddrinfo if one of the defines don't exist
 350 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 351                rsync_cv_HAVE_GETADDR_DEFINES,[
 352                         AC_EGREP_CPP(yes, [
 353                         #include <sys/types.h>
 354                         #include <sys/socket.h>
 355                         #include <netdb.h>
 356                         #ifdef AI_PASSIVE
 357                         yes
 358                         #endif],
 359                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 360                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 361 if test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes"; then
 362         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 363         # something else so we must include <netdb.h> to get the
 364         # redefinition.
 365         AC_CHECK_FUNCS(getaddrinfo, ,
 366                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 367                 AC_TRY_LINK([#include <sys/types.h>
 368                 #include <sys/socket.h>
 369                 #include <netdb.h>],[getaddrinfo(NULL, NULL, NULL, NULL);],
 370                         [AC_MSG_RESULT([yes])
 371                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 372                                 [Define if you have the `getaddrinfo' function.])],
 373                         [AC_MSG_RESULT([no])
 374                         AC_LIBOBJ(lib/getaddrinfo)])])
 375         AC_CHECK_FUNCS(getnameinfo, , AC_LIBOBJ(lib/getnameinfo))
 376 else
 377         AC_LIBOBJ(lib/getaddrinfo)
 378         AC_LIBOBJ(lib/getnameinfo)
 379 fi
 380
 381
 382 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 383                 [ AC_DEFINE(HAVE_SOCKADDR_LEN) ],
 384                 [],
 385                 [
 386 #include <sys/types.h>
 387 #include <sys/socket.h>
 388 ])
 389
 390 AC_MSG_CHECKING(struct sockaddr_storage)
 391 AC_TRY_COMPILE([#include <sys/types.h>
 392 #include <sys/socket.h>],
 393 [struct sockaddr_storage x;],
 394         AC_MSG_RESULT(yes)
 395         AC_DEFINE(HAVE_SOCKADDR_STORAGE, 1,
 396                 [Define if you have strct sockaddr_storage.] ),
 397         AC_MSG_RESULT(no))
 398
 399 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 400                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID) ],
 401                 [],
 402                 [
 403 #include <sys/types.h>
 404 #include <sys/socket.h>
 405 #include <netinet/in.h>
 406 ])
 407
 408 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 409 #
 410 AC_CHECK_FUNCS(strcasecmp)
 411 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 412     AC_CHECK_LIB(resolv, strcasecmp)
 413 fi
 414
 415 dnl At the moment we don't test for a broken memcmp(), because all we
 416 dnl need to do is test for equality, not comparison, and it seems that
 417 dnl every platform has a memcmp that can do at least that.
 418 dnl AC_FUNC_MEMCMP
 419
 420 AC_FUNC_UTIME_NULL
 421 AC_FUNC_ALLOCA
 422 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup strerror chown chmod mknod mkfifo)
 423 AC_CHECK_FUNCS(fchmod fstat strchr readlink link utime utimes strftime)
 424 AC_CHECK_FUNCS(memmove lchown vsnprintf snprintf asprintf setsid glob strpbrk)
 425 AC_CHECK_FUNCS(strlcat strlcpy strtol mtrace mallinfo setgroups)
 426
 427 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 428 AC_TRY_RUN([
 429 #include <sys/types.h>
 430 #include <sys/socket.h>
 431
 432 main() {
 433        int fd[2];
 434        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 435 }],
 436 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
 437 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 438     AC_DEFINE(HAVE_SOCKETPAIR, 1, [ ])
 439 fi
 440
 441 AC_CACHE_CHECK([for working fnmatch],rsync_cv_HAVE_FNMATCH,[
 442 AC_TRY_RUN([#include <fnmatch.h>
 443 main() { exit((fnmatch("*.o", "x.o", FNM_PATHNAME) == 0 &&
 444                fnmatch("a/b/*", "a/b/c/d", FNM_PATHNAME) != 0) ? 0: 1); }],
 445 rsync_cv_HAVE_FNMATCH=yes,rsync_cv_HAVE_FNMATCH=no,rsync_cv_HAVE_FNMATCH=cross)])
 446 if test x"$rsync_cv_HAVE_FNMATCH" = x"yes"; then
 447     AC_DEFINE(HAVE_FNMATCH, 1, [ ])
 448 fi
 449
 450 if test x"$with_included_popt" != x"yes"
 451 then
 452     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 453 fi
 454
 455 AC_MSG_CHECKING([whether to use included libpopt])
 456 if test x"$with_included_popt" = x"yes"
 457 then
 458     AC_MSG_RESULT($srcdir/popt)
 459     BUILD_POPT='$(popt_OBJS)'
 460     CFLAGS="$CFLAGS -I$srcdir/popt"
 461     if test x"$ALLOCA" != x
 462     then
 463         # this can be removed when/if we add an included alloca.c;
 464         #  see autoconf documentation on AC_FUNC_ALLOCA
 465         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 466     fi
 467 else
 468     AC_MSG_RESULT(no)
 469 fi
 470
 471 AC_CACHE_CHECK([for long long],rsync_cv_HAVE_LONGLONG,[
 472 AC_TRY_RUN([#include <stdio.h>
 473 main() { long long x = 1000000; x *= x; exit(((x/1000000) == 1000000)? 0: 1); }],
 474 rsync_cv_HAVE_LONGLONG=yes,rsync_cv_HAVE_LONGLONG=no,rsync_cv_HAVE_LONGLONG=cross)])
 475 if test x"$rsync_cv_HAVE_LONGLONG" = x"yes"; then
 476     AC_DEFINE(HAVE_LONGLONG, 1, [ ])
 477 fi
 478
 479 AC_CACHE_CHECK([for off64_t],rsync_cv_HAVE_OFF64_T,[
 480 AC_TRY_RUN([#include <stdio.h>
 481 #include <sys/stat.h>
 482 main() { struct stat64 st; off64_t s; if (sizeof(off_t) == sizeof(off64_t)) exit(1); exit((lstat64("/dev/null", &st)==0)?0:1); }],
 483 rsync_cv_HAVE_OFF64_T=yes,rsync_cv_HAVE_OFF64_T=no,rsync_cv_HAVE_OFF64_T=cross)])
 484 if test x"$rsync_cv_HAVE_OFF64_T" = x"yes"; then
 485     AC_DEFINE(HAVE_OFF64_T, 1, [ ])
 486 fi
 487
 488 AC_CACHE_CHECK([for short ino_t],rsync_cv_HAVE_SHORT_INO_T,[
 489 AC_TRY_RUN([#include <stdio.h>
 490 #include <sys/types.h>
 491 #include <sys/stat.h>
 492 main() { if (sizeof(ino_t) < sizeof(unsigned int)) return 0; return 1; }],
 493 rsync_cv_HAVE_SHORT_INO_T=yes,rsync_cv_HAVE_SHORT_INO_T=no,rsync_cv_HAVE_SHORT_INO_T=cross)])
 494 if test x"$rsync_cv_HAVE_SHORT_INO_T" = x"yes"; then
 495     AC_DEFINE(HAVE_SHORT_INO_T, 1, [ ])
 496 fi
 497
 498 AC_CACHE_CHECK([for unsigned char],rsync_cv_HAVE_UNSIGNED_CHAR,[
 499 AC_TRY_RUN([#include <stdio.h>
 500 main() { char c; c=250; exit((c > 0)?0:1); }],
 501 rsync_cv_HAVE_UNSIGNED_CHAR=yes,rsync_cv_HAVE_UNSIGNED_CHAR=no,rsync_cv_HAVE_UNSIGNED_CHAR=cross)])
 502 if test x"$rsync_cv_HAVE_UNSIGNED_CHAR" = x"yes"; then
 503     AC_DEFINE(HAVE_UNSIGNED_CHAR, 1, [ ])
 504 fi
 505
 506 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 507 AC_TRY_RUN([#include <sys/types.h>
 508 #include <dirent.h>
 509 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 510 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 511 di->d_name[0] == 0) exit(0); exit(1);} ],
 512 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 513 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 514     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [ ])
 515 fi
 516
 517 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[
 518 AC_TRY_COMPILE([#include <sys/types.h>
 519 #include <utime.h>],
 520 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 521 rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no,rsync_cv_HAVE_UTIMBUF=cross)])
 522 if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then
 523     AC_DEFINE(HAVE_UTIMBUF, 1, [ ])
 524 fi
 525
 526 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 527 AC_TRY_RUN([
 528 #include <sys/time.h>
 529 #include <unistd.h>
 530 main() { struct timeval tv; exit(gettimeofday(&tv, NULL));}],
 531            rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no,rsync_cv_HAVE_GETTIMEOFDAY_TZ=cross)])
 532 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" = x"yes"; then
 533     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [ ])
 534 fi
 535
 536 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 537 AC_TRY_RUN([
 538 #include <sys/types.h>
 539 #include <stdarg.h>
 540 void foo(const char *format, ...) {
 541        va_list ap;
 542        int len;
 543        char buf[5];
 544
 545        va_start(ap, format);
 546        len = vsnprintf(0, 0, format, ap);
 547        va_end(ap);
 548        if (len != 5) exit(1);
 549
 550        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 551
 552        exit(0);
 553 }
 554 main() { foo("hello"); }
 555 ],
 556 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
 557 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 558     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [ ])
 559 fi
 560
 561
 562 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 563 AC_TRY_RUN([#include <stdlib.h>
 564 #include <sys/types.h>
 565 #include <sys/stat.h>
 566 #include <unistd.h>
 567 main() {
 568   struct stat st;
 569   char tpl[20]="/tmp/test.XXXXXX";
 570   int fd = mkstemp(tpl);
 571   if (fd == -1) exit(1);
 572   unlink(tpl);
 573   if (fstat(fd, &st) != 0) exit(1);
 574   if ((st.st_mode & 0777) != 0600) exit(1);
 575   exit(0);
 576 }],
 577 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
 578 rsync_cv_HAVE_SECURE_MKSTEMP=no,
 579 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
 580 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 581     AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [ ])
 582 fi
 583
 584
 585 AC_CACHE_CHECK([for broken inet_ntoa],rsync_cv_REPLACE_INET_NTOA,[
 586 AC_TRY_RUN([
 587 #include <stdio.h>
 588 #include <sys/types.h>
 589 #include <netinet/in.h>
 590 #include <arpa/inet.h>
 591 main() { struct in_addr ip; ip.s_addr = 0x12345678;
 592 if (strcmp(inet_ntoa(ip),"18.52.86.120") &&
 593     strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(1); }
 594 exit(0);}],
 595            rsync_cv_REPLACE_INET_NTOA=no,rsync_cv_REPLACE_INET_NTOA=yes,rsync_cv_REPLACE_INET_NTOA=cross)])
 596 if test x"$rsync_cv_REPLACE_INET_NTOA" = x"yes"; then
 597     AC_DEFINE(REPLACE_INET_NTOA, 1, [ ])
 598 fi
 599
 600
 601 AC_CACHE_CHECK([for broken inet_aton],rsync_cv_REPLACE_INET_ATON,[
 602 AC_TRY_RUN([
 603 #include <stdio.h>
 604 #include <sys/types.h>
 605 #include <netinet/in.h>
 606 #include <arpa/inet.h>
 607 main() { struct in_addr ip;
 608 if (inet_aton("example", &ip) == 0) exit(0); exit(1);}],
 609            rsync_cv_REPLACE_INET_ATON=no,rsync_cv_REPLACE_INET_ATON=yes,rsync_cv_REPLACE_INET_ATON=cross)])
 610 if test x"$rsync_cv_REPLACE_INET_ATON" = x"yes"; then
 611     AC_DEFINE(REPLACE_INET_ATON, 1, [ ])
 612 fi
 613
 614 #
 615 # The following test was mostly taken from the tcl/tk plus patches
 616 #
 617 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 618 rm -rf conftest*
 619 cat > conftest.$ac_ext <<EOF
 620 int main() { return 0; }
 621 EOF
 622 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 623 if test -f conftest..o; then
 624     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 625 else
 626     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 627 fi
 628 rm -rf conftest*
 629 ])
 630 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 631     OBJ_SAVE="#"
 632     OBJ_RESTORE="#"
 633     CC_SHOBJ_FLAG='-o $@'
 634 else
 635     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 636     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 637     CC_SHOBJ_FLAG=""
 638 fi
 639
 640 AC_SUBST(OBJ_SAVE)
 641 AC_SUBST(OBJ_RESTORE)
 642 AC_SUBST(CC_SHOBJ_FLAG)
 643 AC_SUBST(BUILD_POPT)
 644
 645 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
 646 AC_OUTPUT
 647
 648 AC_MSG_RESULT()
 649 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
 650 AC_MSG_RESULT()