configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT()
   4 AC_CONFIG_SRCDIR([byteorder.h])
   5 AC_CONFIG_HEADER(config.h)
   6 AC_PREREQ(2.59)
   7
   8 RSYNC_VERSION=3.1.0dev
   9 AC_SUBST(RSYNC_VERSION)
  10 AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION])
  11
  12 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
  13
  14 LDFLAGS=${LDFLAGS-""}
  15
  16 AC_CANONICAL_HOST
  17
  18 # We must decide this before testing the compiler.
  19
  20 # Please allow this to default to yes, so that your users have more
  21 # chance of getting a useful stack trace if problems occur.
  22
  23 AC_MSG_CHECKING([whether to include debugging symbols])
  24 AC_ARG_ENABLE(debug,
  25         AC_HELP_STRING([--disable-debug],
  26                 [disable debugging symbols and features]))
  27
  28 if test x"$enable_debug" = x"no"; then
  29     AC_MSG_RESULT(no)
  30     ac_cv_prog_cc_g=no
  31 else
  32     AC_MSG_RESULT([yes])
  33     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  34     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  35 fi
  36
  37 dnl Checks for programs.
  38 AC_PROG_CC
  39 AC_PROG_CPP
  40 AC_PROG_EGREP
  41 AC_PROG_INSTALL
  42 AC_PROG_CC_STDC
  43 AC_SUBST(SHELL)
  44
  45 AC_DEFINE([_GNU_SOURCE], 1,
  46           [Define _GNU_SOURCE so that we get all necessary prototypes])
  47
  48 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  49         AC_MSG_WARN([rsync requires an ANSI C compiler and you don't seem to have one])
  50 fi
  51
  52 AC_ARG_ENABLE(profile,
  53         AC_HELP_STRING([--enable-profile],
  54                 [turn on CPU profiling]))
  55 if test x"$enable_profile" = x"yes"; then
  56         CFLAGS="$CFLAGS -pg"
  57 fi
  58
  59
  60 # Specifically, this turns on panic_action handling.
  61 AC_ARG_ENABLE(maintainer-mode,
  62         AC_HELP_STRING([--enable-maintainer-mode],
  63                 [turn on extra debug features]))
  64 if test x"$enable_maintainer_mode" = x"yes"; then
  65         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
  66 fi
  67
  68
  69 # This is needed for our included version of popt.  Kind of silly, but
  70 # I don't want our version too far out of sync.
  71 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  72
  73 # If GCC, turn on warnings.
  74 if test x"$GCC" = x"yes"; then
  75         CFLAGS="$CFLAGS -Wall -W"
  76 fi
  77
  78 AC_ARG_WITH(included-popt,
  79         AC_HELP_STRING([--with-included-popt], [use bundled popt library, not from system]))
  80
  81 AC_ARG_WITH(rsync-path,
  82         AC_HELP_STRING([--with-rsync-path=PATH], [set default --rsync-path to PATH (default: rsync)]),
  83         [ RSYNC_PATH="$with_rsync_path" ],
  84         [ RSYNC_PATH="rsync" ])
  85
  86 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
  87
  88 AC_ARG_WITH(rsyncd-conf,
  89         AC_HELP_STRING([--with-rsyncd-conf=PATH], [set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
  90         [ if test ! -z "$with_rsyncd_conf" ; then
  91                 case $with_rsyncd_conf in
  92                         yes|no)
  93                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
  94                                 ;;
  95                         /*)
  96                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
  97                                 ;;
  98                         *)
  99                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 100                                 ;;
 101                 esac
 102         else
 103                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 104         fi ],
 105         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 106
 107 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 108
 109 AC_ARG_WITH(rsh,
 110         AC_HELP_STRING([--with-rsh=CMD], [set remote shell command to CMD (default: ssh)]))
 111
 112 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 113 if test x$HAVE_REMSH = x1; then
 114         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 115 fi
 116
 117 if test x"$with_rsh" != x; then
 118         RSYNC_RSH="$with_rsh"
 119 else
 120         RSYNC_RSH="ssh"
 121 fi
 122 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 123
 124 AC_CHECK_PROG(HAVE_YODL2MAN, yodl2man, 1, 0)
 125 if test x$HAVE_YODL2MAN = x1; then
 126     MAKE_MAN=man
 127 fi
 128
 129 AC_ARG_WITH(nobody-group,
 130     AC_HELP_STRING([--with-nobody-group=GROUP],
 131                    [set the default unprivileged group (default nobody or nogroup)]),
 132     [ NOBODY_GROUP="$with_nobody_group" ])
 133
 134 if test x"$with_nobody_group" = x; then
 135     AC_MSG_CHECKING([the group for user "nobody"])
 136     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 137         NOBODY_GROUP=nobody
 138     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 139         NOBODY_GROUP=nogroup
 140     else
 141         NOBODY_GROUP=nobody # test for others?
 142     fi
 143     AC_MSG_RESULT($NOBODY_GROUP)
 144 fi
 145
 146 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 147 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 148
 149 # arrgh. libc in some old debian version screwed up the largefile
 150 # stuff, getting byte range locking wrong
 151 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 152 AC_TRY_RUN([
 153 #define _FILE_OFFSET_BITS 64
 154 #include <stdio.h>
 155 #include <fcntl.h>
 156 #include <sys/types.h>
 157 #include <sys/wait.h>
 158
 159 int main(void)
 160 {
 161         struct flock lock;
 162         int status;
 163         char tpl[32] = "/tmp/locktest.XXXXXX";
 164         int fd = mkstemp(tpl);
 165         if (fd < 0) {
 166                 strcpy(tpl, "conftest.dat");
 167                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 168         }
 169
 170         lock.l_type = F_WRLCK;
 171         lock.l_whence = SEEK_SET;
 172         lock.l_start = 0;
 173         lock.l_len = 1;
 174         lock.l_pid = 0;
 175         fcntl(fd,F_SETLK,&lock);
 176         if (fork() == 0) {
 177                 lock.l_start = 1;
 178                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 179         }
 180         wait(&status);
 181         unlink(tpl);
 182         exit(WEXITSTATUS(status));
 183 }
 184 ],
 185 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
 186 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 187    AC_SYS_LARGEFILE
 188 fi
 189
 190 ipv6type=unknown
 191 ipv6lib=none
 192 ipv6trylibc=yes
 193
 194 AC_ARG_ENABLE(ipv6,
 195         AC_HELP_STRING([--disable-ipv6],
 196                 [don't even try to use IPv6]))
 197 if test x"$enable_ipv6" != x"no"; then
 198         AC_MSG_CHECKING([ipv6 stack type])
 199         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
 200                 case $i in
 201                 inria)
 202                         # http://www.kame.net/
 203                         AC_EGREP_CPP(yes, [
 204 #include <netinet/in.h>
 205 #ifdef IPV6_INRIA_VERSION
 206 yes
 207 #endif],
 208                                 [ipv6type=$i;
 209                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 210                                 ])
 211                         ;;
 212                 kame)
 213                         # http://www.kame.net/
 214                         AC_EGREP_CPP(yes, [
 215 #include <netinet/in.h>
 216 #ifdef __KAME__
 217 yes
 218 #endif],
 219                                 [ipv6type=$i;
 220                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 221                         ;;
 222                 linux-glibc)
 223                         # http://www.v6.linux.or.jp/
 224                         AC_EGREP_CPP(yes, [
 225 #include <features.h>
 226 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 227 yes
 228 #endif],
 229                                 [ipv6type=$i;
 230 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 231                         ;;
 232                 linux-inet6)
 233                         # http://www.v6.linux.or.jp/
 234                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 235                                 ipv6type=$i
 236                                 ipv6lib=inet6
 237                                 ipv6libdir=/usr/inet6/lib
 238                                 ipv6trylibc=yes;
 239                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 240                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 241                         fi
 242                         ;;
 243                 solaris)
 244                         # http://www.sun.com
 245                         AC_EGREP_CPP(yes, [
 246 #include <netinet/ip6.h>
 247 #ifdef __sun
 248 yes
 249 #endif],
 250                                 [ipv6type=$i;
 251                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 252                         ;;
 253                 toshiba)
 254                         AC_EGREP_CPP(yes, [
 255 #include <sys/param.h>
 256 #ifdef _TOSHIBA_INET6
 257 yes
 258 #endif],
 259                                 [ipv6type=$i;
 260                                 ipv6lib=inet6;
 261                                 ipv6libdir=/usr/local/v6/lib;
 262                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 263                         ;;
 264                 v6d)
 265                         AC_EGREP_CPP(yes, [
 266 #include </usr/local/v6/include/sys/v6config.h>
 267 #ifdef __V6D__
 268 yes
 269 #endif],
 270                                 [ipv6type=$i;
 271                                 ipv6lib=v6;
 272                                 ipv6libdir=/usr/local/v6/lib;
 273                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 274                         ;;
 275                 zeta)
 276                         AC_EGREP_CPP(yes, [
 277 #include <sys/param.h>
 278 #ifdef _ZETA_MINAMI_INET6
 279 yes
 280 #endif],
 281                                 [ipv6type=$i;
 282                                 ipv6lib=inet6;
 283                                 ipv6libdir=/usr/local/v6/lib;
 284                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 285                         ;;
 286                 cygwin)
 287                         AC_EGREP_CPP(yes, [
 288 #include <netinet/in.h>
 289 #ifdef _CYGWIN_IN6_H
 290 yes
 291 #endif],
 292                                 [ipv6type=$i;
 293                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 294                         ;;
 295                 esac
 296                 if test "$ipv6type" != "unknown"; then
 297                         break
 298                 fi
 299         done
 300         AC_MSG_RESULT($ipv6type)
 301
 302         AC_SEARCH_LIBS(getaddrinfo, inet6)
 303 fi
 304
 305 dnl Do you want to disable use of locale functions
 306 AC_ARG_ENABLE([locale],
 307         AC_HELP_STRING([--disable-locale],
 308                 [disable locale features]))
 309 AH_TEMPLATE([CONFIG_LOCALE],
 310 [Undefine if you don't want locale features.  By default this is defined.])
 311 if test x"$enable_locale" != x"no"; then
 312         AC_DEFINE(CONFIG_LOCALE)
 313 fi
 314
 315 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 316 case $host_os in
 317         *cygwin* ) AC_MSG_RESULT(yes)
 318                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 319                             [Define to 1 if sockets need to be shutdown])
 320                    ;;
 321                * ) AC_MSG_RESULT(no);;
 322 esac
 323
 324 AC_C_BIGENDIAN
 325 AC_HEADER_DIRENT
 326 AC_HEADER_TIME
 327 AC_HEADER_SYS_WAIT
 328 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 329     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 330     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 331     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 332     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 333     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
 334     popt.h popt/popt.h)
 335 AC_HEADER_MAJOR
 336
 337 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 338 AC_TRY_RUN([
 339 #include <sys/types.h>
 340 #ifdef MAJOR_IN_MKDEV
 341 #include <sys/mkdev.h>
 342 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 343 #  define makedev mkdev
 344 # endif
 345 #elif defined MAJOR_IN_SYSMACROS
 346 #include <sys/sysmacros.h>
 347 #endif
 348
 349 int main(void)
 350 {
 351         dev_t dev = makedev(0, 5, 7);
 352         if (major(dev) != 5 || minor(dev) != 7)
 353                 exit(1);
 354         return 0;
 355 }
 356 ],
 357 rsync_cv_MAKEDEV_TAKES_3_ARGS=yes,rsync_cv_MAKEDEV_TAKES_3_ARGS=no,rsync_cv_MAKEDEV_TAKES_3_ARGS=no)])
 358 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 359    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 360 fi
 361
 362 AC_CHECK_SIZEOF(int)
 363 AC_CHECK_SIZEOF(long)
 364 AC_CHECK_SIZEOF(long long)
 365 AC_CHECK_SIZEOF(short)
 366 AC_CHECK_SIZEOF(int16_t)
 367 AC_CHECK_SIZEOF(uint16_t)
 368 AC_CHECK_SIZEOF(int32_t)
 369 AC_CHECK_SIZEOF(uint32_t)
 370 AC_CHECK_SIZEOF(int64_t)
 371 AC_CHECK_SIZEOF(off_t)
 372 AC_CHECK_SIZEOF(off64_t)
 373 AC_CHECK_SIZEOF(time_t)
 374
 375 AC_C_INLINE
 376 AC_C_LONG_DOUBLE
 377
 378 AC_TYPE_SIGNAL
 379 AC_TYPE_UID_T
 380 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 381 AC_TYPE_GETGROUPS
 382 AC_CHECK_MEMBERS([struct stat.st_rdev,
 383                   struct stat.st_mtimensec,
 384                   struct stat.st_mtim.tv_nsec],,,[
 385 #ifdef HAVE_SYS_TYPES_H
 386 #include <sys/types.h>
 387 #endif
 388 #ifdef HAVE_SYS_STAT_H
 389 #include <sys/stat.h>
 390 #endif
 391 #ifdef HAVE_UNISTD_H
 392 #include <unistd.h>
 393 #endif])
 394
 395 TYPE_SOCKLEN_T
 396
 397 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 398     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
 399         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
 400 if test x"$rsync_cv_errno" = x"yes"; then
 401    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 402 fi
 403
 404 # The following test taken from the cvs sources
 405 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 406 # These need checks to be before checks for any other functions that
 407 #    might be in the same libraries.
 408 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 409 # libsocket.so which has a bad implementation of gethostbyname (it
 410 # only looks in /etc/hosts), so we only look for -lsocket if we need
 411 # it.
 412 AC_CHECK_FUNCS(connect)
 413 if test x"$ac_cv_func_connect" = x"no"; then
 414     case "$LIBS" in
 415     *-lnsl*) ;;
 416     *) AC_CHECK_LIB(nsl_s, printf) ;;
 417     esac
 418     case "$LIBS" in
 419     *-lnsl*) ;;
 420     *) AC_CHECK_LIB(nsl, printf) ;;
 421     esac
 422     case "$LIBS" in
 423     *-lsocket*) ;;
 424     *) AC_CHECK_LIB(socket, connect) ;;
 425     esac
 426     case "$LIBS" in
 427     *-linet*) ;;
 428     *) AC_CHECK_LIB(inet, connect) ;;
 429     esac
 430     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 431     dnl has been cached.
 432     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 433        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 434         # ac_cv_func_connect=yes
 435         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 436         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 437     fi
 438 fi
 439
 440 AC_SEARCH_LIBS(inet_ntop, resolv)
 441
 442 # Solaris and HP-UX weirdness:
 443 # Search for libiconv_open (not iconv_open) to discover if -liconv is needed!
 444 AC_SEARCH_LIBS(libiconv_open, iconv)
 445
 446 AC_MSG_CHECKING([for iconv declaration])
 447 AC_CACHE_VAL(am_cv_proto_iconv, [
 448     AC_TRY_COMPILE([
 449 #include <stdlib.h>
 450 #include <iconv.h>
 451 extern
 452 #ifdef __cplusplus
 453 "C"
 454 #endif
 455 #if defined(__STDC__) || defined(__cplusplus)
 456 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 457 #else
 458 size_t iconv();
 459 #endif
 460 ], [], am_cv_proto_iconv_arg1="", am_cv_proto_iconv_arg1="const")
 461       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 462     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 463 AC_MSG_RESULT([$]{ac_t:-
 464          }[$]am_cv_proto_iconv)
 465 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 466                    [Define as const if the declaration of iconv() needs const.])
 467
 468 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 469
 470 AC_CHECK_FUNCS(inet_ntop, , [AC_LIBOBJ(lib/inet_ntop)])
 471 AC_CHECK_FUNCS(inet_pton, , [AC_LIBOBJ(lib/inet_pton)])
 472
 473 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 474 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 475 #include <sys/socket.h>])
 476
 477 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 478 #   builtin getaddrinfo if one of the defines don't exist
 479 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 480                rsync_cv_HAVE_GETADDR_DEFINES,[
 481                         AC_EGREP_CPP(yes, [
 482                         #include <sys/types.h>
 483                         #include <sys/socket.h>
 484                         #include <netdb.h>
 485                         #ifdef AI_PASSIVE
 486                         yes
 487                         #endif],
 488                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 489                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 490 if test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"; then
 491         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 492         # something else so we must include <netdb.h> to get the
 493         # redefinition.
 494         AC_CHECK_FUNCS(getaddrinfo, ,
 495                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 496                 AC_TRY_LINK([#include <sys/types.h>
 497                 #include <sys/socket.h>
 498                 #include <netdb.h>],[getaddrinfo(NULL, NULL, NULL, NULL);],
 499                         [AC_MSG_RESULT([yes])
 500                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 501                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],
 502                         [AC_MSG_RESULT([no])
 503                         AC_LIBOBJ(lib/getaddrinfo)])])
 504 else
 505         AC_LIBOBJ(lib/getaddrinfo)
 506 fi
 507
 508 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 509                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 510                 [],
 511                 [
 512 #include <sys/types.h>
 513 #include <sys/socket.h>
 514 ])
 515
 516 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 517                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 518                 [],
 519                 [
 520 #include <sys/types.h>
 521 #include <sys/socket.h>
 522 #include <netinet/in.h>
 523 ])
 524
 525 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 526                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 527                 [],
 528                 [
 529 #include <sys/types.h>
 530 #include <sys/socket.h>
 531 #include <netinet/in.h>
 532 ])
 533
 534 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 535                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 536                 [],
 537                 [
 538 #include <sys/types.h>
 539 #include <sys/socket.h>
 540 #include <netinet/in.h>
 541 ])
 542
 543 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 544 #if HAVE_SYS_TYPES_H
 545 # include <sys/types.h>
 546 #endif
 547 #if HAVE_SYS_STAT_H
 548 # include <sys/stat.h>
 549 #endif
 550 #if STDC_HEADERS
 551 # include <stdlib.h>
 552 # include <stddef.h>
 553 #else
 554 # if HAVE_STDLIB_H
 555 #  include <stdlib.h>
 556 # endif
 557 #endif
 558 ])
 559
 560 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 561 #
 562 AC_CHECK_FUNCS(strcasecmp)
 563 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 564     AC_CHECK_LIB(resolv, strcasecmp)
 565 fi
 566
 567 AC_CHECK_FUNCS(aclsort)
 568 if test x"$ac_cv_func_aclsort" = x"no"; then
 569     AC_CHECK_LIB(sec, aclsort)
 570 fi
 571
 572 dnl At the moment we don't test for a broken memcmp(), because all we
 573 dnl need to do is test for equality, not comparison, and it seems that
 574 dnl every platform has a memcmp that can do at least that.
 575 dnl AC_FUNC_MEMCMP
 576
 577 AC_FUNC_UTIME_NULL
 578 AC_FUNC_ALLOCA
 579 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 580     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 581     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 582     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 583     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 584     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 585     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 586     initgroups utimensat)
 587
 588 dnl cygwin iconv.h defines iconv_open as libiconv_open
 589 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 590     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 591 fi
 592
 593 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 594 if test $ac_cv_func_getpgrp = yes; then
 595     AC_FUNC_GETPGRP
 596 fi
 597
 598 AC_ARG_ENABLE(iconv-open,
 599     AC_HELP_STRING([--disable-iconv-open],
 600             [disable all use of iconv_open() function]),
 601     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 602
 603 if test x"$enable_iconv_open" != x"no"; then
 604     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 605 fi
 606
 607 AC_ARG_ENABLE(iconv,
 608     AC_HELP_STRING([--disable-iconv],
 609             [disable rsync's --iconv option]),
 610     [], [enable_iconv=$enable_iconv_open])
 611 AH_TEMPLATE([ICONV_OPTION],
 612 [Define if you want the --iconv option.  Specifing a value will set the
 613 default iconv setting (a NULL means no --iconv processing by default).])
 614 if test x"$enable_iconv" != x"no"; then
 615         if test x"$enable_iconv" = x"yes"; then
 616                 AC_DEFINE(ICONV_OPTION, NULL)
 617         else
 618                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 619         fi
 620         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 621 fi
 622
 623 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 624   AC_TRY_RUN([
 625 #if HAVE_UNISTD_H
 626 # include <unistd.h>
 627 #endif
 628 #include <stdlib.h>
 629 #include <errno.h>
 630     main() {
 631         char const *dangling_symlink = "conftest.dangle";
 632         unlink(dangling_symlink);
 633         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 634         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) exit(1);
 635         exit(0);
 636     }],
 637   rsync_cv_chown_modifies_symlink=yes,rsync_cv_chown_modifies_symlink=no,rsync_cv_chown_modifies_symlink=no)])
 638 if test $rsync_cv_chown_modifies_symlink = yes; then
 639   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 640 fi
 641
 642 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 643   AC_TRY_RUN([
 644 #if HAVE_UNISTD_H
 645 # include <unistd.h>
 646 #endif
 647 #include <stdlib.h>
 648 #include <errno.h>
 649 #define FILENAME "conftest.dangle"
 650     main() {
 651         unlink(FILENAME);
 652         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 653         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 654         exit(0);
 655     }],
 656   rsync_cv_can_hardlink_symlink=yes,rsync_cv_can_hardlink_symlink=no,rsync_cv_can_hardlink_symlink=no)])
 657 if test $rsync_cv_can_hardlink_symlink = yes; then
 658   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 659 fi
 660
 661 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 662   AC_TRY_RUN([
 663 #if HAVE_UNISTD_H
 664 # include <unistd.h>
 665 #endif
 666 #include <stdlib.h>
 667 #include <errno.h>
 668 #define FILENAME "conftest.fifi"
 669     main() {
 670         unlink(FILENAME);
 671         if (mkfifo(FILENAME, 0777) < 0) abort();
 672         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 673         exit(0);
 674     }],
 675   rsync_cv_can_hardlink_special=yes,rsync_cv_can_hardlink_special=no,rsync_cv_can_hardlink_special=no)])
 676 if test $rsync_cv_can_hardlink_special = yes; then
 677     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 678 fi
 679
 680 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 681 AC_TRY_RUN([
 682 #include <sys/types.h>
 683 #include <sys/socket.h>
 684
 685 main() {
 686        int fd[2];
 687        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 688 }],
 689 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
 690 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 691     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 692 fi
 693
 694 if test x"$with_included_popt" != x"yes"; then
 695     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 696 fi
 697 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
 698     # If the system has /usr/include/popt/popt.h, we enable the
 699     # included popt because an attempt to "#include <popt/popt.h>"
 700     # would use our included header file anyway (due to -I.), and
 701     # might conflict with the system popt.
 702     with_included_popt=yes
 703 elif test x"$ac_cv_header_popt_h" != x"yes"; then
 704     with_included_popt=yes
 705 fi
 706
 707 AC_MSG_CHECKING([whether to use included libpopt])
 708 if test x"$with_included_popt" = x"yes"; then
 709     AC_MSG_RESULT($srcdir/popt)
 710     BUILD_POPT='$(popt_OBJS)'
 711     CFLAGS="$CFLAGS -I$srcdir/popt"
 712     if test x"$ALLOCA" != x
 713     then
 714         # this can be removed when/if we add an included alloca.c;
 715         #  see autoconf documentation on AC_FUNC_ALLOCA
 716         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 717     fi
 718 else
 719     AC_MSG_RESULT(no)
 720 fi
 721
 722 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 723 AC_TRY_COMPILE([],[signed char *s = ""],
 724 rsync_cv_SIGNED_CHAR_OK=yes,rsync_cv_SIGNED_CHAR_OK=no)])
 725 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 726     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 727 fi
 728
 729 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 730 AC_TRY_RUN([#include <sys/types.h>
 731 #include <dirent.h>
 732 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 733 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 734 di->d_name[0] == 0) exit(0); exit(1);} ],
 735 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 736 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 737     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
 738 fi
 739
 740 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
 741 AC_TRY_COMPILE([#include <sys/types.h>
 742 #include <utime.h>],
 743 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 744 rsync_cv_HAVE_STRUCT_UTIMBUF=yes,rsync_cv_HAVE_STRUCT_UTIMBUF=no)])
 745 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
 746     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
 747 fi
 748
 749 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 750 AC_TRY_COMPILE([#include <sys/time.h>
 751 #include <unistd.h>],
 752 [struct timeval tv; exit(gettimeofday(&tv, NULL));],
 753 rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no)])
 754 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
 755     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
 756 fi
 757
 758 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 759 AC_TRY_RUN([
 760 #include <sys/types.h>
 761 #include <stdarg.h>
 762 void foo(const char *format, ...) {
 763        va_list ap;
 764        int len;
 765        char buf[5];
 766
 767        va_start(ap, format);
 768        len = vsnprintf(0, 0, format, ap);
 769        va_end(ap);
 770        if (len != 5) exit(1);
 771
 772        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 773
 774        exit(0);
 775 }
 776 main() { foo("hello"); }
 777 ],
 778 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
 779 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 780     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
 781 fi
 782
 783
 784 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 785 AC_TRY_RUN([#include <stdlib.h>
 786 #include <sys/types.h>
 787 #include <sys/stat.h>
 788 #include <unistd.h>
 789 main() {
 790   struct stat st;
 791   char tpl[20]="/tmp/test.XXXXXX";
 792   int fd = mkstemp(tpl);
 793   if (fd == -1) exit(1);
 794   unlink(tpl);
 795   if (fstat(fd, &st) != 0) exit(1);
 796   if ((st.st_mode & 0777) != 0600) exit(1);
 797   exit(0);
 798 }],
 799 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
 800 rsync_cv_HAVE_SECURE_MKSTEMP=no,
 801 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
 802 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 803     case $host_os in
 804     hpux*)
 805         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
 806         dnl so we noisily skip using it.  See HP change request JAGaf34426
 807         dnl for details. (sbonds)
 808         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
 809         ;;
 810     *)
 811         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
 812         ;;
 813     esac
 814 fi
 815
 816
 817 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
 818 AC_TRY_RUN([
 819 #include <stdio.h>
 820 #include <sys/stat.h>
 821 #include <errno.h>
 822 main() { int rc, ec; char *fn = "fifo-test";
 823 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
 824 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 825 return 0;}],
 826            rsync_cv_MKNOD_CREATES_FIFOS=yes,rsync_cv_MKNOD_CREATES_FIFOS=no,rsync_cv_MKNOD_CREATES_FIFOS=cross)])
 827 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
 828     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
 829 fi
 830
 831 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
 832 AC_TRY_RUN([
 833 #include <stdio.h>
 834 #include <sys/stat.h>
 835 #include <errno.h>
 836 main() { int rc, ec; char *fn = "sock-test";
 837 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
 838 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 839 return 0;}],
 840            rsync_cv_MKNOD_CREATES_SOCKETS=yes,rsync_cv_MKNOD_CREATES_SOCKETS=no,rsync_cv_MKNOD_CREATES_SOCKETS=cross)])
 841 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
 842     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
 843 fi
 844
 845 #
 846 # The following test was mostly taken from the tcl/tk plus patches
 847 #
 848 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 849 rm -rf conftest*
 850 cat > conftest.$ac_ext <<EOF
 851 int main() { return 0; }
 852 EOF
 853 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 854 if test -f conftest..o; then
 855     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 856 else
 857     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 858 fi
 859 rm -rf conftest*
 860 ])
 861 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 862     OBJ_SAVE="#"
 863     OBJ_RESTORE="#"
 864     CC_SHOBJ_FLAG='-o $@'
 865 else
 866     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 867     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 868     CC_SHOBJ_FLAG=""
 869 fi
 870
 871 AC_SUBST(OBJ_SAVE)
 872 AC_SUBST(OBJ_RESTORE)
 873 AC_SUBST(CC_SHOBJ_FLAG)
 874 AC_SUBST(BUILD_POPT)
 875 AC_SUBST(MAKE_MAN)
 876
 877 AC_CHECK_FUNCS(_acl __acl _facl __facl)
 878 #################################################
 879 # check for ACL support
 880
 881 AC_MSG_CHECKING([whether to support ACLs])
 882 AC_ARG_ENABLE(acl-support,
 883         AC_HELP_STRING([--disable-acl-support],
 884                        [disable ACL support]))
 885
 886 if test x"$enable_acl_support" = x"no"; then
 887     AC_MSG_RESULT(no)
 888 else
 889     case "$host_os" in
 890     *sysv5*)
 891         AC_MSG_RESULT(Using UnixWare ACLs)
 892         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
 893         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
 894         ;;
 895     *solaris*|*cygwin*)
 896         AC_MSG_RESULT(Using solaris ACLs)
 897         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
 898         AC_DEFINE(SUPPORT_ACLS, 1)
 899         ;;
 900     *hpux*)
 901         AC_MSG_RESULT(Using HPUX ACLs)
 902         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
 903         AC_DEFINE(SUPPORT_ACLS, 1)
 904         ;;
 905     *irix*)
 906         AC_MSG_RESULT(Using IRIX ACLs)
 907         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
 908         AC_DEFINE(SUPPORT_ACLS, 1)
 909         ;;
 910     *aix*)
 911         AC_MSG_RESULT(Using AIX ACLs)
 912         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
 913         AC_DEFINE(SUPPORT_ACLS, 1)
 914         ;;
 915     *osf*)
 916         AC_MSG_RESULT(Using Tru64 ACLs)
 917         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
 918         AC_DEFINE(SUPPORT_ACLS, 1)
 919         LIBS="$LIBS -lpacl"
 920         ;;
 921     darwin*)
 922         AC_MSG_RESULT(Using OS X ACLs)
 923         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
 924         AC_DEFINE(SUPPORT_ACLS, 1)
 925         ;;
 926     *)
 927         AC_MSG_RESULT(running tests:)
 928         AC_CHECK_LIB(acl,acl_get_file)
 929             AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
 930             AC_TRY_LINK([#include <sys/types.h>
 931 #include <sys/acl.h>],
 932 [ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);],
 933 samba_cv_HAVE_POSIX_ACLS=yes,samba_cv_HAVE_POSIX_ACLS=no)])
 934         AC_MSG_CHECKING(ACL test results)
 935         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
 936             AC_MSG_RESULT(Using posix ACLs)
 937             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
 938             AC_DEFINE(SUPPORT_ACLS, 1)
 939             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
 940                 AC_TRY_LINK([#include <sys/types.h>
 941 #include <sys/acl.h>],
 942 [ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);],
 943 samba_cv_HAVE_ACL_GET_PERM_NP=yes,samba_cv_HAVE_ACL_GET_PERM_NP=no)])
 944             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
 945                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
 946             fi
 947         else
 948             if test x"$enable_acl_support" = x"yes"; then
 949                 AC_MSG_ERROR(Failed to find ACL support)
 950             else
 951                 AC_MSG_RESULT(No ACL support found)
 952             fi
 953         fi
 954         ;;
 955     esac
 956 fi
 957
 958 #################################################
 959 # check for extended attribute support
 960 AC_MSG_CHECKING(whether to support extended attributes)
 961 AC_ARG_ENABLE(xattr-support,
 962     AC_HELP_STRING([--disable-xattr-support],
 963             [disable extended attributes]),
 964     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link" in
 965         *yes*) enable_xattr_support=maybe ;;
 966         *) enable_xattr_support=no ;;
 967         esac])
 968 AH_TEMPLATE([SUPPORT_XATTRS],
 969 [Define to 1 to add support for extended attributes])
 970 if test x"$enable_xattr_support" = x"no"; then
 971     AC_MSG_RESULT(no)
 972 else
 973     case "$host_os" in
 974     *linux*)
 975         AC_MSG_RESULT(Using Linux xattrs)
 976         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs])
 977         AC_DEFINE(SUPPORT_XATTRS, 1)
 978         ;;
 979     darwin*)
 980         AC_MSG_RESULT(Using OS X xattrs)
 981         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
 982         AC_DEFINE(SUPPORT_XATTRS, 1)
 983         ;;
 984     freebsd*)
 985         AC_MSG_RESULT(Using FreeBSD extattrs)
 986         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
 987         AC_DEFINE(SUPPORT_XATTRS, 1)
 988         ;;
 989     solaris*)
 990         AC_MSG_RESULT(Using Solaris xattrs)
 991         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
 992         AC_DEFINE(SUPPORT_XATTRS, 1)
 993         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks don't support xattrs])
 994         ;;
 995     *)
 996         if test x"$enable_xattr_support" = x"yes"; then
 997             AC_MSG_ERROR(Failed to find extended attribute support)
 998         else
 999             AC_MSG_RESULT(No extended attribute support found)
1000         fi
1001         ;;
1002     esac
1003 fi
1004
1005 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1006     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1007     OLD_CFLAGS="$CFLAGS"
1008     CFLAGS="$CFLAGS -Wno-unused-parameter"
1009     AC_COMPILE_IFELSE([ ], [rsync_warn_flag=yes], [rsync_warn_flag=no])
1010     AC_MSG_RESULT([$rsync_warn_flag])
1011     if test x"$rsync_warn_flag" = x"no"; then
1012         CFLAGS="$OLD_CFLAGS"
1013     fi
1014 fi
1015
1016 case "$CC" in
1017 ' checker'*|checker*)
1018     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1019     ;;
1020 esac
1021
1022 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1023 AC_OUTPUT
1024
1025 AC_MSG_RESULT()
1026 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1027 AC_MSG_RESULT()