packaging/release-rsync

   1 #!/usr/bin/perl
   2 use strict;
   3
   4 # This script expects the directory ~/samba-rsync-ftp to exist and to be a
   5 # copy of the /home/ftp/pub/rsync dir on samba.org.  When the script is done,
   6 # the git repository in the current directory will be updated, and the local
   7 # ~/samba-rsync-ftp dir will be ready to be rsynced to samba.org.
   8
   9 use Cwd;
  10 use Date::Format;
  11
  12 my $dest = $ENV{HOME} . '/samba-rsync-ftp';
  13
  14 my $cl_today = time2str('* %a %b %d %Y', time);
  15 my $ztoday = time2str('%d %b %Y', time);
  16 (my $today = $ztoday) =~ s/^0//;
  17
  18 my $curdir = Cwd::cwd;
  19
  20 my @extra_files;
  21 open(IN, '<', 'Makefile.in') or die "Couldn't open Makefile.in: $!\n";
  22 while (<IN>) {
  23     if (s/^GENFILES=//) {
  24         while (s/\\$//) {
  25             $_ .= <IN>;
  26         }
  27         @extra_files = split(' ', $_);
  28         last;
  29     }
  30 }
  31 close IN;
  32
  33 my $break = <<EOT;
  34 ==========================================================================
  35 EOT
  36
  37 print $break, <<EOT, $break, "\n";
  38 == This will release a new version of rsync onto an unsuspecting world. ==
  39 EOT
  40
  41 die "$dest does not exist\n" unless -d $dest;
  42 die "There is no .git dir in the current directory.\n" unless -d '.git';
  43 die "'a' must not exist in the current directory.\n" if -e 'a';
  44 die "'b' must not exist in the current directory.\n" if -e 'b';
  45
  46 open(IN, '-|', 'git status') or die $!;
  47 my $status = join('', <IN>);
  48 close IN;
  49 die "The checkout is not clean:\n", $status unless $status =~ /\nnothing to commit \(working directory clean\)/;
  50 die "The checkout is not on the master branch.\n" unless $status =~ /^# On branch master\n/;
  51
  52 my $lastversion;
  53 open(IN, '<', 'configure.in') or die $!;
  54 while (<IN>) {
  55     if (/^RSYNC_VERSION=(.*)/) {
  56         $lastversion = $1;
  57         last;
  58     }
  59 }
  60 close IN;
  61 if ($lastversion =~ /dev$/) {
  62     open(IN, '<', 'OLDNEWS') or die $!;
  63     $_ = <IN>;
  64     close IN;
  65     ($lastversion) = /(\d+\.\d+\.\d+)/;
  66 }
  67
  68 my $version = $lastversion;
  69 $version =~ s/dev/pre1/ || $version =~ s/pre(\d+)/ 'pre' . ($1 + 1) /e;
  70
  71 print "Please enter the version number of this release: [$version] ";
  72 chomp($_ = <STDIN>);
  73 if ($_ eq '.') {
  74     $version =~ s/pre\d+//;
  75 } elsif ($_ ne '') {
  76     $version = $_;
  77 }
  78 $version =~ s/[-.]*pre[-.]*/pre/;
  79
  80 print "Enter the previous version to produce a patch against: [$lastversion] ";
  81 chomp($_ = <STDIN>);
  82 $lastversion = $_ if $_ ne '';
  83 $lastversion =~ s/[-.]*pre[-.]*/pre/;
  84
  85 my $release = 1;
  86 print "Please enter the RPM release number of this release: [$release] ";
  87 chomp($_ = <STDIN>);
  88 $release = $_ if $_ ne '';
  89
  90 my $diffdir;
  91 my $skipping;
  92 if ($lastversion =~ /pre/) {
  93     if ($version !~ /pre/) {
  94         die "You should not diff a release version against a pre-release version.\n";
  95     }
  96     $diffdir = "$dest/old-previews";
  97     $skipping = ' ** SKIPPING **';
  98 } elsif ($version =~ /pre/) {
  99     $diffdir = $dest;
 100     $skipping = ' ** SKIPPING **';
 101 } else {
 102     $diffdir = "$dest/old-versions";
 103     $skipping = '';
 104 }
 105
 106 print "\n", $break, <<EOT;
 107 \$version is "$version"
 108 \$lastversion is "$lastversion"
 109 \$dest is "$dest"
 110 \$curdir is "$curdir"
 111 \$diffdir is "$diffdir"
 112 \$release is "$release"
 113
 114 About to:
 115     - make sure that SUBPROTOCOL_VERSION is 0$skipping
 116     - tweak the version in configure.in and the spec files
 117     - tweak NEWS and OLDNEWS to update the release date$skipping
 118     - tweak the date in the *.yo files and generate the man pages
 119     - generate configure.sh, config.h.in, and proto.h
 120     - page through the differences
 121
 122 EOT
 123 print "<Press Enter to continue> ";
 124 $_ = <STDIN>;
 125
 126 print $break;
 127
 128 my @tweak_files = ( glob('packaging/*.spec'), glob('packaging/*/*.spec'),
 129                     glob('*.yo'), qw( configure.in ) );
 130
 131 if ($version !~ /pre/) {
 132     push(@tweak_files, qw( rsync.h NEWS OLDNEWS ));
 133 }
 134 foreach my $fn (@tweak_files) {
 135     open(IN, '<', $fn) or die $!;
 136     undef $/; $_ = <IN>; $/ = "\n";
 137     close IN;
 138     if ($fn =~ /configure/) {
 139         s/^RSYNC_VERSION=.*/RSYNC_VERSION=$version/m;
 140     } elsif ($fn =~ /\.spec/) {
 141         s/^(Version:) .*/$1 $version/m;
 142         s/^(Release:) .*/$1 $release/m;
 143         s/^(Released) .*/$1 $version./m;
 144         s/^\* \w\w\w \w\w\w \d\d \d\d\d\d (.*)/$cl_today $1/m;
 145     } elsif ($fn =~ /\.yo/) {
 146         s/^(manpage\([^)]+\)\(\d+\)\()[^)]+(\).*)/$1$today$2/m;
 147         s/^(This man ?page is current for version) \S+ (of rsync)/$1 $version $2/m;
 148     } elsif ($fn eq 'NEWS') {
 149         s/^(NEWS for rsync \Q$version\E) \(UNRELEASED\)\s*\n/$1 ($today)\n/mi
 150             or die "Couldn't update NEWS file with release date!\n";
 151     } elsif ($fn eq 'rsync.h') {
 152         s/(#define\s+SUBPROTOCOL_VERSION)\s+\d+/$1 0/;
 153     } elsif ($fn eq 'OLDNEWS') {
 154         s/^\t\S\S\s\S\S\S\s\d\d\d\d(\t\Q$version\E)/\t$ztoday$1/m
 155             or die "Couldn't update OLDNEWS file with release date!\n";
 156     } else {
 157         die "Unrecognized file in \@tweak_files: $fn\n";
 158     }
 159     open(OUT, '>', $fn) or die $!;
 160     print OUT $_;
 161     close OUT;
 162 }
 163
 164 print $break;
 165 system "git diff --color | less -p '^diff .*'";
 166
 167 my $srctar_name = "rsync-$version.tar.gz";
 168 my $pattar_name = "rsync-patches-$version.tar.gz";
 169 my $diff_name = "rsync-$lastversion-$version.diffs.gz";
 170 my $srctar_file = "$dest/$srctar_name";
 171 my $pattar_file = "$dest/$pattar_name";
 172 my $diff_file = "$dest/$diff_name";
 173 my $lasttar_file = "$dest/rsync-$lastversion.tar.gz";
 174
 175 print $break, <<EOT;
 176
 177 About to:
 178     - commit all changes
 179     - tag this release as v$version
 180     - move the old tar/diff files into the appropriate old-* dirs
 181     - hard-link the moved tar/diff files on samba.org
 182     - create release tar, "$srctar_name"
 183     - create patches tar, "$pattar_name"
 184     - create release diffs, "$diff_name"
 185     - update patch branches and generate patch/* files
 186     - update README, *NEWS, TODO, and changelog
 187     - update rsync*.html man pages
 188     - gpg-sign the release files
 189
 190 EOT
 191 print "<Press Enter to continue> ";
 192 $_ = <STDIN>;
 193
 194 system "git commit -a -m 'Preparing for release of $version'" and exit 1;
 195 system "git tag -s -m 'Version $version.' v$version" and exit 1;
 196
 197 # When creating a pre-release after a normal release, there's nothing to move.
 198 if ($diffdir ne $dest) {
 199     chdir($dest) or die $!;
 200
 201     print "Shuffling old files ...\n";
 202
 203     # We need to run this regardless of $lastversion's "pre"ness.
 204     my @moved_files;
 205     foreach my $fn (glob('rsync*pre*.tar.gz*'), glob('rsync*pre*-NEWS')) {
 206         link($fn, "old-previews/$fn") or die $!;
 207         push(@moved_files, $fn);
 208     }
 209
 210     if ($version !~ /pre/) {
 211         foreach my $fn (glob('rsync*.tar.gz*'), glob('rsync*-NEWS')) {
 212             next if $fn =~ /^rsync.*pre/;
 213             link($fn, "old-versions/$fn") or die $!;
 214             push(@moved_files, $fn);
 215         }
 216
 217         foreach my $fn (glob('rsync*pre*.diffs.gz*')) {
 218             unlink($fn);
 219         }
 220
 221         foreach my $fn (glob('rsync*.diffs.gz*')) {
 222             link($fn, "old-patches/$fn") or die $!;
 223             push(@moved_files, $fn);
 224         }
 225     }
 226
 227     # Optimize our future upload (in the absence of --detect-renamed) by
 228     # using rsync to hard-link the above files on samba.org.
 229     system "rsync -avHOC --include='rsync*.gz*' --include='old-*/' --exclude='*' . samba.org:/home/ftp/pub/rsync";
 230     foreach (@moved_files) {
 231         unlink($_);
 232     }
 233
 234     chdir($curdir) or die $!;
 235 }
 236
 237 print "Creating $diff_file ...\n";
 238 @_ = @extra_files;
 239 map { s#^#rsync-$lastversion/# } @_;
 240 system "tar xzf $lasttar_file @_";
 241 rename("rsync-$lastversion", 'a');
 242 system "make gen; rsync -a @extra_files b/";
 243 my $sed_script = 's:^((---|\+\+\+) [ab]/[^\t]+)\t.*:\1:';
 244 system "(git diff v$lastversion v$version; diff -up a b | sed -r '$sed_script') | gzip -9 >$diff_file";
 245 system "rm -rf a";
 246 rename('b', "rsync-$version");
 247
 248 print "Creating $srctar_file ...\n";
 249 system "git archive --format=tar --prefix=rsync-$version/ v$version | tar xf -";
 250 system "support/git-set-file-times --prefix=rsync-$version/";
 251 system "fakeroot tar czf $srctar_file rsync-$version; rm -rf rsync-$version";
 252
 253 system "support/patch-update --gen";
 254
 255 symlink('.', "rsync-$version");
 256 system "fakeroot tar czf $pattar_file rsync-$version/patches";
 257 unlink("rsync-$version");
 258
 259 print "Updating the other files in $dest ...\n";
 260 system "rsync -a README NEWS OLDNEWS TODO $dest";
 261 unlink("$dest/rsync-$version-NEWS");
 262 link("$dest/NEWS", "$dest/rsync-$version-NEWS");
 263 system "git log --name-status | gzip -9 >$dest/changelog.gz";
 264
 265 system "yodl2html -o $dest/rsync.html rsync.yo";
 266 system "yodl2html -o $dest/rsyncd.conf.html rsyncd.conf.yo";
 267
 268 chdir($dest) or die $!;
 269 system "gpg -ba $srctar_name; gpg -ba $pattar_name; gpg -ba $diff_name";
 270 print $break, <<EOT;
 271
 272 All done.  Remember to announce the release on *BOTH*
 273 rsync-announce\@lists.samba.org and rsync\@lists.samba.org!
 274 EOT